Есть ли лучшее назначение с двойной точностью в Fortran 90?

В Fortran 90 (использующем gfortran в Mac OS X), если я присваиваю значение переменной двойной точности без явного указания вида, точность не "принимает". Что я имею в виду, если я запускаю следующую программу:

program sample_dp

implicit none

integer, parameter :: sp = kind(1.0)
integer, parameter :: dp = kind(1.0d0)

real(sp) :: a = 0.
real(dp) :: b = 0., c = 0., d = 0.0_dp, e = 0_dp

! assign values
a = 0.12345678901234567890
b = 0.12345678901234567890
c = DBLE(0.12345678901234567890)
d = 0.12345678901234567890_dp

write(*,101) a, b, c, d
101 format(1x, 'Single precision: ',  T27, F17.15, / &
           1x, 'Double precisison: ', T27, F17.15, / &
           1x, 'Double precision (DBLE): ', T27, F17.15, / &
           1x, 'Double precision (_dp): ',  T27, F17.15)

end program

Я получаю результат:

Single precision:        0.123456791043282
Double precision:        0.123456791043282
Double precision (DBLE): 0.123456791043282
Double precision (_dp):  0.123456789012346

Результат с одинарной точностью начинает округляться с восьмым десятичным знаком, как и ожидалось, но только переменная двойной точности, которую я явно назначил с помощью _dp, сохраняет все 16 цифр точности. Это кажется странным, так как я ожидаю (я относительно новичок в Фортране), что переменная двойной точности автоматически будет двойной точности. Есть ли лучший способ назначить переменные двойной точности, или я должен явно ввести их, как указано выше?

Источник

2 ответа

Решение

Реальное, которое не помечено как двойная точность, будет считаться одинарным. То, что через некоторое время вы присваиваете переменную двойной точности или конвертируете ее в двойную точность, это не означает, что значение "волшебным образом" будет иметь двойную точность. Он не смотрит вперед, чтобы увидеть, как будет использоваться значение.

Источник

Здесь есть несколько вопросов, связывающих друг с другом, поэтому лучше изложить некоторые детали с примерами, особенно для начинающих.

Как утверждает MRAB в своем правильном ответе, выражение всегда оценивается без какого-либо контекста, поэтому

 0.12345678901234567890

является плавающим литералом точности (одинарной) по умолчанию, независимо от того, где он появляется. То же самое относится к числам с плавающей запятой в экспоненциальной форме

 0.12345678901234567890E0

это также число точности по умолчанию.

Если вы хотите использовать константу двойной точности, вы можете использовать D вместо E в вышеуказанной форме. Даже если такая константа двойной точности присваивается переменной точности по умолчанию, она сначала обрабатывается как число двойной точности, а затем преобразуется в точность по умолчанию.

То, как вы используете в своем вопросе (с использованием добрых обозначений и нескольких добрых констант), является более общим и более современным, но принцип тот же.

 0.12345678901234567890_sp

это ряд добрых sp а также

 0.12345678901234567890_dp

это ряд добрых dp и не важно, где они появляются.

Как показывает ваш пример, речь идет не только о назначении. В соответствии

 c = DBLE(0.12345678901234567890)

первый номер 0.12345678901234567890 точность по умолчанию. Затем он преобразуется в двойную точность DBLE, но это делается после того, как некоторые цифры уже потеряны. Затем этот новый номер двойной точности присваивается c,

Источник
Другие вопросы по тегам