Как мне установить выходные флаги для ALU в курсе "Nand to Tetris"?
Хотя я пометил это домашнее задание, на самом деле это курс, который я делаю самостоятельно, бесплатно. В любом случае, этот курс называется "От Нанда до Тетриса", и я надеюсь, что кто-то здесь видел или прошел этот курс, чтобы я мог получить некоторую помощь. Я нахожусь на этапе, когда я строю АЛУ с помощью поставляемого языка HDL. Моя проблема в том, что я не могу заставить мой чип правильно скомпилировать. Я получаю ошибки, когда пытаюсь установить выходные флаги для АЛУ. Я полагаю, что проблема в том, что я не могу подписать какую-либо промежуточную переменную, так как, когда я просто пытаюсь установить флаги в true или false, основываясь на некоторой случайной переменной (скажем, флаг ввода), я не получаю ошибки. Я знаю, что проблема не в чипах, которые я пытаюсь использовать, так как я использую все встроенные чипы.
Вот мой чип ALU:
/**
* The ALU. Computes a pre-defined set of functions out = f(x,y)
* where x and y are two 16-bit inputs. The function f is selected
* by a set of 6 control bits denoted zx, nx, zy, ny, f, no.
* The ALU operation can be described using the following pseudocode:
* if zx=1 set x = 0 // 16-bit zero constant
* if nx=1 set x = !x // Bit-wise negation
* if zy=1 set y = 0 // 16-bit zero constant
* if ny=1 set y = !y // Bit-wise negation
* if f=1 set out = x + y // Integer 2's complement addition
* else set out = x & y // Bit-wise And
* if no=1 set out = !out // Bit-wise negation
*
* In addition to computing out, the ALU computes two 1-bit outputs:
* if out=0 set zr = 1 else zr = 0 // 16-bit equality comparison
* if out<0 set ng = 1 else ng = 0 // 2's complement comparison
*/
CHIP ALU {
IN // 16-bit inputs:
x[16], y[16],
// Control bits:
zx, // Zero the x input
nx, // Negate the x input
zy, // Zero the y input
ny, // Negate the y input
f, // Function code: 1 for add, 0 for and
no; // Negate the out output
OUT // 16-bit output
out[16],
// ALU output flags
zr, // 1 if out=0, 0 otherwise
ng; // 1 if out<0, 0 otherwise
PARTS:
// Zero the x input
Mux16( a=x, b=false, sel=zx, out=x2 );
// Zero the y input
Mux16( a=y, b=false, sel=zy, out=y2 );
// Negate the x input
Not16( in=x, out=notx );
Mux16( a=x, b=notx, sel=nx, out=x3 );
// Negate the y input
Not16( in=y, out=noty );
Mux16( a=y, b=noty, sel=ny, out=y3 );
// Perform f
Add16( a=x3, b=y3, out=addout );
And16( a=x3, b=y3, out=andout );
Mux16( a=andout, b=addout, sel=f, out=preout );
// Negate the output
Not16( in=preout, out=notpreout );
Mux16( a=preout, b=notpreout, sel=no, out=out );
// zr flag
Or8way( in=out[0..7], out=zr1 ); // PROBLEM SHOWS UP HERE
Or8way( in=out[8..15], out=zr2 );
Or( a=zr1, b=zr2, out=zr );
// ng flag
Not( in=out[15], out=ng );
}
Таким образом, проблема проявляется, когда я пытаюсь отправить подписанную версию "out" на чип Or8Way. Я попытался использовать переменную, отличную от "out", но с той же проблемой. Тогда я прочитал, что вы не можете использовать промежуточные переменные. Я подумал, может быть, если я отправлю промежуточную переменную в какой-то другой чип, и этот чип подпишется на него, это решит проблему, но у нее та же ошибка. К сожалению, я просто не могу придумать способ установить флаги zr и ng без подписки какой-либо промежуточной переменной, поэтому я действительно застрял!
Просто чтобы вы знали, если я заменим проблемные строки на следующие, он скомпилируется (но не даст правильных результатов, так как я просто использую некоторый случайный ввод):
// zr flag
Not( in=zx, out=zr );
// ng flag
Not( in=zx, out=ng );
У кого-нибудь есть идеи?
Редактировать: вот приложение книги для курса, который определяет, как работает HDL. В частности, посмотрите на раздел 5, в котором говорится о шинах и говорится: "Внутренний вывод (как v выше) не может быть подписан".
Редактировать: Вот точная ошибка, которую я получаю: "Линия 68, Не могу соединить выходной контакт затвора с деталью". Однако сообщение об ошибке немного сбивает с толку, так как это не является реальной проблемой. Если я просто заменю "Or8way( in=out[0..7], out=zr1);" с "Or8way( in=false, out=zr1);" это не сгенерирует эту ошибку, из-за чего я заглянул в приложение и обнаружил, что переменная out, поскольку она была получена как промежуточная, не может быть подписана.
5 ответов
Решение, предложенное Pax, заключалось в использовании промежуточной переменной в качестве входных данных для другого чипа, такого как Or16Way. Вот код после того, как я исправил проблему и отладил:
CHIP ALU {
IN // 16-bit inputs:
x[16], y[16],
// Control bits:
zx, // Zero the x input
nx, // Negate the x input
zy, // Zero the y input
ny, // Negate the y input
f, // Function code: 1 for add, 0 for and
no; // Negate the out output
OUT // 16-bit output
out[16],
// ALU output flags
zr, // 1 if out=0, 0 otherwise
ng; // 1 if out<0, 0 otherwise
PARTS:
// Zero the x input
Mux16( a=x, b=false, sel=zx, out=x2 );
// Zero the y input
Mux16( a=y, b=false, sel=zy, out=y2 );
// Negate the x input
Not16( in=x2, out=notx );
Mux16( a=x2, b=notx, sel=nx, out=x3 );
// Negate the y input
Not16( in=y2, out=noty );
Mux16( a=y2, b=noty, sel=ny, out=y3 );
// Perform f
Add16( a=x3, b=y3, out=addout );
And16( a=x3, b=y3, out=andout );
Mux16( a=andout, b=addout, sel=f, out=preout );
// Negate the output
Not16( in=preout, out=notpreout );
Mux16( a=preout, b=notpreout, sel=no, out=preout2 );
// zr flag
Or16Way( in=preout2, out=notzr );
Not( in=notzr, out=zr );
// ng flag
And16( a=preout2, b=true, out[15]=ng );
// Get final output
And16( a=preout2, b=preout2, out=out );
}
Для всех, кто интересуется, решение, поддерживаемое эмулятором, заключается в использовании нескольких выходов.
Mux16( a=preout, b=notpreout, sel=no, out=out,out=preout2,out[15]=ng);
Вот как я сделал АЛУ:
CHIP ALU {
IN // 16-bit inputs:
x[16], y[16],
// Control bits:
zx, // Zero the x input
nx, // Negate the x input
zy, // Zero the y input
ny, // Negate the y input
f, // Function code: 1 for add, 0 for and
no; // Negate the out output
OUT // 16-bit output
out[16],
// ALU output flags
zr, // 1 if out=0, 0 otherwise
ng; // 1 if out<0, 0 otherwise
PARTS:
Mux16(a=x, b=false, sel=zx, out=M16x);
Not16(in=M16x, out=Nx);
Mux16(a=M16x, b=Nx, sel=nx, out=M16M16x);
Mux16(a=y, b=false, sel=zy, out=M16y);
Not16(in=M16y, out=Ny);
Mux16(a=M16y, b=Ny, sel=ny, out=M16M16y);
And16(a=M16M16x, b=M16M16y, out=And16);
Add16(a=M16M16x, b=M16M16y, out=Add16);
Mux16(a=And16, b=Add16, sel=f, out=F16);
Not16(in=F16, out=NF16);
Mux16(a=F16, b=NF16, sel=no, out=out, out[15]=ng, out[0..7]=zout1, out[8..15]=zout2);
Or8Way(in=zout1, out=zr1);
Or8Way(in=zout2, out=zr2);
Or(a=zr1, b=zr2, out=zr3);
Not(in=zr3, out=zr);
}
Ты пытался:
// zr flag
Or8way(
in[0]=out[ 0], in[1]=out[ 1], in[2]=out[ 2], in[3]=out[ 3],
in[4]=out[ 4], in[5]=out[ 5], in[6]=out[ 6], in[7]=out[ 7],
out=zr1);
Or8way(
in[0]=out[ 8], in[1]=out[ 9], in[2]=out[10], in[3]=out[11],
in[4]=out[12], in[5]=out[13], in[6]=out[14], in[7]=out[15],
out=zr2);
Or( a=zr1, b=zr2, out=zr );
Я не знаю, сработает ли это, но, кажется, имеет смысл взглянуть на этот документ здесь.
Я также подумал бы дважды об использовании out в качестве имени переменной, так как это сбивает с толку, пытаясь выяснить разницу между этим и ключевым словом out (как в "out=...").
После вашего редактирования, если вы не можете подписать промежуточные значения, то, похоже, вам придется реализовать отдельный "чип", такой как IsZero16 который будет принимать 16-битное значение в качестве входа (ваш промежуточный out) и вернуть один бит, указывающий его нулевое значение, которое вы можете загрузить в zr, Или вы могли бы сделать IsZero8 чип, но вы должны были бы назвать это двумя этапами, как вы в настоящее время делаете с Or8Way,
Это похоже на правильное решение, так как вы можете добавить входные значения в чип.
И, просто глядя на ошибку, это может быть проблема, отличная от той, которую вы предлагаете. Фраза "Не удается подключить выходной контакт затвора к детали" будет означать для меня, что вы не можете подключить сигналы от выходного параметра обратно в область обработки микросхем. Это имеет смысл с электрической точки зрения.
Вы можете обнаружить, что должны сохранить выходные данные во временную переменную и использовать их для zr а также out (поскольку после того, как сигналы "отправлены" на выходные выводы микросхем, они могут перестать быть доступными).
Можем ли мы попробовать:
CHIP SetFlags16 {
IN inpval[16];
OUT zflag,nflag;
PARTS:
Or8way(in=inpval[0.. 7],out=zr0);
Or8way(in=inpval[8..15],out=zr1);
Or(a=zr0,b=zr1,out=zflag);
Not(in=inpval[15],out=nflag);
}
и затем, в вашем чипе ALU, используйте это в конце:
// Negate the output
Not16( in=preout, out=notpreout );
Mux16( a=preout, b=notpreout, sel=no, out=tempout );
// flags
SetFlags16(inpval=tempout,zflag=zr,nflag=ng);
// Transfer tempout to out (may be a better way).
Or16(a=tempout,b=tempout,out=out);
Вот еще один с новым чипом, но он чище
/**
* Negator16 - negates the input 16-bit value if the selection flag is lit
*/
CHIP Negator16 {
IN sel,in[16];
OUT out[16];
PARTS:
Not16(in=in, out=negateIn);
Mux16(a=in, b=negateIn, sel=sel, out=out);
}
CHIP ALU {
// IN and OUT go here...
PARTS:
//Zero x and y if needed
Mux16(a=x, b[0..15]=false, sel=zx, out=x1);
Mux16(a=y, b[0..15]=false, sel=zy, out=y1);
//Create x1 and y1 negations if needed
Negator16(in=x1, sel=nx, out=x2);
Negator16(in=y1, sel=ny, out=y2);
//Create x&y and x+y
And16(a=x2, b=y2, out=andXY);
Add16(a=x2, b=y2, out=addXY);
//Choose between And/Add according to selection
Mux16(a=andXY, b=addXY, sel=f, out=res);
// negate if needed and also set negative flag
Negator16(in=res, sel=no, out=res1, out=out, out[15]=ng);
// set zero flag (or all bits and negate)
Or16Way(in=res1, out=nzr);
Not(in=nzr, out=zr);
}