Использование делегата /DLR Lambdas для переопределения методов экземпляра?

Question

Стремясь выучить F# и.Net, я поиграл с DLR, который должен быть выпущен.

С этой целью я поигрался с рефлексией, пытаясь реализовать систему базовых типов, которая прекрасно интегрируется с clr. Хотя я могу создать простой тип, расширяющий Object, я получаю сообщение об ошибке при вызове метода, который он определяет.

Потому что в конце дня DLR LambdaExpressions компилируется в делегаты, что я делаю, это извлекаю сгенерированный MethodInfo из сгенерированного делегата и вызываю его, заполняя стек аргументами сгенерированного метода. Тогда верни это. Именно в этот момент я получаю свою ошибку.

Вот мой код:

open System
open System.Reflection
open System.Reflection.Emit

type ConstructorInformation=
    {Types:System.Type array}

type MethodInformation=
    {ParamTypes:System.Type array;
     Name:string
     Impl:System.Delegate}


let rec addConstructors (t:TypeBuilder) (baseType:System.Type) constructorInfos =
    match constructorInfos with
        |ci::rest ->
            let cb = t.DefineConstructor(MethodAttributes.Public, CallingConventions.Standard,ci.Types)
            let ilGen = cb.GetILGenerator()

            ilGen.Emit(OpCodes.Ldarg_0)
            Array.iteri (fun (index:int) _-> ilGen.Emit(OpCodes.Ldarg, index+1)) ci.Types
            ilGen.Emit( OpCodes.Call, baseType.GetConstructor(ci.Types) )
            addConstructors t baseType rest
        |[] -> ()

let rec addMethods (tb:TypeBuilder) baseType methodInfos =
    match methodInfos with
    |mi::rest ->
        let mb = tb.DefineMethod(mi.Name, MethodAttributes.Public, typeof<obj>, mi.ParamTypes)
        let ilGen = mb.GetILGenerator()
        ilGen.Emit(OpCodes.Ldarg_0)
        Array.iteri (fun index _ -> ilGen.Emit(OpCodes.Ldarg, index+1)) mi.ParamTypes
        ilGen.EmitCall(OpCodes.Call, mi.Impl.Method, mi.ParamTypes)
        ilGen.Emit(OpCodes.Ret)
        addMethods tb baseType rest
    |[] -> ()

let defineType (baseType:System.Type) constructorInfos methodInfos= 
    let ab =  AppDomain.CurrentDomain.DefineDynamicAssembly( AssemblyName("test"), AssemblyBuilderAccess.Run)
    let mb = ab.DefineDynamicModule("test")
    let typeBuilder = mb.DefineType("testType", TypeAttributes.Public, baseType)// | TypeAttributes.Class
    addConstructors typeBuilder baseType constructorInfos
    addMethods typeBuilder baseType methodInfos
    typeBuilder.CreateType()

type Delegate1 = delegate of obj -> obj
let echo y:#obj= (y :> obj)
let del1 : Delegate1 = new Delegate1(echo)

let mis:MethodInformation list=[{Impl=del1; Name="Echo"; ParamTypes=[|(typeof<obj>)|]}]
let cis:ConstructorInformation list=[]
let t= defineType (typeof<obj>) cis mis
let cinfo = t.GetConstructor([||])
let instance =cinfo.Invoke([||])
instance.GetType()
(t.GetMethod("Echo")).Invoke(instance, [| (1:>obj)|])

Вот моя ошибка, от ФСИ:

System.Reflection.TargetInvocationException: Exception has been thrown by the target of an invocation. ---> System.MethodAccessException: [e-mail](System.Object)
   at testType.Echo(Object )
   --- End of inner exception stack trace ---
   at System.RuntimeMethodHandle._InvokeMethodFast(Object target, Object[] arguments, SignatureStruct& sig, MethodAttributes methodAttributes, RuntimeTypeHandle typeOwner)
   at System.RuntimeMethodHandle.InvokeMethodFast(Object target, Object[] arguments, Signature sig, MethodAttributes methodAttributes, RuntimeTypeHandle typeOwner)
   at System.Reflection.RuntimeMethodInfo.Invoke(Object obj, BindingFlags invokeAttr, Binder binder, Object[] parameters, CultureInfo culture, Boolean skipVisibilityChecks)
   at System.Reflection.RuntimeMethodInfo.Invoke(Object obj, BindingFlags invokeAttr, Binder binder, Object[] parameters, CultureInfo culture)
   at <StartupCode$FSI_0002>.$FSI_0002._main()
stopped due to error

Любая помощь или предложения будут оценены - я немного новичок.Net, поэтому моя ошибка может быть простой.

Майк Кохоут

Answer 1

Ну, я решил это. Сгенерированный CIL был плохим. Кроме того, мне пришлось динамически вызывать делегата, а не функцию, которую он выполнял.

#light

open System
open System.Reflection
open System.Reflection.Emit

type ConstructorInformation=
    {Types:System.Type array}

