PL/SQL - Создать таблицы на основе курсора, используя команду "Выполнить немедленно"?

Я написал следующий код, который выбирает некоторые тестовые данные учащихся и, используя курсор, вставляет их в таблицу. То, что вы хотели бы сделать, это создать одну таблицу для каждого учащегося и вставить относительные данные. Это может быть одна строка или несколько строк.

SET SERVEROUTPUT ON

CREATE OR REPLACE PROCEDURE run_student_scores 

  IS

  CURSOR c_pass_fail_cursor
    IS
  SELECT students.firstname,
      test_history.score,
      test_id.test_name,
      test_id.passing_grade
  FROM students
  INNER JOIN test_history
    ON students.student_id = test_history.student_id
  INNER JOIN test_id
    ON test_id.test_id = test_history.test_id
    WHERE test_history.start_time BETWEEN to_timestamp(sysdate) + INTERVAL '8' HOUR 
      AND to_timestamp(sysdate) + INTERVAL '21' HOUR;

v_name    students.firstname%TYPE;
v_score   test_history.score%TYPE;
v_test    varchar2(40);
v_passing test_id.passing_grade%TYPE;
v_result  varchar2(4);

BEGIN

  EXECUTE IMMEDIATE ('create table student_tests_' || (to_char(sysdate, 'yyyymmdd')) ||     '(student_name VARCHAR2(20), test_name varchar2(40), test_score NUMBER(3), pass_rate     NUMBER(3), pass_fail VARCHAR2(4))');

OPEN c_pass_fail_cursor;
 LOOP
FETCH c_pass_fail_cursor INTO v_name, v_score, v_test, v_passing;
EXIT WHEN c_pass_fail_cursor%NOTFOUND;
If v_score < v_passing 
  THEN v_result := 'Fail';
    DBMS_OUTPUT.PUT_LINE(v_name || ' ' || v_score || ' ' || v_test || ' ' || V_passing || ' ' || 'Result =' || v_result);
ELSE
  v_result := 'Pass';
  DBMS_OUTPUT.PUT_LINE(v_name || ' ' || v_score || ' ' || v_test || ' ' || V_passing || ' ' || 'Result =' || v_result);
END IF;

EXECUTE IMMEDIATE 'INSERT INTO student_tests_' || (to_char(sysdate, 'yyyymmdd')) || ' ' || ' values(:1, :2, :3, :4, :5)' using v_name, v_test, v_score, v_passing, v_result;

END LOOP;

CLOSE c_pass_fail_cursor; 

END;
/

Я играл с этим последние пару дней и не могу заставить его работать. Самое близкое, что я могу получить, - это создать таблицы и вставить только первую строку, генерируя ошибку, когда цикл пытается создать таблицу, которая уже существует.

Любая помощь будет потрясающей

Спасибо ребята

Бен

Источник

2 ответа

Результат: 1 таблица на каждого учащегося (уникальная по имени).

create table ... теперь внутри цикла, окруженного блоком исключения. Если таблица уже существует, исключение (ORA-00955) обрабатывается.

SET SERVEROUTPUT ON

CREATE OR REPLACE PROCEDURE run_student_scores 

IS

  CURSOR c_pass_fail_cursor
    IS
  SELECT students.firstname,
      test_history.score,
      test_id.test_name,
      test_id.passing_grade
  FROM students
  INNER JOIN test_history
    ON students.student_id = test_history.student_id
  INNER JOIN test_id
    ON test_id.test_id = test_history.test_id
    WHERE test_history.start_time BETWEEN to_timestamp(sysdate) + INTERVAL '8' HOUR 
      AND to_timestamp(sysdate) + INTERVAL '21' HOUR;

v_name    students.firstname%TYPE;
v_score   test_history.score%TYPE;
v_test    varchar2(40);
v_passing test_id.passing_grade%TYPE;
v_result  varchar2(4);

    --New variables
    table_already_exists EXCEPTION;
    PRAGMA EXCEPTION_INIT(table_already_exists, -955);
BEGIN

OPEN c_pass_fail_cursor;
 LOOP
FETCH c_pass_fail_cursor INTO v_name, v_score, v_test, v_passing;
EXIT WHEN c_pass_fail_cursor%NOTFOUND;

    begin
        EXECUTE IMMEDIATE ('create table student_tests_' || v_name  || ' (student_name VARCHAR2(20), test_name varchar2(40), test_score NUMBER(3), pass_rate     NUMBER(3), pass_fail VARCHAR2(4))');
    exception when table_already_exists then
        null;
    end;

If v_score < v_passing 
  THEN v_result := 'Fail';
    DBMS_OUTPUT.PUT_LINE(v_name || ' ' || v_score || ' ' || v_test || ' ' || V_passing || ' ' || 'Result =' || v_result);
ELSE
  v_result := 'Pass';
  DBMS_OUTPUT.PUT_LINE(v_name || ' ' || v_score || ' ' || v_test || ' ' || V_passing || ' ' || 'Result =' || v_result);
END IF;

EXECUTE IMMEDIATE 'INSERT INTO student_tests_' || v_name || ' ' || ' values(:1, :2, :3, :4, :5)' using v_name, v_test, v_score, v_passing, v_result;

END LOOP;

CLOSE c_pass_fail_cursor; 

END;
/
Источник

Ответ Grafros выглядит хорошо, но я настоятельно рекомендую взглянуть на DBMS_ASSERT с DBMS_ASSERT.ENQUOTE_NAME или DBMS_ASSERT.ENQUOTE_LITERAL всякий раз, когда вы берете абиторные строки и используете их в execute immidiate.

Источник
Другие вопросы по тегам