Создать экземпляр для класса (находится в B.vbs) из другого файла.VBS

Question

У меня есть 2 VBS файлы.

A.vbs:

Class test
  public a
  public b
End Class

B.vbs:

Dim objShell
Set objShell = Wscript.CreateObject("WScript.Shell")
objShell.Run "C:\Users\shanmugavel.chinnago\Desktop\Test3.vbs" 

Dim ins
Set ins = new test 'Here throws "Class not defined: test"
ins.a = 10
ins.b = "SCS"

msgbox ins.a
msgbox ins.b

Теперь я хочу добиться этого, как в файле B.vbs. Но он выдает ошибку при создании экземпляра для класса, доступного в A.vbs. Любая помощь?

Answer 1

,Запуск ning.vbs не сделает код пригодным для использования в другом. Простая, но расширяемая стратегия - использовать.ExecuteGlobal для "библиотек". Дано

Lib.vbs:

' Lib.vbs - simple VBScript library/module
' use
'  ExecuteGlobal goFS.OpenTextFile(<PathTo\Lib.vbs>).ReadAll()
' to 'include' Lib.vbs in you main script

Class ToBeAShamedOf
  Public a
  Public b
End Class ' ToBeAShamedOf

и main.vbs:

' main.vbs - demo use of library/module Lib.vbs

' Globals
Dim gsLibDir : gsLibDir = ".\"
Dim goFS     : Set goFS = CreateObject("Scripting.FileSystemObject")

' LibraryInclude
ExecuteGlobal goFS.OpenTextFile(goFS.BuildPath(gsLibDir, "Lib.vbs")).ReadAll()

WScript.Quit main()

Function main()
  Dim o : Set o = New ToBeAShamedOf
  o.a = 4711
  o.b = "whatever"
  WScript.Echo o.a, o.b
  main = 1 ' can't call this a success
End Function ' main

ты получишь:

cscript main.vbs
4711 whatever

(см. этот ответ для семени полезного класса)

Answer 2

Ваш b-скрипт не имеет связи с youyr-сценарием, вам нужно включить код, подобный этому, тогда вы можете использовать код, подобный тому, который был представлен в b

call Include("a.vbs")

Sub Include (Scriptnaam)
  Dim oFile
  Set oFile = oFso.OpenTextFile(Scriptnaam)
  ExecuteGlobal oFile.ReadAll()
  oFile.Close
End Sub

Answer 3

Это код, который мы используем для этого.

Sub Include(sInstFile)
    Dim f, s, oFSO
    Set oFSO = CreateObject("Scripting.FileSystemObject")
    On Error Resume Next
    If oFSO.FileExists(sInstFile) Then
        Set f = oFSO.OpenTextFile(sInstFile)
        s = f.ReadAll
        f.Close
        ExecuteGlobal s
    End If
    On Error Goto 0
    Set f = Nothing
    Set oFSO = Nothing
End Sub

Include("c:\files\SSDConnection.vbs")
Include("c:\files\SSDTable.vbs")

Работает безупречно для нашей команды

Answer 4

Вы можете преобразовать B.vbs в файл сценариев Windows, который позволит вам включить A.vbs.