Emacs Lisp: Как добавить папку и все ее подпапки первого уровня в путь загрузки

Question

Если у меня есть структура папок, настроенная так:

~/Projects
    emacs
        package1
            package1-helpers
        package2
            package2-helpers
            package2-more-helpers
        package3
            package3-helpers

Как мне добавить эти папки:

• ~ / Проекты / Emacs
• ~ / Проекты / Emacs / package1
• ~ / Проекты / Emacs / package2
• ~ / Проекты / Emacs / упаковке3

... к load-path из моего файла.emacs?

Мне в основном нужна короткая автоматическая версия этого кода:

(add-to-list 'load-path "~/Projects/emacs")
(add-to-list 'load-path "~/Projects/emacs/package1")
(add-to-list 'load-path "~/Projects/emacs/package2")
(add-to-list 'load-path "~/Projects/emacs/package3")

Answer 1

(let ((base "~/Projects/emacs"))
  (add-to-list 'load-path base)
  (dolist (f (directory-files base))
    (let ((name (concat base "/" f)))
      (when (and (file-directory-p name) 
                 (not (equal f ".."))
                 (not (equal f ".")))
        (add-to-list 'load-path name)))))

Answer 2

Вот что я использую в своем.emacs:

(let* ((my-lisp-dir "~/.elisp/")
       (default-directory my-lisp-dir)
       (orig-load-path load-path))
  (setq load-path (cons my-lisp-dir nil))
  (normal-top-level-add-subdirs-to-load-path)
  (nconc load-path orig-load-path))

Если вы посмотрите на описание normal-top-level-add-subdirs-to-load-path, то будет разумно выбрать, какие каталоги исключить.

Answer 3

Я предлагаю вам использовать subdirs.el

Answer 4

Это моя взломанная версия:P

(defun add-to-list-with-subdirs (base exclude-list include-list)
  (dolist (f (directory-files base))
 (let ((name (concat base "/" f)))
   (when (and (file-directory-p name)
     (not (member f exclude-list)))
  (add-to-list 'load-path name)
  (when (member f include-list)
   (add-to-list-with-subdirs name exclude-list include-list)))))
  (add-to-list 'load-path base))

Это добавит все каталоги первого уровня из базы и исключит их из списка исключений, в то время как для каталогов в include-списке также будут добавлены все каталоги первого уровня этого каталога.

(add-to-list-with-subdirs "~/.emacs.d" '("." ".." "backup") '("vendor" "my-lisp"))

Answer 5

Устанавливать dash а также f сторонние библиотеки. Ваша необходимая функция f-directories:

(f-directories "~/YOURDIR") ; return only immediate directories
(f-directories "~/YOURDIR" nil t) ; all directories recursively

Тогда используйте --each добавить каждый найденный каталог в load-path, Вся эта операция работает в O(n²), но как load-path обычно супер-маленький, кого это волнует.

(add-to-list 'load-path "~/YOURDIR") ; your parent folder itself
(--each (f-directories "~/YOURDIR") (add-to-list 'load-path it))

Answer 6

Эта функция отобразит подпапки и файлы первого уровня в BASE-PATH и добавит их в LOAD-LIST, если это каталог (исключая каталоги "." И "..").

(defun add-subdirs-to-load-path (base-path)
  "Adds first level subfolders to LOAD-PATH.
BASE-PATH must not end with a '/'"
  (mapc (lambda (attr)
          (let ((name (car attr))
                (folder-p (cadr attr)))
            (unless (or (not folder-p)
                        (equal name ".")
                        (equal name ".."))
              (add-to-list 'load-path (concat base-path "/" name)))))
        (directory-files-and-attributes base-path)))