Как я могу получить количество элементов в разреженном массиве в Actionscript?

Question

Actionscript использует разреженные массивы, поэтому у меня может быть такой массив:

var myArray:Array = new Array();
myArray[0] = "foo";
myArray[22] = "bar";

Теперь myArray.length даст мне 23. Есть ли способ получить фактическое количество элементов в массиве без итерации каждого элемента?

Answer 1

Если вы не хотите перебирать массив, вы можете отфильтровать его:

var myArray:Array = new Array();
myArray[0] = "foo";
myArray[22] = "bar";

var numberOfItems:int = myArray.toString().split(',').filter(isItem).length;

function isItem(item:*, index:int, array:Array):Boolean
{
  return item != "";
}

Answer 2

Самый быстрый способ должен заключаться в том, чтобы всегда использовать встроенные функции.

    function myFilter(item:*, index:int, array:Array):Boolean{
        if(item)
        {
            return true;
        }else{
            return false;
        }
    }

    var myArray:Array = new Array();
    myArray[0] = "foo";
    myArray[22] = "bar";
    trace(myArray.length) // 23
    var myMyNewArray:Array = myArray.filter(myFilter)
    trace(myMyNewArray .length) // 2

Answer 3

Используя for синтаксис, который будет повторять определенные индексы:

public static function definedCount(arr:Array):uint {
    var ctr:uint = 0;
    for(ix:* in arr)
        ctr++;
    return ctr;
}

Если вам нужно часто проверять количество элементов в разреженном массиве, вам следует обернуть его в класс коллекции, который независимо отслеживает количество элементов. Что-то вроде:

public class IndexedCollection { 
    private var _arr:Array = [];
    private var _itemCount:uint = 0;

    public function get count():uint {
        return _itemCount;
    }

    public function getItem(index:uint):* { 
        return _arr[index]; 
    }

    public function setItem(index:uint, value:*):void {
        if(_arr[index] === undefined)
            _itemCount++;
        _arr[index] = value; 
    }

    public function delete(index:uint):void { 
        if(_arr[index] === undefined) 
            return;
        delete _arr[index]; 
        _itemCount--;
    }
}