Плавная интерполяция между двумя точками

Question

Я пытаюсь интерполировать в сетке между точками. Я провел небольшое исследование и нашел несколько решений, но все они дают странные результаты для меня. Я попробовал Cosinus и Cubic интерполяцию, но целая сетка получает крошечные волны вместо того, чтобы быть гладкой.

Я пробовал это

 mu2 = mu*mu;
   a0 = y3 - y2 - y0 + y1;
   a1 = y0 - y1 - a0;
   a2 = y2 - y0;
   a3 = y1;

   return(a0*mu*mu2+a1*mu2+a2*mu+a3);

отсюда: http://paulbourke.net/miscellaneous/interpolation/

Я получил все очки, которые мне нужны, и все должно работать, но это не так. Я потратил много времени на его отладку, и единственная проблема, с которой я столкнулся, это то, что кажется, что mu (обычный t от 0.0 - 1.0 в интерполяции) начинается с 0.0 в P1, как и должно быть, но в 1.0 это в P3, в то время как это должно быть в P2 (точки P0, P1, P2, P3, где интерполяция должна происходить между P1 и P2)

Если есть какой-либо другой, более простой способ сделать интерполяцию между двумя точками, пожалуйста, дайте мне знать. Я не хочу делать кривые Безье или что-то подобное с контрольными точками. У меня просто есть две точки, и я могу использовать еще одну точку на каждой стороне, как в примере выше.

Спасибо за любую помощь, Люк

Answer 1

Похоже, что сплайн Catmull-Rom подойдет для ваших данных.

В качестве примера реализации этого в VB.NET:

Module Module1

    ''' <summary>
    ''' A class for a 2-D point and operations on it.
    ''' </summary>
    Class PointD
        Property X As Double
        Property Y As Double

        Public Shared Operator +(p1 As PointD, p2 As PointD) As PointD
            Return New PointD(p1.X + p2.X, p1.Y + p2.Y)
        End Operator

        Public Shared Operator -(p As PointD) As PointD
            Return New PointD(-p.X, -p.Y)
        End Operator

        Public Shared Operator -(p1 As PointD, p2 As PointD) As PointD
            Return New PointD(p1.X - p2.X, p1.Y - p2.Y)
        End Operator

        Public Shared Operator *(a As Double, p As PointD) As PointD
            Return New PointD(a * p.X, a * p.Y)
        End Operator

        Public Shared Operator *(p As PointD, a As Double) As PointD
            Return New PointD(a * p.X, a * p.Y)
        End Operator

        'TODO: (Optional) Add methods for magnitude, cross product and dot product.

        Public Sub New()
            ' empty contructor
        End Sub

        Public Sub New(x As Double, y As Double)
            Me.X = x
            Me.Y = y
        End Sub

        Public Overrides Function ToString() As String
            ' use the N3 format string for tidiness in this example
            Return $"({X:N3}, {Y:N3})"
        End Function

    End Class

    ''' <summary>
    ''' Ordinary Catmull-Rom interpolation.
    ''' </summary>
    ''' <param name="t">Vary from 0.0 to 1.0 to get an interpolated point between data points p1 and p2.</param>
    ''' <param name="p0">The first control point.</param>
    ''' <param name="p1">The first data point.</param>
    ''' <param name="p2">The second data point.</param>
    ''' <param name="p3">The second control point.</param>
    ''' <returns>The interpolated point.</returns>
    Function CatmullRomInterpolate(t As Double, p0 As PointD, p1 As PointD, p2 As PointD, p3 As PointD) As PointD
        ' this is the regular Catmull-Rom spline
        ' other ways of treating it can be found at:
        ' https://stackru.com/questions/9489736/catmull-rom-curve-with-no-cusps-And-no-self-intersections
        Return 0.5 * ((2 * p1) +
            t * (p2 - p0) +
            Math.Pow(t, 2) * (2 * p0 - 5 * p1 + 4 * p2 - p3) +
            Math.Pow(t, 3) * (3 * (p1 - p2) + p3 - p0))

    End Function


    Sub Main()
        ' some sample data which will produce a symmetrical wave shape...
        Dim p0 As New PointD(-1, 1)
        Dim p1 As New PointD(0, 0)
        Dim p2 As New PointD(1, 0)
        Dim p3 As New PointD(2, -1)

        For t = 0.0 To 1.0 Step 0.1
            Console.WriteLine(CatmullRomInterpolate(t, p0, p1, p2, p3))
        Next

        Console.ReadLine()

    End Sub

End Module

В зависимости от того, что вам нужно, вы можете найти кривую Catmull-rom без острых выступов и самопересечений.