Обработка - анимация между двумя точками

Question

Я разрабатываю код ниже. Чтобы дать вам краткое описание, он позволяет пользователю нажимать на различные точки на экране, затем эти координаты и позиции мыши сохраняются в массиве, а также отображаются на экране. Когда пользователь нажимает enter происходит перемещение от первой точки к последней точке с использованием техники линейной интерполяции. У меня трудности с for петля как PVector v хранит координаты. Может ли кто-нибудь, пожалуйста, вести меня соответственно?

ArrayList vectors;
PVector v = new PVector();
boolean animate = false; //declare a boolean variable you can use to switch from building points to animating the movement
int FirstMouseClick; //declare an int variable to store the frameCount of the first mouseclick
int AnimationStart; //declare an int variable to store the frameCount of the animation start

void setup()  
{
  size(500, 500);
  frameRate(60);
  vectors = new ArrayList();
}

void draw()  
{
  if(!animate)//if the boolean variable animate is true
  {
    float output = frameCount - AnimationStart; // subract the animation start frameCount from the current frameCount so you know which framecount from the vectors array you should be showing
    for(int i=0; i<vectors.size(); i++) //loop through the vectors array
     //until you find the (next PVector's frameCount - frameCount of first mouseClick) > above subtraction result
    {
      v = (PVector)vectors.get(frameCount); //until you find the (next PVector's frameCount)

    }
   ellipse(v.x,v.y,10,10);// use the current pvector's xpos and ypos to draw the ellipse
  }
}

void mouseClicked()
{
  frameCount = 0; //if not yet set, set the first frameCount value
  vectors.add(new PVector(mouseX, mouseY,frameCount));// <--- store the framecount in the z axis
  ellipse(mouseX,mouseY,10,10);
  println("Mouse Coordinates are: " + vectors);
}

void keyPressed()
{
  if(keyCode == ENTER)
  {
    animate = true; //set the boolean variable animate to true
    AnimationStart = 3; //set the framecount of the animation start
  }
}

Answer 1

Я действительно не уверен, что вы пытались сделать, но если я вас правильно понял, вы захотите сделать что-то вроде этого:

• Нарисуйте несколько кружков, если пользователь нажал на холст
• Если пользователь нажал Enter, запустить анимацию
• Анимация означает: другой круг (v) движется линейно от круга к кругу

Я действительно не знаю, для чего был ваш frameCount. Может быть, вы можете добавить его в этот код проще сейчас? Обратите внимание, что вы можете добавлять новые цели, щелкая мышью, даже если анимация верна.

Вы можете сделать это:

ArrayList<PVector> vectors = new ArrayList();
PVector v = new PVector();
boolean animate = false; // true means, the circles moves
int nextTarget = 0; // defines the index of the next circle, the point is going to

void setup()  
{
  size(500, 500);
  frameRate(60);
  v = new PVector(width/2, height/2);
}

void draw() {

  // draw background to delete old drawings
  background(128);

  // show all circles
  for (int i=0; i<vectors.size(); i++) {
    fill(255);
    ellipse(vectors.get(i).x, vectors.get(i).y, 10, 10);
  }

  // if the boolean variable animate is true
  if (animate) {
    // compute angle to target circle and remaining distance
    float diffX = vectors.get(nextTarget).x - v.x;
    float diffY = vectors.get(nextTarget).y - v.y;
    float angle = atan2(diffX, diffY);

    // defines the speed of the circle
    float movement = 2;

    // compute new position of v
    v = new PVector(v.x + sin(angle)*movement, v.y + cos(angle)*movement);

    // if v reached the target circle, move on to the next one
    if (dist(v.x, v.y, vectors.get(nextTarget).x, vectors.get(nextTarget).y) < 1 && nextTarget < vectors.size()-1) {
      nextTarget++;
    }
  }
  fill(0);
  ellipse(v.x, v.y, 10, 10); // use the current pvector's xpos and ypos to draw the ellipse
}


void mouseClicked()
{
  vectors.add(new PVector(mouseX, mouseY));
  ellipse(mouseX, mouseY, 10, 10);
  println("Mouse Coordinates are: " + vectors);
}

// toggle animation mode
void keyReleased() {
  if (key == ENTER) {
    animate = !animate;
    println("animation: "+ animate);
  }
}