AS3 RTMP видео поток на локальном хосте Red5 проблема пути

Question

Ниже приведен основной бит кода в as3 flash. Простой пример потокового видео с использованием rtmp red5. Но у меня, похоже, возникают проблемы с подключением к потоку. Я использую те же видеофайлы, что и при установке демонстрационной версии сервера red5.(Я проверил установленную демонстрацию ofla, запустив ее правильно), моя трассировка вывода прослеживается как соединение Успех и начало воспроизведения видео файла. Но я не могу получить его метаданные или заставить его играть.

netStatusHandler NetConnection.Connect.Success

netStatusHandler NetStream.Play.Reset

netStatusHandler NetStream.Play.Start

что мне здесь не хватает в отношении указания пути к видеофайлу? они находятся в той же папке примера демонстрации, которая поставляется с установкой по умолчанию red5.

package 
{
    import flash.display.*;
    import flash.events.*;
    import flash.media.*;
    import flash.net.*



    public class NetConnectionExample extends MovieClip
    {
        private var videoURL:String = "rtmp://localhost/oflaDemo/streams";
        private var connection:NetConnection;
        private var stream:NetStream;
        public function NetConnectionExample()
        {
            // constructor code
            connection = new NetConnection();
            connection.addEventListener(NetStatusEvent.NET_STATUS, netStatusHandler);
            connection.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            connection.connect(videoURL, true);
        }
        private function netStatusHandler(event:NetStatusEvent):void
        {
            trace("netStatusHandler",event.info.code);
            switch (event.info.code)
            {
                case "NetConnection.Connect.Success":
                    connectStream();
                    break;
                case "NetStream.Play.StreamNotFound":
                    trace("Stream not found: " + videoURL);
                    break;
                case "NetStream.Play.Start":
                break;
            }
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void
        {
            trace("securityErrorHandler: " + event);
        }

        private function connectStream():void
        {
            stream = new NetStream(this.connection);
            stream.addEventListener(NetStatusEvent.NET_STATUS, netStatusHandler);
            stream.addEventListener(AsyncErrorEvent.ASYNC_ERROR, asyncErrorHandler)
            stream.client = new CustomClient();
            var video:Video = new Video();
            video.attachNetStream(stream);
            stream.play(videoURL+"avatar.flv");
            addChild(video);
        }
        function asyncErrorHandler(event:AsyncErrorEvent):void {
            // ignore AsyncErrorEvent events.
        }

    }
}

class CustomClient {
public function onMetaData(info:Object):void
{
    trace("metadata: duration=" + info.duration + " width=" + info.width + " height=" + info.height + " framerate=" + info.framerate);
}
public function onCuePoint(info:Object):void
{
    trace("cuepoint: time=" + info.time + " name=" + info.name + " type=" + info.type);
}
}

Изменить: Связанные Где я могу разместить FLV-файл для потоковой передачи на локальный сервер Red5?

Answer 1

Это был вопрос пути. папка rtmp video приложения с именем oflaDemo называется streams. давая путь так

 private var videoURL:String = "rtmp://localhost/oflaDemo";

и непосредственно имя файла после подключения потока. работает

 stream.play("avatar.flv");