Tree Functor и Foldable, но с узлами. Есть ли какие-либо обобщения по этому поводу?

Question

data Tree t = Empty | Node t (Tree t) (Tree t)

Мы можем создать экземпляр Functor и использовать

fmap :: (t -> a) -> Tree t -> Tree a

Но что, если вместо (t -> a) я хочу (Tree t -> a), чтобы я мог иметь доступ ко всему (Node t), а не только к t

treeMap :: (Tree t -> a) -> Tree t -> Tree a
treeMap f Empty = Empty
treeMap f n@(Node _ l r) = Node (f n) (treeMap f l) (treeMap f r)

То же самое с сгибом

treeFold :: (Tree t -> a -> a) -> a -> Tree t -> a

Есть ли какие-либо обобщения над такими функциями?

map :: (f t -> a) -> f t -> f a
fold ::  (f t -> a -> a) -> a -> f t -> a

Answer 1

Вы только что обнаружили комонады! Ну, почти.

class Functor f => Comonad f where
  extract :: f a -> a
  duplicate :: f a -> f (f a)

instance Comonad Tree where
  extract (Node x _ _) = x   -- this one only works if your trees are guaranteed non-empty
  duplicate t@(Node n b1 b2) = Node t (duplicate b1) (duplicate b2)

С duplicate Вы можете реализовать свои функции:

treeMap f = fmap f . duplicate
freeFold f i = foldr f i . duplicate

Чтобы сделать это правильно, вы должны обеспечить непустоту системой типов:

type Tree' a = Maybe (Tree'' a)

data Tree'' t = Node' t (Tree' t) (Tree' t)
   deriving (Functor)

instance Comonad Tree'' where
  extract (Node' x _ _) = x
  duplicate t@(Node' _ b1 b2) = Node' t (fmap duplicate b1) (fmap duplicate b2)