type MethodInformation=
    {ParamTypes:System.Type array;
     Name:string;
     Impl:System.Delegate;
     mutable Field:FieldBuilder option}


let rec addConstructors (t:TypeBuilder) (baseType:System.Type) constructorInfos =
    match constructorInfos with
        |ci::rest ->
            let cb = t.DefineConstructor(MethodAttributes.Public, CallingConventions.Standard,ci.Types)
            let ilGen = cb.GetILGenerator()

            ilGen.Emit(OpCodes.Ldarg_0)
            Array.iteri (fun (index:int) _-> ilGen.Emit(OpCodes.Ldarg, index+1)) ci.Types
            ilGen.Emit( OpCodes.Call, baseType.GetConstructor(ci.Types) )
            addConstructors t baseType rest
        |[] -> ()

let rec addMethods (tb:TypeBuilder) baseType methodInfos =
    match methodInfos with
    |mi::rest ->
        let fb = tb.DefineField(mi.Name+"_field", typeof<Delegate>, FieldAttributes.Public);
        mi.Field <- Some(fb)
        let mb = tb.DefineMethod(mi.Name, MethodAttributes.Public, typeof<obj>, mi.ParamTypes)
        let ilGen = mb.GetILGenerator()
        let arrayLocal = ilGen.DeclareLocal((typeof<obj[]>))
        ilGen.Emit(OpCodes.Ldarg_0)
        ilGen.Emit(OpCodes.Ldfld, fb)
        ilGen.Emit(OpCodes.Ldc_I4, Array.length mi.ParamTypes)
        ilGen.Emit(OpCodes.Newarr, typeof<obj>)
        ilGen.Emit(OpCodes.Stloc, arrayLocal)
        ilGen.Emit(OpCodes.Ldloc, arrayLocal)
        Array.iteri (fun index _ -> ilGen.Emit(OpCodes.Ldc_I4, index)
                                    ilGen.Emit(OpCodes.Ldarg, index+1)
                                    ilGen.Emit(OpCodes.Stelem_Ref)
                                    ilGen.Emit(OpCodes.Ldloc, arrayLocal)) mi.ParamTypes
        ilGen.EmitCall(OpCodes.Callvirt, (mi.Impl.GetType()).GetMethod("DynamicInvoke", [|(typeof<obj[]>)|]), mi.ParamTypes)
        ilGen.Emit(OpCodes.Ret)
        addMethods tb baseType rest
    |[] -> ()

let defineType (baseType:System.Type) constructorInfos methodInfos= 
    let ab =  AppDomain.CurrentDomain.DefineDynamicAssembly( AssemblyName("test"), AssemblyBuilderAccess.Run)
    let mb = ab.DefineDynamicModule("test")
    let typeBuilder = mb.DefineType("testType", TypeAttributes.Public, baseType)// | TypeAttributes.Class
    addConstructors typeBuilder baseType constructorInfos
    addMethods typeBuilder baseType methodInfos
    typeBuilder.CreateType()

type Delegate1 = delegate of obj -> obj
let echo y:#obj= (y :> obj)
let del1 : Delegate1 = new Delegate1(echo)

type Delegate2 = delegate of obj * obj -> obj
let echoFirst (x:#obj) (y:#obj)=(x:>obj)
let echoFirstDelegate:Delegate2 = new Delegate2(echoFirst)
echoFirstDelegate.DynamicInvoke( [|(1:>obj);(2:>obj)|])
//let mis:MethodInformation list=[{Impl=del1; Name="Echo"; ParamTypes=[|(typeof<obj>)|];Field=None}]
//let cis:ConstructorInformation list=[]
//let t= defineType (typeof<obj>) cis mis
//let cinfo = t.GetConstructor([||])
//let instance =cinfo.Invoke([||])
//instance.GetType()
//(t.GetField("Echo_field")).SetValue(instance, del1)
//let fieldDelegate = (t.GetField("Echo_field")).GetValue(instance) :?> Delegate
//(t.GetMethod("Echo")).Invoke(instance, [| (1:>obj)|])

//del1.DynamicInvoke( [|(1:>obj)|])

let mis:MethodInformation list=[{Impl=del1; Name="Echo"; ParamTypes=[|(typeof<obj>)|];Field=None};
                                {Impl=echoFirstDelegate; Name="EchoFirst"; ParamTypes=[| (typeof<obj>);(typeof<obj>)|]; Field=None}]
let cis:ConstructorInformation list=[]
let t= defineType (typeof<obj>) cis mis
let cinfo = t.GetConstructor([||])
let instance =cinfo.Invoke([||])
instance.GetType()
(t.GetField("Echo_field")).SetValue(instance, del1)
let fieldDelegate = (t.GetField("Echo_field")).GetValue(instance) :?> Delegate
(t.GetMethod("Echo")).Invoke(instance, [| (1:>obj)|])
(t.GetField("EchoFirst_field")).SetValue(instance, echoFirstDelegate)
(t.GetMethod("EchoFirst")).Invoke(instance, [| (1:>obj);(2:>obj)|])