Netlogo - Отбор проб из бета-пертского дистрибутива

Question

Я публикую это частично, чтобы получить ответ на вопрос, и частично, чтобы кто-то другой мог найти его позже и избавить их от головной боли.

Я пытаюсь создать бета-версию дистрибутива в NetLogo, следуя приведенной здесь формуле из Epix Analytics.

Я создал дистрибутив Beta(Alpha1, alpha2), используя преобразование из гамма-дистрибутива, здесь, на вики-странице дистрибутива Beta:

Код, который я создал:

to pert

 let mu ((a + 4 * b + c) / 6) 

 let alpha1 ((mu  - a ) * (2 * b - a - c)) / ((b - mu) * (c - a))

 let alpha2 (alpha1 * (c - mu)) / (mu - a)

 let x (random-gamma alpha1 1)

 let y (random-gamma alpha2 1)

 let beta-output  (x / (x + y))

 let output beta-output * (c - a) + a

 show output
end

Мой вопрос о преобразовании страницы Википедии из гамма-дистрибутива в бета-дистрибутив. Он имеет тэту как вторую часть гамма-распределения, но никогда не определяет, что это такое. Я принял это как заполнитель и, пока тэта одинакова для X и Y, не повлияет на результат. Я играл с разными значениями тета без видимых изменений в распределении. Это правильное предположение?

Answer 1

to-report random-pert [#minval #likeval #maxval]
  ;use pert params to draw from a beta distribution
  if not (#minval <= #likeval and #likeval <= #maxval) [error "wrong argument ranking"]
  if (#minval = #likeval and #likeval = #maxval) [report #minval] ;;handle trivial inputs
  let pert-var 1. / 36
  let pert-mean (#maxval + 4 * #likeval - 5 * #minval) / (6 * (#maxval - #minval))
  let temp pert-mean * (1 - pert-mean) / pert-var
  let alpha1 pert-mean * (temp - 1)
  let alpha2 (1 - pert-mean) * (temp - 1)
  let x1 random-gamma alpha1 1
  let x2 random-gamma alpha2 1
  report (x1 / (x1 + x2)) * (#maxval - #minval) + #minval
end