Как я могу считать символы в Perl?

Question

У меня есть следующий скрипт Perl, подсчитывающий количество Fs и Ts в строке:

my $str = "GGGFFEEIIEETTGGG";
my $ft_count = 0;
$ft_count++ while($str =~ m/[FT]/g);
print "$ft_count\n";

Есть ли более краткий способ подсчета (другими словами, чтобы объединить строки 2 и 3)?

Answer 1

my $ft_count = $str =~ tr/FT//;

Смотрите perlop.

Если REPLACEMENTLIST пуст, SEARCHLIST реплицируется. Этот последний полезен для подсчета символов в классе…

  $cnt = $sky =~ tr/*/*/;     # count the stars in $sky
  $cnt = tr/0-9//;            # count the digits in $_

Вот эталон:

use strict; use warnings;

use Benchmark qw( cmpthese );

my ($x, $y) = ("GGGFFEEIIEETTGGG" x 1000) x 2;

cmpthese -5, {
    'tr' => sub {
        my $cnt = $x =~ tr/FT//;
    },
    'm' => sub {
        my $cnt = ()= $y =~ m/[FT]/g;
    },
};

 Оценить тр м
     Оценить м тр
м 108/ с -  -99%
тр 8118/ с 7440%    -

С ActiveState Perl 5.10.1.1006 на 32 Windows XP.

Разница кажется более суровой с

C:\Temp> c:\opt\strawberry-5.12.1\perl\bin\perl.exe t.pl
      Оценить м тр
м 88,8 / с -  -100%
tr 25507/s 28631%     -

Answer 2

Когда оператор "m" имеет флаг /g и выполняется в контексте списка, он возвращает список соответствующих подстрок. Так что еще один способ сделать это будет:

my @ft_matches = $str =~ m/[FT]/g;
my $ft_count = @ft_matches; # count elements of array

Но это все еще две строки. Еще один странный трюк, который может сделать его короче:

my $ft_count = () = $str =~ m/[FT]/g;

"() =" Заставляет "m" находиться в контексте списка. Присвоение списка с N элементами списку нулевых переменных на самом деле ничего не делает. Но затем, когда это выражение присваивания используется в скалярном контексте ($ft_count = ...), правый оператор "=" возвращает количество элементов с правой стороны - именно то, что вы хотите.

Это невероятно странно, когда впервые встречается, но идиома "=()=" - полезный трюк на Perl, который нужно знать для "оценки в контексте списка, а затем получения размера списка".

Примечание: у меня нет данных о том, какие из них более эффективны при работе с большими строками. На самом деле, я подозреваю, что ваш оригинальный код может быть лучшим в этом случае.

Answer 3

Да, вы можете использовать секретный оператор CountOf:

my $ft_count = ()= $str =~ m/[FT]/g;

Answer 4

Вы можете объединить строки 2, 3 и 4 в одну, например, так:

my $str = "GGGFFEEIIEETTGGG";
print $str =~ s/[FT]//g; #Output 4;