Cypher расходящийся и сходящийся совокупный путь

Question

У меня есть вопрос, касающийся агрегатов по нескольким путям, которые сходятся, а затем снова расходятся. Некоторые из агрегатов должны принимать во внимание только подмножество путей, а другие больше.

Я объясню это как можно лучше на примере производства продукта. Допустим, у меня есть компания, производящая 1 продукт, состоящий из некоторого материала, поставляемого поставщиком. Если быть более точным, эта компания производит 5 наименований товаров одного типа, состоящих из 10 граммов материала. Поэтому в процессе производства они использовали 50 граммов материала. Но в производстве есть материальные отходы, и они фактически использовали 70 граммов и потратили впустую 20.

То, что я хотел бы рассчитать, это скорректированный вес материала для каждого продукта и поставщика с учетом потерь. В этом случае это легко. 70g

Что происходит, когда это становится более сложным:

Теперь исправленный вес для материала1 на продукт1 и поставщика1 составляет 58,82 грамма. Это формула:

material composition = sum(production amount * product composition)
corrected weight = (production amount * product composition * 
                     (purchased / (material composition)))

т.е.

material composition = (5 * 10) + (20 * 40) = 850
corrected weight = (5 * 10 * (1000 / (850))) = 58.82

Таким образом, выполнение зашифрованного запроса в этом примере должно дать мне 6 результатов, так как это число перестановок продуктов, материалов и поставщиков.

Вопрос в том, как написать такой запрос. Я пытался уменьшить функции, повторил с, и т. Д., Но всегда кажется, что агрегирует по неправильному набору узлов...

Просто для полноты, вот шифр для создания графа:

Создайте:

create (c:Company {name:'test', id:'c1'}),  
       (p1:Product {name:'product1', id:'p1'}),  
       (p2:Product {name:'product2', id:'p2'}), 
       (m1:Material {name:'material1', id:'m1'}), 
       (m2:Material {name:'material2', id:'m2'}), 
       (s1:Supplier {name:'supplier1', id:'s1'}), 
       (s2:Supplier {name:'supplier2', id:'s2'}), 
       (s3:Supplier {name:'supplier3', id:'s3'})

Rels:

match (c:Company {id:'c1'}), 
    (p1:Product {id:'p1'}), 
    (m1:Material {id:'m1'})
    merge (c)<-[pb_r1:PRODUCED_BY {amount:5}]-(p1)-[co_r11:CONSISTS_OF {amount:10}]->(m1)
    with c, p1, m1
    match (p2:Product {id:'p2'})
    merge (c)<-[pb_r2:PRODUCED_BY {amount:20}]-(p2)-[co_r12:CONSISTS_OF {amount:40}]->(m1)
    with p1, p2, m1
    match (s1:Supplier {id:'s1'})
    merge (m1)-[pf_r1:PURCHASED_FROM {amount: 1000}]->(s1)
    with p1, p2
    match (m2:Material {id:'m2'})
    merge (p1)-[co_r21:CONSISTS_OF {amount:30}]->(m2)
    with p2, m2
    merge (p2)-[co_r22:CONSISTS_OF {amount:80}]->(m2)
    with m2
    match (s2:Supplier {id:'s2'})
    merge (m2)-[pf_r2:PURCHASED_FROM {amount: 1000}]->(s2)
    with m2
    match (s3:Supplier {id:'s3'})
    merge (m2)-[pf_r3:PURCHASED_FROM {amount: 1000}]->(s3)

Answer 1

// Selection of the supply chain and production by Company 
//
MATCH (C:Company {id:'c1'})
        <-[pb:PRODUCED_BY]-
      (P:Product)
        -[co:CONSISTS_OF]->
      (M:Material)
        -[pf:PURCHASED_FROM]->
      (S:Supplier)

// Grouping by materials, calculation material composition,
// and the preservation of the chain to the supplier
// 
WITH M,
     S, // group by supplier 
     SUM(pb.amount*co.amount) as mComp, 
     collect({
       product:P,
       prod: pb.amount, 
       comp: co.amount, 
       purchased: pf.amount
     }) as tmps

// Calculating the correct weight by material and supplier
// 
UNWIND tmps as tmp
RETURN M as material, 
       tmp['product'] as product, 
       S as supplier,
       1.0 * tmp['prod'] * tmp['comp'] * tmp['purchased'] / mComp as cWeight