Сбой при взаимодействии CUDA/OGL

Question

Я пытаюсь настроить небольшой пример взаимодействия CUDA/GL. Я посмотрел в Интернете, поэтому я нашел несколько учебных пособий с некоторыми полезными вещами.

Все, что я хочу - это создать текстуру в CUDA и нарисовать ее с помощью OpenGL.

Источник, который у меня сейчас есть, - это сбой моего Macbook Pro каждый раз, когда я его запускаю, поэтому я подумал, что, если кто-то сможет на это взглянуть, это будет очень полезно.

    #include <stdlib.h>
    #include <stdio.h>
    #include <string.h>
    #include <math.h>

    #ifdef _WIN32
    #  define WINDOWS_LEAN_AND_MEAN
    #  define NOMINMAX
    #  include <windows.h>
    #endif

    // OpenGL Graphics includes
    #include <GL/glew.h>
    #if defined (__APPLE__) || defined(MACOSX)
    #include <GLUT/glut.h>
    #else
    #include <GL/freeglut.h>
    #endif

    // includes, cuda
    #include <cuda_runtime.h>
    #include <cuda_gl_interop.h>

    // Utilities and timing functions
    #include <helper_functions.h>    // includes cuda.h and cuda_runtime_api.h
    #include <timer.h>               // timing functions

    // CUDA helper functions
    #include <helper_cuda.h>         // helper functions for CUDA error check
    #include <helper_cuda_gl.h>      // helper functions for CUDA/GL interop

    #include <vector_types.h>
     const unsigned int window_width  = 512;
     const unsigned int window_height = 512;
    GLuint viewGLTexture;
    cudaGraphicsResource_t viewCudaResource;

    void initGLandCUDA() {
         int argc = 0;
         char** argv = NULL;
         glutInit(&argc, argv);
         glutInitDisplayMode(GLUT_RGBA | GLUT_DOUBLE);
         glutInitWindowSize(window_width, window_height);
         glutCreateWindow("CUDA GL Interop");

         glewInit();

         glEnable(GL_TEXTURE_2D);
         glGenTextures(1, &viewGLTexture);
         glBindTexture(GL_TEXTURE_2D, viewGLTexture);
         {
             glTexParameteri(GL_TEXTURE_2D, GL_TEXTURE_MIN_FILTER, GL_NEAREST);
             glTexParameteri(GL_TEXTURE_2D, GL_TEXTURE_MAG_FILTER, GL_NEAREST);
             glTexImage2D(GL_TEXTURE_2D, 0, GL_RGBA, 512, 512, 0, GL_RGBA, GL_UNSIGNED_BYTE, NULL);
         }
         glBindTexture(GL_TEXTURE_2D, 0);

         cudaGLSetGLDevice(gpuGetMaxGflopsDeviceId());
         cudaGraphicsGLRegisterImage(&viewCudaResource, viewGLTexture, GL_TEXTURE_2D,     cudaGraphicsRegisterFlagsWriteDiscard);
    }    


    __global__ void renderingKernel(cudaSurfaceObject_t image) {
         unsigned int x = blockIdx.x*blockDim.x + threadIdx.x;
         unsigned int y = blockIdx.y*blockDim.y + threadIdx.y;

         uchar4 color = make_uchar4(0.f, 0.f, 0.f, .3f);
         //if I write in 0, 0 and not x,y, the computer is not crashing, but there is no black pixel at 0,0
         surf2Dwrite(color, image, x, y, cudaBoundaryModeClamp);
    }


    void callCUDAKernel(cudaSurfaceObject_t image) {
         dim3 block(8, 1, 1);
         dim3 grid(8, 1, 1);
         renderingKernel<<< grid, block>>>(image);
    }

     void renderFrame() {
        cudaGraphicsMapResources(1, &viewCudaResource);
        {
            cudaArray_t viewCudaArray;
            checkCudaErrors(cudaGraphicsSubResourceGetMappedArray(&viewCudaArray, viewCudaResource, 0, 0));
            cudaResourceDesc viewCudaArrayResourceDesc;
            {
                viewCudaArrayResourceDesc.resType = cudaResourceTypeArray;
                viewCudaArrayResourceDesc.res.array.array = viewCudaArray;
            }
            cudaSurfaceObject_t viewCudaSurfaceObject;
            checkCudaErrors(cudaCreateSurfaceObject(&viewCudaSurfaceObject, &viewCudaArrayResourceDesc));

            callCUDAKernel(viewCudaSurfaceObject);

            checkCudaErrors(cudaDestroySurfaceObject(viewCudaSurfaceObject));
        }
        checkCudaErrors(cudaGraphicsUnmapResources(1, &viewCudaResource));
        checkCudaErrors(cudaStreamSynchronize(0));

        glBindTexture(GL_TEXTURE_2D, viewGLTexture);
        {
            glBegin(GL_QUADS);
            {
                 glTexCoord2f(0.0f, 0.0f); glVertex2f(-1.0f, -1.0f);
                 glTexCoord2f(1.0f, 0.0f); glVertex2f(+1.0f, -1.0f);
                 glTexCoord2f(1.0f, 1.0f); glVertex2f(+1.0f, +1.0f);
                 glTexCoord2f(0.0f, 1.0f); glVertex2f(-1.0f, +1.0f);
            }
            glEnd();
         }
         glBindTexture(GL_TEXTURE_2D, 0);
         glFinish();
    }

    int main(int argc, char **argv)
    {
         initGLandCUDA();

        glutDisplayFunc(renderFrame);
        //glutKeyboardFunc(keyboard);
        //glutMouseFunc(mouse);
        glutMainLoop();
    }

