Как открыть папку / почтовый ящик, где находится сообщение, которое я выбрал в результате поиска в приложении Mail в macOS?

Question

В приложении "Почта" macOS я работаю со множеством "умных" папок (конкретный почтовый ящик, в котором отображаются результаты предварительно определенных критериев поиска). Таким образом, эти умные почтовые ящики показывают сообщения из разных учетных записей и папок.

Обычно мне нужно перейти к фактическому почтовому ящику / папке, где находится сообщение, выбранное в списке результатов. У меня тоже много папок.

Одним из улучшений (неприятностей) в новом приложении Mail было то, что я не мог найти способ сделать это. В прошлых версиях macOS (по крайней мере, до Mavericks) это было легко. Я мог бы сделать то же самое, что я делаю во многих других приложениях. Смотрите изображение.

Предыдущий трюк больше не работает в окнах сообщений почтового приложения.

Можно ли каким-либо образом перейти или открыть почтовый ящик / папку, в которой находится сообщение, которое я выбрал в результатах поиска или в интеллектуальном почтовом ящике?

Answer 1

Решение с Automator + AppleScript

Решение, которое я нашел, состояло в том, чтобы создать Службу Automator и при необходимости связать ее с ярлыком.

1. Откройте Automator.
2. Новый документ
3. Выбрать Service для типа документа.
4. В верхней части окна установите тип ввода для этой службы:
   Service receives selected выбирать no input
in выбирать Mail.app
5. В библиотеке действий (левая панель) найдите действие Run AppleScript,
6. Перетащите его в область рабочего процесса.
7. Скопируйте код в конце этого ответа и вставьте его в действие Run AppleScript,
8. Сохраните ваш сервис (например, "Перейти в папку").

Протестируйте сервис

При тестировании сервиса Automator мог оставаться открытым, а также почтовое приложение.

1. Откройте почтовое приложение.
2. Выполните поиск и выберите одно сообщение, предпочтительно сообщение, расположенное в пользовательской папке.
3. В строке меню перейдите к Mail > Services, Вы должны увидеть свой новый сервис.
4. Выберите сервис.

Выбранный и активный почтовый ящик / папка должен быть почтовым ящиком ранее выбранного сообщения.

Необязательный. Назначьте ярлык для вашего сервиса:

1. Откройте Системные настройки.
2. Идти к Keyboard > Shortcuts
3. На левой панели выберите Services
4. В конце правой панели под General вы должны найти свой сервис
5. Назначьте ему ярлык (например, CMD-OPTION-J)

Код

set theDialogTitle to "Go to Folder Script"

tell application "Mail"

    -- Get the selected messages and the count of them
    set theMessageList to selected messages of message viewer 1
    set theCount to length of theMessageList

    -- Error if no messages
    if theCount is 0 then
        display dialog ¬
            "No message selected." with title theDialogTitle buttons {"OK"} with icon caution
        return
    end if

    -- Error if more than one message
    if theCount is greater than 1 then
        display dialog ¬
            "Must select only one message." with title theDialogTitle buttons {"OK"} with icon caution
        return
    end if

    -- Get the message
    set theMessage to item 1 of theMessageList

    -- Get the mailbox object
    set theMailbox to mailbox of theMessage

    -- Select the mailbox
    set selected mailboxes of message viewer 1 to theMailbox

end tell