XSL: добавить ссылку на подстроку в строке, состоящей из нескольких элементов TEI-XML

Уже несколько дней пытаюсь добавить ссылку на подстроку w[@type='verb'] в строке Я работаю над TEI-XML транслитерация глиняных табличек, таким образом elements а также @type из <w> содержалась в <l> не всегда в одном и том же порядке.

XSLT версия 3.0:

<?xml version="1.0" encoding="UTF-8"?>

<xsl:template match="/">
 <xsl:apply-templates select="//div1"/>
</xsl:template>

<xsl:template match="//div1">
<!-- additional content before <ul> -->
 <ul>
  <li>
    <xsl:for-each select="descendant-or-self::lg/l[@n]">
       <xsl:variable name="verb1" select="w[@type='verb']"/>
       <xsl:variable name="href1" select="w[@type='verb']/@lemmaRef"/>
       <xsl:variable name="single-l" select="w[@type='coo'] | w[@type='noun'] | w[@type='verb'] | w[@type='num'] | w[@type='adv'] | w[@type='adj'] | g | name"/>

       <xsl:value-of select="$single-l"/> 
       <sup><xsl:value-of select="./@n"/></sup>
     </xsl:for-each>
   </li>
 </ul>
</xsl:template>

Мне нужно добавить ссылку lemmaRef для каждого w[@type='verb'],

Образец TEI - Я удалил @xml:id от element Кроме как l для этого примера:

<lg>
    <l n="4b-5a" xml:id="ktu1-3_ii_l4b-5a">
       <w type="coo">w</w><space/>
       <w type="verb" lemmaRef="uga/verb.xsl#qry"><damage degree="medium" facs="definir"><supplied resp="KTU">t</supplied></damage>qry</w>
       <g>.</g>
       <w type="noun" lemmaRef="uga/noun.xsl#ġlm">ġlmm</w>
       <lb/><w>b</w><space/>
       <w type="noun" lemmaRef="uga/noun.xsl#št">št</w>
       <g>.</g>
       <w type="noun" lemmaRef="uga/noun.xsl#ġr">ġr</w>
       <g>.</g>
    </l>
 </lg>

Мне нужно отобразить:

<ul>
 <li>w <a href="uga/verb.xml#qry">tqry</a> . ġlmm št . ġr .<sup>4b-5a</sup></li>
</ul>

"tqry" - глагол, содержащийся в <l>,

Как я могу сделать в XSLT чтобы иметь возможность отображать <a href="{$href1}"><xsl:value-of select="$verb1"/>, Я старался replace из $single-l или определить новую переменную предыдущего XSLT код, но это не работает. Я пробовал также с key но я думаю, что у меня все еще есть проблема...

Заранее спасибо за добрый совет.

Источник

1 ответ

Решение

Я не думаю, что вы должны пытаться создать строку, а затем вставить туда разметку, кажется, что должна быть возможность просто обработать дочерние элементы и затем сопоставить их с lg/l[@n]/w[@type = 'verb'] чтобы преобразовать его в гиперссылку HTML:

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema"
    exclude-result-prefixes="xs"
    version="3.0">

  <xsl:output method="html" indent="yes" html-version="5"/>
  <xsl:strip-space elements="*"/>

  <xsl:template match="/">
    <html>
      <head>
        <title>Example</title>
      </head>
      <xsl:apply-templates/>
    </html>
  </xsl:template>

  <xsl:template match="div">
      <section>
          <ul>
              <xsl:apply-templates select=".//lg/l[@n]"/>
          </ul>
      </section>
  </xsl:template>

  <xsl:template match="lg/l[@n]">
      <li>
          <xsl:apply-templates/>
          <sup>
              <xsl:value-of select="@n"/>
          </sup>
      </li>
  </xsl:template>

  <xsl:template match="lg/l[@n]/w[@type = 'verb']">
      <a href="{@lemmaRef}">
          <xsl:apply-templates/>
      </a>
  </xsl:template>

  <xsl:template match="space">
      <xsl:text> </xsl:text>
  </xsl:template>

</xsl:stylesheet>

В настоящее время это не совсем дает желаемый результат, но

<li>w <a href="uga/verb.xsl#qry">tqry</a>.ġlmmb št.ġr.<sup>4b-5a</sup></li>

вместо этого, но если есть содержимое элемента, который вам не нужен или не нужен, вы можете добавить для него пустой шаблон, чтобы он не выдавал никаких результатов (например, <xsl:template match="lg/l[@n]/w[not(@type)]"/>).

Я не уверен, что отсутствует также важный пробел и каковы правила его вставки, возможно, вам придется это объяснить.

Образец онлайн находится по адресу http://xsltfiddle.liberty-development.net/b4GWV5/1.

Источник
Другие вопросы по тегам