Кажется, это какая-то ошибка, выходящая за пределы допустимого диапазона, но у меня нет идей (кстати, это cc 3.0, работающий на nVidia 650M).

Изменить: под сбой я имею в виду: сбой. Компьютер зависает. Я не могу двигать мышью, и мне нужно перезагрузить компьютер.

Да, я посмотрел во всех примерах, они не совсем то, что я хочу. Меняя их, чтобы хотеть, я хочу результатов в этой проблеме. Если бы была какая-либо другая помощь в руководстве или где-либо еще, которая могла бы помочь мне, и я обнаружил, что я не потрудился бы обратиться за помощью. Вам нужно связаться с cuda_runtime и перенасыщенными библиотеками

Answer 1

Ниже приведена рабочая версия вашего кода. Проблемы в вашем коде были:

• Ваше ядро ​​зависело от запуска с потоками 512x512, но вы запускали только с потоками 64x1.

• Ваше ядро ​​записывало на невыровненные адреса с помощью surf2Dwrite().

• Вы настраивали двойную буферизацию в OpenGL, но не меняли буферы. (glutSwapBuffers()).

• Вы инициализировали uchar4 с поплавками.

#include <stdlib.h>
#include <stdio.h>
#include <string.h>
#include <math.h>

#ifdef _WIN32
#  define WINDOWS_LEAN_AND_MEAN
#  define NOMINMAX
#  include <windows.h>
#endif

// OpenGL Graphics includes
#include <GL/glew.h>
#if defined (__APPLE__) || defined(MACOSX)
#include <GLUT/glut.h>
#else
#include <GL/freeglut.h>
#endif

#include <cuda_runtime.h>
#include <cuda_gl_interop.h>

#include <vector_types.h>
const unsigned int window_width  = 512;
const unsigned int window_height = 512;

GLuint viewGLTexture;
cudaGraphicsResource_t viewCudaResource;

#define check(ans) { _check((ans), __FILE__, __LINE__); }
inline void _check(cudaError_t code, char *file, int line)
{
  if (code != cudaSuccess) {
    fprintf(stderr,"CUDA Error: %s %s %d\n", cudaGetErrorString(code), file, line);
    exit(code);
  }
}

