Как я могу отправить текстовое электронное письмо (с разрывом строки), используя sp_send_dbmail?

Question

У меня есть процедура SQL Server 2008, которая отправляет электронную почту через sp_send_dbmail.

Я использую следующий код:

  set @bodyText = ( select 
                      N'Here is one line of text ' +
                      N'It would be nice to have this on a 2nd line ' +
                      N'Below is some data: ' +
                      N' ' +
                      N' ' +
                      field1 +
                      N' ' +
                      field2 +
                      N' ' +
                      N'This is the last line'
                    from myTable )

    EXEC msdb.dbo.sp_send_dbmail
        @profile_name = 'myProfile',
        @recipients = @to,
        @body = @bodyText,
        @body_format = 'TEXT',
        @subject = 'Testing Email' ;

MyProfile настроен на использование локального сервера SMTP, в результате чего файл.EML в C:\inetpub\mailroot\queue

Когда я открываю один из этих файлов.eml (угу, единственное, что может их открыть, это outlook express, глядя на них во всем остальном, просто показывает тело в виде двоичного объекта, закодированного в base64). Похоже, он отображает результат в виде HTML - так что я не уверен, что проблема в клиенте, или

Я пытался вставить \ n в сообщение, но это не сработало. Как я могу отправить простой текст с разрывами строк и убедиться, что конечный результат выглядит правильно?

Кстати, я не могу на самом деле отправить письмо, чтобы проверить его с реальными почтовыми клиентами - корп. сеть заблокирована.

Answer 1

Вы фактически не вставляете никаких разрывов строк. Вы можете встроить их непосредственно в строковый литерал в SQL Server, как показано ниже.

SET @bodyText = (SELECT N'Here is one line of text 
It would be nice to have this on a 2nd line 
Below is some data: 


' + field1 + N' 

' + field2 + N' 

' + N'This is the last line'
                 FROM   myTable);

Или более аккуратный подход может быть

DECLARE @Template NVARCHAR(max) = 
N'Here is one line of text 
It would be nice to have this on a 2nd line 
Below is some data: 

##field1##

##field2##

This is the last line';

SET @bodyText = (SELECT REPLACE(
                    REPLACE(@Template, 
                       '##field1##', field1), 
                       '##field2##', field2)
                 FROM   myTable); 

Оба вызовут ошибку, если myTable содержит более одной строки, поскольку вы присваиваете результат скалярной переменной.

Answer 2

Я всегда использовал CHAR(13)+CHAR(10) для создания разрывов строк (которые, кажется, работают в сочетании со значениями nvarchar) в TSQL, поэтому попробуйте что-то вроде этого:

DECLARE @CRLF char(2)
       ,@bodyText nvarchar(max)
       ,@field1  nvarchar(10)
       ,@field2  nvarchar(10)
SELECT @CRLF=CHAR(13)+CHAR(10)
      ,@field1='your data'
      ,@field2='and more'

set @bodyText =
                N'Here is one line of text ' 
                +@CRLF+ N'It would be nice to have this on a 2nd line ' 
                +@CRLF+ N'Below is some data: ' + N' ' + N' ' + ISNULL(@field1,'') + N' ' + ISNULL(@field2 + N' ' ,'')
                +@CRLF+ N'This is the last line' 


PRINT @bodyText

ВЫХОД:

Here is one line of text 
It would be nice to have this on a 2nd line 
Below is some data:   your data and more 
This is the last line

этот CHAR(13)+CHAR(10) будет работать с msdb.dbo.sp_send_dbmailЯ отправляю отформатированные электронные письма, используя это все время.

Answer 3

Поздно до вечеринки, но, как упомянул Fandango68 выше, если вам разрешено отправлять html письма, установите @bodyFormat = 'HTML', тогда вы можете использовать <br/> для разрывов строк и сделайте так, как вам хочется, используя все теги, которые вы получаете из HTML, такие как разрывы строк, img, strong и так далее...

  set @bodyText = ( select 
                      '<h1>My Data</h1><p>Here is one line of text<br/>
                       It would be nice to have this on a 2nd line <br/>
                       Below is some data: <br/>'
                       + field1 + '<br/>'
                       + field2 + '<br/>'
                       + 'This is the last line</p>'
                       from myTable )

    EXEC msdb.dbo.sp_send_dbmail
        @profile_name = 'myProfile',
        @recipients = @to,
        @body = @bodyText,
        @body_format = 'HTML',
        @subject = 'Testing Email' ;

Answer 4

В моем случае обычное текстовое письмо с CHAR(13)+CHAR(10)был отформатирован Outlook, который «услужливо» удаляет лишние разрывы строк (если только он не отключен в параметрах Outlook).

Кроме того, мой список записей будет динамическим, поэтому я собрал STUFF FOR XML PATH, который извлекал конкатенированную строку и просто добавлял буквальную пустую строку с новым разрывом строки, а затем присваивал sp_send_dbmail @body = @emailBody:

      DECLARE @emailBody VARCHAR(MAX)

SET @emailBody = CONCAT('files: '
    ,(SELECT STUFF((SELECT
    ' 

' + CONCAT([FileName],'.csv')
    FROM localdb.dbo.tableName
    for xml path(''), TYPE).value('.', 'VARCHAR(MAX)'),1,1,'')))