Как конвертировать NSImage в FireMonkey TBitmap?

Question

Как преобразовать NSImage в Delphis FireMonkey TBitmap? NSImage передается мне из Objective C API. Я использую Delphi XE8.

Answer 1

Попробуйте использовать данные NSImage.TIFFRepresentation. Сохраните его в потоке памяти, а затем загрузите TBitmap из потока. Другой способ заключается в использовании NSImage.CGImageForProposedRect, образец которого можно найти здесь: https://delphi-foundations.googlecode.com/svn/trunk/FMX%20Utilities/CCR.FMXClipboard.Mac.pas https://delphi-foundations.googlecode.com/svn/trunk/XE2%20book/13.%20Native%20APIs/Taking%20a%20screenshot/ScreenshotForm.pas

Обновление: хорошо, вот мое решение:

function PutBytesCallback(info: Pointer; buffer: Pointer; count: Longword): Longword; cdecl;
begin
  Result := TStream(info).Write(buffer^, count)
end;

procedure ReleaseConsumerCallback(info: Pointer); cdecl;
begin
end;

function NSImageToBitmap(Image: NSImage; Bitmap: TBitmap): Boolean;
var
  LStream: TMemoryStream;
  LCGImageRef: CGImageRef;
  LCallbacks: CGDataConsumerCallbacks;
  LConsumer: CGDataConsumerRef;
  LImageDest: CGImageDestinationRef;
begin
  Result := False;
  LStream := TMemoryStream.Create;
  LImageDest := nil;
  LConsumer := nil;
  try
    LCallbacks.putBytes := PutBytesCallback;
    LCallbacks.releaseConsumer := ReleaseConsumerCallback;
    LCGImageRef := Image.CGImageForProposedRect(nil, nil, nil);
    LConsumer := CGDataConsumerCreate(LStream, @LCallbacks);
    if LConsumer <> nil then
      LImageDest := CGImageDestinationCreateWithDataConsumer(LConsumer, CFSTR('public.png'), 1, nil);
    if LImageDest <> nil then
    begin
      CGImageDestinationAddImage(LImageDest, LCGImageRef, nil);
      CGImageDestinationFinalize(LImageDest);
      LStream.Position := 0;
      Bitmap.LoadFromStream(LStream);
      Result := True
    end
  finally
    if LImageDest <> nil then CFRelease(LImageDest);
    if LConsumer <> nil then CGDataConsumerRelease(LConsumer);
    LStream.Free
  end;
end;