Как получить targetPath, информацию WorkingDir из Microsoft Office выстрелы (например, Word 2013.lnk)

Question

Попытка использования IShellLink COM-интерфейса для получения информации о файлах.LNK. Он отлично работает для многих ярлыков приложений, но для ярлыков приложений Microsoft Office не дает правильной информации. Например:

во время чтения ProgramData\Microsoft\Windows\ Пуск \ Меню \ Программы \ Microsoft Office 2013 \ Word 2013.lnk

IShellLink:: GetPath возвращает "C:\Windows\Installer{90150000-0011-0000-0000-0000000FF1CE}\wordicon.exe"

не C:\Program Files (x86)\Microsoft Office\Office15\WINWORD.exe

Есть ли способ получить целевую информацию из таких.lnk файлов. какие окна используются для запуска приложения при двойном щелчке по ярлыку.

@Денис

Вот код C++, который я пробовал

IShellLinkDataList* comShellLinkDataList;
if (SUCCEEDED(psl->QueryInterface(IID_IShellLinkDataList,(void**)&comShellLinkDataList)))
{
    DWORD flags = 0;
    if (SUCCEEDED(comShellLinkDataList->GetFlags(&flags)))
    {
        if (flags & SLDF_HAS_DARWINID)
        {
            PIDLIST_ABSOLUTE pidList;
            if (SUCCEEDED(psl->GetIDList(&pidList)))
            {
                IShellFolder* shellFolder;
                PCITEMID_CHILD childItem;
                if (SUCCEEDED(SHBindToParent(pidList, IID_IShellFolder, (void**)&shellFolder, &childItem)))
                {
                    STRRET strRet;
                    if (SUCCEEDED(shellFolder->GetDisplayNameOf(childItem, SHGDN_NORMAL | SHGDN_FORPARSING, &strRet)))
                    {
                        TCHAR path[MAX_PATH] = {0};
                        if (SUCCEEDED(StrRetToBuf(&strRet, childItem, path, MAX_PATH)))
                        {
                            return path;
                        }
                    }                                    
                }                                
            }

        }
    }  
}

Answer 1

function GetExeNameFromShellLink(AShellLink: IShellLink): UnicodeString;
var List: IShellLinkDataList;
    Flags: DWORD;
    IDList: PItemIDList;
    ShellFolder: IShellFolder;
    ChildItem: PItemIDList;
    Attr: DWORD;
    StrRet: TStrRet;
begin
  if Succeeded(AShellLink.QueryInterface(IShellLinkDataList, List)) then
    try
      if Succeeded(List.GetFlags(Flags)) and (Flags and SLDF_HAS_DARWINID <> 0) then
        AShellLink.Resolve(0, SLR_INVOKE_MSI);
    finally
      List := nil;
    end;
  OleCheck(AShellLink.GetIDList(IDList));
  try
    OleCheck(SHBindToParent(IDList, IShellFolder, Pointer(ShellFolder), ChildItem));
    try
      OleCheck(ShellFolder.GetDisplayNameOf(ChildItem, SHGDN_NORMAL or SHGDN_FORPARSING, StrRet));
      case StrRet.uType of
        STRRET_WSTR:
          begin
            Result := StrRet.pOleStr;
            CoTaskMemFree(StrRet.pOleStr);
          end;
        STRRET_OFFSET:
          begin
            Inc(PByte(ChildItem), StrRet.uOffset);
            Result := UnicodeString(PAnsiChar(ChildItem));
          end;
        STRRET_CSTR:
          Result := UnicodeString(AnsiString(StrRet.cStr));
      else
        Result := '';
      end;
    finally
      ShellFolder := nil;
    end;
  finally
    CoTaskMemFree(IDList);
  end;
end;