DateAdd() в специальном формате

Question

Я пробовал все способы, которые я вижу, чтобы добавить месяц к определенной дате, а затем вернуть его в определенном формате, но я в растерянности. Вот мой код, но мне нужно отформатировать его:

replace( formatdatetime( dateadd( "m" , 1 , request("date") ), 0 ) , "/" , "-" ) & "' )

request("date") в yyyyy-dd-mm hh:mm:ss формат и вот как мне нужна новая дата.

Answer 1

Следующее должно работать идеально:

replace( formatdatetime( dateadd( "m" , 1 , cDate(request("date")) ), 0 ) , "/" , "-" )

Обратите внимание на использование cDate функция для явного преобразования значения в дату.

Редактировать:

Я удалил последнюю часть вашего кода & "' )иначе это дало мне ошибку.

Answer 2

При работе с датами особенно важно заботиться о правильных (под) типах данных. Подача строки в функцию, которая ожидает дату (и полагается, что "VBScript - и ваши локальные настройки - будут делать правильные вещи") опасна.

Использование замены никогда не изменит порядок частей даты.

FormatDateTime зависит от локальных / региональных настроек и его следует избегать как верный путь к катастрофе.

Один из способов решить эту проблему + большинство других проблем, связанных с необычным форматированием в VBScript, - это использовать.Net System.Text.StringBuilder:

Учитывая Lib.vbs:

' Lib.vbs - simple VBScript library/module
' use
'  ExecuteGlobal goFS.OpenTextFile(<PathTo\Lib.vbs>).ReadAll()
' to 'include' Lib.vbs in you main script

Class ToBeAShamedOf
  Public a
  Public b
End Class ' ToBeAShamedOf

Class cFormat
  Private m_oSB
  Private Sub Class_Initialize()
    Set m_oSB = CreateObject("System.Text.StringBuilder")
  End Sub ' Class_Initialize
  Public Function formatOne(sFmt, vElm)
    m_oSB.AppendFormat sFmt, vElm
    formatOne = m_oSB.ToString()
    m_oSB.Length = 0
  End Function ' formatOne
  Public Function formatArray(sFmt, aElms)
    m_oSB.AppendFormat_4 sFmt, (aElms)
    formatArray = m_oSB.ToString()
    m_oSB.Length = 0
  End Function ' formatArray
End Class ' cFormat

и main.vbs:

' main.vbs - demo use of library/module Lib.vbs

' Globals
Dim gsLibDir : gsLibDir = ".\"
Dim goFS     : Set goFS = CreateObject("Scripting.FileSystemObject")

' LibraryInclude
ExecuteGlobal goFS.OpenTextFile(goFS.BuildPath(gsLibDir, "Lib.vbs")).ReadAll()

WScript.Quit demoDateFormat()
WScript.Quit main()

Function main()
  Dim o : Set o = New ToBeAShamedOf
  o.a = 4711
  o.b = "whatever"
  WScript.Echo o.a, o.b
  main = 1 ' can't call this a success
End Function ' main

Function demoDateFormat()
  Dim sD   : sD       = "2012-05-16 01:02:03" ' near future; not yyyyy!
  Dim dtD  : dtD      = CDate(sD)
  Dim dtDM : dtDM     = DateAdd("m", 1, dtD)
  Dim oFmt : Set oFmt = New cFormat
  WScript.Echo oFmt.formatArray( _
      "   sD: {1}{0}  dtD: {2}{0} dtDM: {3}{0}dtDM': {4}" _
    , Array(vbCrLf, sD, dtD, dtDM, oFmt.formatOne("{0:yyyy-MM-dd hh:mm:ss}", dtDM)))
  demoDateFormat = 0 ' seems to be decent
End Function ' demoDateFormat

ты получишь:

cscript main.vbs
   sD: 2012-05-16 01:02:03
  dtD: 16.05.2012 01:02:03
 dtDM: 16.06.2012 01:02:03
dtDM': 2012-06-16 01:02:03

(чтобы увидеть в контексте этого ответа)

Answer 3

Это может помочь:

FormatDateTime(DateAdd("M",1,DateSerial(Left(request("date"),4),Mid(request("date"),9,2),Mid(request("date"),6,2))) & " " & Mid(request("date"),12,8),d,0)

Он в основном преобразует строку в допустимую дату в собственном формате, добавляет 1 запрошенный месяц и затем перестраивает строку.

ПРИМЕЧАНИЕ: request("date") выглядит так, как будто он возвращает текущее значение даты / времени, поэтому его выполнение таким образом может сгенерировать конечное значение, равное секунде или около того, если это проблема, тогда вам лучше будет хранить статическое значение в переменная, в противном случае это должно быть хорошо.