void initGLandCUDA() {
  int argc = 0;
  char** argv = NULL;
  glutInit(&argc, argv);
  glutInitDisplayMode(GLUT_RGBA);
  glutInitWindowSize(window_width, window_height);
  glutCreateWindow("CUDA GL Interop");

  glewInit();

  glEnable(GL_TEXTURE_2D);
  glGenTextures(1, &viewGLTexture);
  glBindTexture(GL_TEXTURE_2D, viewGLTexture);

  glTexParameteri(GL_TEXTURE_2D, GL_TEXTURE_MIN_FILTER, GL_NEAREST);
  glTexParameteri(GL_TEXTURE_2D, GL_TEXTURE_MAG_FILTER, GL_NEAREST);
  glTexImage2D(GL_TEXTURE_2D, 0, GL_RGBA, window_width, window_height, 0, GL_RGBA, GL_UNSIGNED_BYTE, NULL);
  glBindTexture(GL_TEXTURE_2D, 0);

  check(cudaGLSetGLDevice(0));

  check(cudaGraphicsGLRegisterImage(&viewCudaResource, viewGLTexture, GL_TEXTURE_2D, cudaGraphicsRegisterFlagsWriteDiscard));
}    


__global__ void renderingKernel(cudaSurfaceObject_t image) {
  unsigned int x = blockIdx.x * blockDim.x + threadIdx.x;
  unsigned int y = blockIdx.y * blockDim.y + threadIdx.y;

  uchar4 color = make_uchar4(x / 2, y / 2, 0, 127);
  surf2Dwrite(color, image, x * sizeof(color), y, cudaBoundaryModeClamp);
}


void callCUDAKernel(cudaSurfaceObject_t image) {
  dim3 block(256, 1, 1);
  dim3 grid(2, 512, 1);
  renderingKernel<<<grid, block>>>(image);
  check(cudaPeekAtLastError());
  check(cudaDeviceSynchronize());
}

void renderFrame() {
  check(cudaGraphicsMapResources(1, &viewCudaResource));

  cudaArray_t viewCudaArray;
  check(cudaGraphicsSubResourceGetMappedArray(&viewCudaArray, viewCudaResource, 0, 0));

  cudaResourceDesc viewCudaArrayResourceDesc;
  memset(&viewCudaArrayResourceDesc, 0, sizeof(viewCudaArrayResourceDesc));
  viewCudaArrayResourceDesc.resType = cudaResourceTypeArray;
  viewCudaArrayResourceDesc.res.array.array = viewCudaArray;

  cudaSurfaceObject_t viewCudaSurfaceObject;
  check(cudaCreateSurfaceObject(&viewCudaSurfaceObject, &viewCudaArrayResourceDesc));

  callCUDAKernel(viewCudaSurfaceObject);

  check(cudaDestroySurfaceObject(viewCudaSurfaceObject));

  check(cudaGraphicsUnmapResources(1, &viewCudaResource));

  check(cudaStreamSynchronize(0));

  glBindTexture(GL_TEXTURE_2D, viewGLTexture);
  {
    glBegin(GL_QUADS);
    {
      glTexCoord2f(0.0f, 0.0f); glVertex2f(-1.0f, -1.0f);
      glTexCoord2f(1.0f, 0.0f); glVertex2f(+1.0f, -1.0f);
      glTexCoord2f(1.0f, 1.0f); glVertex2f(+1.0f, +1.0f);
      glTexCoord2f(0.0f, 1.0f); glVertex2f(-1.0f, +1.0f);
    }
    glEnd();
  }
  glBindTexture(GL_TEXTURE_2D, 0);
  glFinish();
}

int main(int argc, char **argv)
{
  initGLandCUDA();

  glutDisplayFunc(renderFrame);
  //glutKeyboardFunc(keyboard);
  //glutMouseFunc(mouse);
  glutMainLoop();
}

Выход: