Flash Player 11 проверить ускорение графического процессора

Question

С флеш-плеером 11 появилось ускорение 3D GPU, но не каждая видеокарта может выполнить эту работу, а при отсутствии поддержки ускорение видеокарты переключается на программное обеспечение. Могу ли я проверить, доступно ли аппаратное ускорение, чтобы настроить мое приложение?

Answer 1

Вы должны получить Context3D чтобы посмотреть это driverInfo:

trace("3d mode: " + context3D.driverInfo);

Для меня это означает:

Проще всего проверить программный рендеринг, аппаратно ускоренный графический процессор будет обозначен DirectX или OpenGL.

Это может быть реализовано так:

package
{
    import flash.display.Sprite;
    import flash.display.Stage3D;
    import flash.display3D.Context3D;
    import flash.display3D.Context3DRenderMode;
    import flash.events.Event;
    import flash.system.ApplicationDomain;
    import flash.system.Capabilities;

    public class X extends Sprite
    {
        public function X()
        {
            super();

            if (ApplicationDomain.currentDomain.hasDefinition("flash.display.Stage3D"))
            {
                stage.stage3Ds[0].addEventListener(Event.CONTEXT3D_CREATE, onContext3DCreate);
                stage.stage3Ds[0].requestContext3D();
            }
        }

        private function onContext3DCreate(event:Event):void
        {
            // obtain context
            var t:Stage3D = event.target as Stage3D;
            var context3D:Context3D = t.context3D;

            // detect software mode
            if ((context3D.driverInfo == Context3DRenderMode.SOFTWARE)
                || (context3D.driverInfo.indexOf('oftware') > -1))
            {
                trace("Software mode detected!");
            }

            trace("Flash Version: " + Capabilities.version);
            trace("3D mode: " + context3D.driverInfo);
        }

    }
}

Для ускоренного графического процессора StageVideo, вы слушаете StageVideoAvailabilityEvent подтвердить StageVideoAvailability.AVAILABLE,

Это может быть реализовано как:

package
{
    import flash.display.Sprite;
    import flash.events.StageVideoAvailabilityEvent;
    import flash.media.StageVideoAvailability;

    public class X extends Sprite
    {
        public function X()
        {
            super();
            stage.addEventListener(StageVideoAvailabilityEvent.STAGE_VIDEO_AVAILABILITY, onStageVideoState);
        }

        private function onStageVideoState(event:StageVideoAvailabilityEvent):void
        {
            if (event.availability == StageVideoAvailability.AVAILABLE)
                trace("available");
        }

    }
}

Когда у вас есть StageVideo, состояние рендеринга обозначается StageVideoEvent.RENDER_STATE,

var stageVideo = stage.stageVideos[0];
stageVideo.addEventListener(StageVideoEvent.RENDER_STATE, stageVideoStateChange);

function stageVideoStateChange(event:StageVideoEvent):void
{   
    trace("Render State: " + event.status);
}

Состояние рендеринга определяется StageVideoEvent.status и включает в себя:

• VideoStatus.ACCELERATED - Декодирование и представление происходят на аппаратном уровне. (Лучшее представление.)
• VideoStatus.SOFTWARE - Презентация в аппаратном обеспечении, декодирование в программном обеспечении. (Приемлемая производительность.)
• VideoStatus.UNAVAILABLE - Нет ресурсов GPU для обработки видео, и ничего не отображается. Возврат к видео объекту.