MQTT код перестает работать через пару часов

Question

Сделал некоторый код для NodeMCU в Arduino IDE, чтобы нажать кнопку с помощью MQTT. Код работает отлично в течение некоторого времени, но через пару часов он больше не отвечает.

Код очень Франкенштейн, так как я мега-новичок, и выглядит следующим образом:

#include <ESP8266WiFi.h>
#include <PubSubClient.h>
#include <Servo.h>

const char* ssid = "ap_name"; //change
const char* password =  "ap_pw"; //change
const char* mqttServer = "server_ip"; //change
const int mqttPort = 1883; 
const char* mqttUser = "server_name"; //change
const char* mqttPassword = "server_pw"; //change

WiFiClient espClient;
PubSubClient client(espClient);

Servo servo;

void setup() {
  Serial.begin(115200); 
  WiFi.begin(ssid, password);

  servo.attach(D4);
  servo.write(70);

  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.println("Connecting to WiFi..");
  }
  Serial.println("Connected to the WiFi network");

  client.setServer(mqttServer, mqttPort);
  client.setCallback(callback);

  while (!client.connected()) {
    Serial.println("Connecting to MQTT...");

    if (client.connect("ESP8266Client", mqttUser, mqttPassword )) {

      Serial.println("connected");  

    } else {

      Serial.print("failed with state ");
      Serial.print(client.state());
      delay(2000);

    }
  }

  client.publish("esp/test", "Hello from ESP8266");
  client.subscribe("esp/test");

}

void callback(char* topic, byte* payload, unsigned int length) {

  Serial.print("Message arrived in topic: ");
  Serial.println(topic);

  Serial.print("Message:");
  for (int i = 0; i < length; i++) {
    Serial.print((char)payload[i]);
  }

  if(*payload == 49){
    rotServo();
    Serial.println();
    Serial.print("Roterar servo");
    delay(3000);
    client.publish("esp/test", "0");
  }

  Serial.println();
  Serial.println("-----------------------");

}

void rotServo(){
  servo.attach(D4);
  servo.write(70);
  delay(1000);
  servo.write(175);
  delay(2000);
  servo.write(70);
  delay(3000);
  servo.detach();
}

void loop() {
  client.loop();
}

Кто-нибудь знает, что может заставить его перестать работать?

Answer 1

Это может быть потому, что вы никогда не переподключитесь, если ваш клиент когда-либо будет отключен.

См. Пример здесь для получения более подробной информации, но вот функция пересоединения из примера и как она вызывается в цикле. Вам нужно будет адаптировать его под ваше приложение.

void reconnect() {
  // Loop until we're reconnected
  while (!client.connected()) {
    Serial.print("Attempting MQTT connection...");
    // Create a random client ID
    String clientId = "ESP8266Client-";
    clientId += String(random(0xffff), HEX);
    // Attempt to connect
    if (client.connect(clientId.c_str())) {
      Serial.println("connected");
      // Once connected, publish an announcement...
      client.publish("outTopic", "hello world");
      // ... and resubscribe
      client.subscribe("inTopic");
    } else {
      Serial.print("failed, rc=");
      Serial.print(client.state());
      Serial.println(" try again in 5 seconds");
      // Wait 5 seconds before retrying
      delay(5000);
    }
  }
}


void loop() {

  if (!client.connected()) {
    reconnect();
  }
  client.loop();
  ...
}

С другой стороны, хотя я не думаю, что это вызовет вашу конкретную проблему, при обратном вызове вы просто сравниваете содержимое полезной нагрузки с числом 49.

if(*payload == 49){
...
}

Вы должны проверить, является ли тема актуальной темой, которая вас интересует, и что длина также соответствует ожидаемой, прежде чем вы начнете смотреть на полезную нагрузку.