Emacs Semantic не будет правильно анализировать файл в Windows
Недавно я переключил свою среду программирования с CentOS на Windows. Я фанат Emacs, поэтому я хочу использовать Emacs для программирования и на Windows. Все идет гладко, но когда я использую семантику emacs для анализа системных включений, возникает проблема.
Кажется, что emacs semantic будет выбирать, какой файл анализировать, а какой нет. Я указываю, что MS Visual Studio включает каталоги для разбора emacs, но это не так. Я также пробовал заголовки MinGW, но emacs анализирует только несколько файлов. Мой файл init.el такой
(defun my-semantic-hook()
(semantic-add-system-include "C:\\Program Files (x86)\\Microsoft Visual Studio 10.0\\VC\\include")
)
Я не знаю, должен ли я использовать / или \ в emacs для Windows, но кажется, что оба будут работать. И если я использую semantic-c-describe-environment выход
This file’s project include is handled by:
EDE : #<ede-cpp-root-target ede-cpp-root-target>
with the system path:
C:\Program Files (x86)\Microsoft Visual Studio 10.0\VC\include
D:/WorkSpace/
This file’s system include path is:
/usr/include
c:/Program Files (x86)/Microsoft Visual Studio 10.0/VC/include/
Вы можете видеть, что я также пытался EDE, чтобы указать путь включения системы, но он тоже не работает. Тем не менее, другие особенности семантических работ довольно хорошо. Если я напишу #include "lib1.h" или же #include "headers/lib1.h" или используя EDE #include <myproj/headers/lib1.h>Все они работают хорошо. Однако, когда дело доходит до включаемых файлов VS или MinGW, все идет не так, как надо. Я полагаю, если семантик сначала проверяет файл, и он обнаружил, что что-то не так, он просто пропускает файл? Тогда как я мог решить проблему?
Теперь проблема имеет новый прогресс. Я попытался использовать семантику в моем старом проекте с использованием библиотеки SDL2. После того, как я написал конфигурацию проекта для EDE и открыл один из исходных файлов, что-то случилось. Семантический анализ некоторых системных включаемых файлов, таких как stdio.h. Тогда я могу перейти к этому через семантику.
Затем я попробовал другой файл, используя iostream. Однако, семантика все еще не разбирает это. Но я могу использовать C-c , u Команда, чтобы перейти к файлу, и я вручную вызвать семантическую для его анализа. Затем я вернулся к своему исходному файлу с помощью iostream, бэкэнд компании, использующий семантику, теперь может работать довольно хорошо.
Так что теперь я могу убедиться, что проблема в том, что семантика не анализирует сам файл. Может быть, это потому, что он анализирует файлы только с.h или.c в конце имени файла? Но в Linux он хорошо работает с файлами, такими как iostream, почему в Windows это не так? Как это исправить?
1 ответ
добавить систему включает в себя пример:
(semantic-reset-system-include 'c-mode) (dolist (x 'your-system-includes) (semantic-add-system-include x 'c-mode))добавить корни проекта:
(setq semanticdb-project-roots 'your-project-roots)
В " Разумном Emacs" есть реализация того, как найти правильные пути включения системы в Windows, Darwin и Linux в system-cc-include из cc.el
;;;; -*- lexical-binding:t -*-
;;;;
;; More reasonable Emacs on MacOS, Windows and Linux
;; https://github.com/junjiemars/.emacs.d
;;;;
;; cc.el
;;;;
(platform-supported-when windows-nt
(defun check-vcvarsall-bat ()
"Return the path of vcvarsall.bat if which exists."
(let* ((pfroot (windows-nt-posix-path (getenv "PROGRAMFILES")))
(vsroot (concat pfroot " (x86)/Microsoft Visual Studio/"))
(vswhere (concat vsroot "Installer/vswhere.exe")))
(windows-nt-posix-path
(or (let* ((cmd (shell-command* (shell-quote-argument vswhere)
"-nologo -latest -property installationPath"))
(bat (and (zerop (car cmd))
(concat (string-trim> (cdr cmd))
"/VC/Auxiliary/Build/vcvarsall.bat"))))
(when (file-exists-p bat) bat))
(let* ((ver (car (directory-files vsroot t "[0-9]+" #'string-greaterp)))
(bat (concat ver "/BuildTools/VC/Auxiliary/Build/vcvarsall.bat")))
(when (file-exists-p bat) bat)))))))
(platform-supported-when windows-nt
(defun make-cc-env-bat ()
"Make cc-env.bat in `exec-path'."
(let ((vcvarsall (check-vcvarsall-bat))
(arch (downcase (getenv "PROCESSOR_ARCHITECTURE"))))
(when vcvarsall
(save-str-to-file
(concat "@echo off\n"
"rem generated by More Reasonable Emacs https://github.com/junjiemars/.emacs.d\n\n"
"pushd %cd%\n"
"cd /d \"" (file-name-directory vcvarsall) "\"\n"
"\n"
"call vcvarsall.bat " arch "\n"
"set CC=cl" "\n"
"set AS=ml" (if (string-match "[_a-zA-Z]*64" arch) "64" "") "\n"
"\n"
"popd\n"
"echo \"%INCLUDE%\"\n")
(v-home% ".exec/cc-env.bat"))))))
(defun check-cc-include ()
"Return cc include paths list."
(platform-supported-if windows-nt
;; Windows: msvc
(let ((cmd (shell-command* (make-cc-env-bat))))
(when (zerop (car cmd))
(mapcar (lambda (x) (windows-nt-posix-path x))
(var->paths
(car (nreverse
(split-string* (cdr cmd) "\n" t "\"")))))))
;; Darwin/Linux: clang or gcc
(let ((cmd (shell-command* "echo '' | cc -v -E 2>&1 >/dev/null -")))
(when (zerop (car cmd))
(take-while
(lambda (p)
(string-match "End of search list." p))
(drop-while
(lambda (p)
(string-match "#include <...> search starts here:" p))
(split-string* (cdr cmd) "\n" t "[ \t\n]")))))))
(defvar system-cc-include nil
"The system include paths used by C compiler.
This should be set with `system-cc-include'")
(defun system-cc-include (&optional cached)
"Returns a list of system include directories.
Load `system-cc-include' from file when CACHED is t,
otherwise check cc include on the fly."
(let ((c (v-home% "config/.cc-inc.el")))
(if (and cached (file-exists-p (concat c "c")))
(progn
(load (concat c "c"))
system-cc-include)
(let ((paths (platform-supported-if darwin
(mapcar (lambda (x)
(string-trim> x " (framework directory)"))
(check-cc-include))
(check-cc-include))))
(when (save-sexp-to-file
`(setq system-cc-include ',paths) c)
(byte-compile-file c))
(setq system-cc-include paths)))))
(provide 'cc)
Вызов system-cc-include Функция должна возвращать список системных путей включения:
(defun set-semantic-cc-env! (&optional project-includes project-roots preprocessors)
"Use `semantic-mode' in`c-mode'.
PROJECT-INCLUDES specify C include directories
via `semantic-add-system-include',
check it by `semantic-dependency-system-include-path'.'
PROJECT-ROOTS specify C project root directories
via `semanticdb-_project-roots'.
PREPROCESSORS specify C preprocessors
via `semantic-lex-c-preprocessor-symbol-map'
Use `semantic-c-describe-environment' to describe the current C environment."
(semantic-reset-system-include 'c-mode)
(dolist (x (append (when-fn% system-cc-include cc
(system-cc-include t))
project-includes))
(semantic-add-system-include x 'c-mode))
(setq% semanticdb-project-roots project-roots semantic/db)
(when-fn% global-semantic-idle-summary-mode semantic
(global-semantic-idle-summary-mode))
(when-fn% semantic-ia-fast-jump semantic
(define-key semantic-mode-map (kbd "C-c , f") #'semantic-ia-fast-jump))
(when-fn% semantic-ia-complete-symbol semantic
(define-key semantic-mode-map (kbd "C-c , TAB") #'semantic-ia-complete-symbol))
(setq% semantic-lex-c-preprocessor-symbol-map
preprocessors semantic/bovine/c)))