Как получить текущий тип жесткого диска?

Я нашел способ получить HDD серийный номер нет в VB6. Но для этого нужно выбрать вариант из

  • основной мастер
  • первичный раб
  • вторичный мастер
  • вторичный раб

Но я хочу автоматически выбрать опцию. Логика автоматического выбора

Предположим, у меня есть 4 HDD с вышеуказанными 4 типами. И логика выберет тип жесткого диска, по которому загружается текущая система.

Я действительно понятия не имею, как определить текущую систему, на которой тип жесткого диска. Пожалуйста помоги.

Вот класс, который я использую для выбора серийного номера жесткого диска. HDSN CLASS

Источник

2 ответа

Решение

Код ниже должен помочь:

Option Explicit

Private Const FILE_SHARE_READ = &H1
Private Const FILE_SHARE_WRITE = &H2
Private Const GENERIC_READ = &H80000000
Private Const GENERIC_WRITE = &H40000000
Private Const OPEN_EXISTING = 3

Private Const IOCTL_VOLUME_BASE     As Long = 86 ' Asc("V")
Private Const METHOD_BUFFERED       As Long = 0
Private Const FILE_READ_ACCESS      As Long = 1
Private Const FILE_ANY_ACCESS       As Long = 0

'DEFINE IOCTL_VOLUME_GET_VOLUME_DISK_EXTENTS CTL_CODE(IOCTL_VOLUME_BASE, 0, METHOD_BUFFERED, FILE_ANY_ACCESS)
Private Const IOCTL_VOLUME_GET_VOLUME_DISK_EXTENTS = (((IOCTL_VOLUME_BASE) * (2& ^ 16&)) Or ((FILE_ANY_ACCESS) * (2& ^ 14&)) Or ((0&) * (2& ^ 2&)) Or (METHOD_BUFFERED))

Private Type DISK_EXTENT
    DiskNumber          As Long
    StartingOffset      As Currency
    ExtentLength        As Currency
End Type

Private Type VOLUME_DISK_EXTENTS
    NumberOfDiskExtents As Currency
    Extents(1 To 4)     As DISK_EXTENT
End Type

Private Declare Function CreateFile _
    Lib "kernel32" Alias "CreateFileA" _
    (ByVal lpFileName As String, _
    ByVal dwDesiredAccess As Long, _
    ByVal dwShareMode As Long, _
    ByVal lpSecurityAttributes As Long, _
    ByVal dwCreationDisposition As Long, _
    ByVal dwFlagsAndAttributes As Long, _
    ByVal hTemplateFile As Long) As Long

Private Declare Function CloseHandle _
    Lib "kernel32" _
    (ByVal hObject As Long) As Long

Private Declare Function GetWindowsDirectory Lib "Kernel32.dll" Alias "GetWindowsDirectoryW" ( _
    ByVal lpBuffer As Long, _
    ByVal uSize As Long _
) As Long

Private Declare Function DeviceIoControlNoInput _
    Lib "kernel32" Alias "DeviceIoControl" _
    (ByVal hDevice As Long, _
    ByVal dwIoControlCode As Long, _
    ByVal lpInBuffer As Long, _
    ByVal nInBufferSize As Long, _
    ByRef lpOutBuffer As Any, _
    ByVal nOutBufferSize As Long, _
    ByRef lpBytesReturned As Long, _
    ByVal lpOverlapped As Long) As Long

' Return the index of the physical drive from which we've booted into Windows. 
Public Function GetBootPhysicalDrive() As Long

    Dim sWindowsPath        As String
    Dim nRet                As Long
    Dim sDevicePath         As String
    Dim hLogicalBootDrive   As Long
    Dim sVolumeDevice       As String
    Dim uVolumeDiskExtents  As VOLUME_DISK_EXTENTS
    Dim nBytesReturned      As Long

    ' Allocate space and retrieve the windows directory.
    sWindowsPath = Space$(64)
    nRet = GetWindowsDirectory(StrPtr(sWindowsPath), 64)

    ' This gives us the volume that Windows is on. Open it.
    sVolumeDevice = "\\.\" & Left$(sWindowsPath, 2)
    hLogicalBootDrive = CreateFile(sVolumeDevice, GENERIC_READ + GENERIC_WRITE, FILE_SHARE_READ + FILE_SHARE_WRITE, 0&, OPEN_EXISTING, 0&, 0&)

    ' Find out information about this volume.
    nRet = DeviceIoControlNoInput(hLogicalBootDrive, IOCTL_VOLUME_GET_VOLUME_DISK_EXTENTS, 0&, 0&, uVolumeDiskExtents, LenB(uVolumeDiskExtents), nBytesReturned, 0&)

    If nRet = 0 Then
    ' Something went wrong. Return error value.
        GetBootPhysicalDrive = -1
    Else
    ' This is the physical disk number.
        GetBootPhysicalDrive = uVolumeDiskExtents.Extents(1).DiskNumber
    End If

    ' Close volume.
    CloseHandle hLogicalBootDrive

End Function
Источник

Используя вышеприведенное решение Марка Бертеншоу, я написал следующее в модуле и просто назвал GetDiskSerialNumber функция для получения серийного жесткого диска, с которого загружается текущая система. Вот мой код модуля:

Option Explicit

Private Const FILE_SHARE_READ = &H1
Private Const FILE_SHARE_WRITE = &H2
Private Const GENERIC_READ = &H80000000
Private Const GENERIC_WRITE = &H40000000
Private Const OPEN_EXISTING = 3

Private Const IOCTL_VOLUME_BASE     As Long = 86 ' Asc("V")
Private Const METHOD_BUFFERED       As Long = 0
Private Const FILE_READ_ACCESS      As Long = 1
Private Const FILE_ANY_ACCESS       As Long = 0

'DEFINE IOCTL_VOLUME_GET_VOLUME_DISK_EXTENTS CTL_CODE(IOCTL_VOLUME_BASE, 0, METHOD_BUFFERED, FILE_ANY_ACCESS)
Private Const IOCTL_VOLUME_GET_VOLUME_DISK_EXTENTS = (((IOCTL_VOLUME_BASE) * (2& ^ 16&)) Or ((FILE_ANY_ACCESS) * (2& ^ 14&)) Or ((0&) * (2& ^ 2&)) Or (METHOD_BUFFERED))

Private Type DISK_EXTENT
    DiskNumber          As Long
    StartingOffset      As Currency
    ExtentLength        As Currency
End Type

Private Type VOLUME_DISK_EXTENTS
    NumberOfDiskExtents As Currency
    Extents(1 To 4)     As DISK_EXTENT
End Type

Private Declare Function CreateFile _
    Lib "kernel32" Alias "CreateFileA" _
    (ByVal lpFileName As String, _
    ByVal dwDesiredAccess As Long, _
    ByVal dwShareMode As Long, _
    ByVal lpSecurityAttributes As Long, _
    ByVal dwCreationDisposition As Long, _
    ByVal dwFlagsAndAttributes As Long, _
    ByVal hTemplateFile As Long) As Long

Private Declare Function CloseHandle _
    Lib "kernel32" _
    (ByVal hObject As Long) As Long

Private Declare Function GetWindowsDirectory Lib "Kernel32.dll" Alias "GetWindowsDirectoryW" ( _
    ByVal lpBuffer As Long, _
    ByVal uSize As Long _
) As Long

Private Declare Function DeviceIoControlNoInput _
    Lib "kernel32" Alias "DeviceIoControl" _
    (ByVal hDevice As Long, _
    ByVal dwIoControlCode As Long, _
    ByVal lpInBuffer As Long, _
    ByVal nInBufferSize As Long, _
    ByRef lpOutBuffer As Any, _
    ByVal nOutBufferSize As Long, _
    ByRef lpBytesReturned As Long, _
    ByVal lpOverlapped As Long) As Long

' Return the index of the physical drive from which we've booted into Windows. 
Public Function GetBootPhysicalDrive() As Long

    Dim sWindowsPath        As String
    Dim nRet                As Long
    Dim sDevicePath         As String
    Dim hLogicalBootDrive   As Long
    Dim sVolumeDevice       As String
    Dim uVolumeDiskExtents  As VOLUME_DISK_EXTENTS
    Dim nBytesReturned      As Long

    ' Allocate space and retrieve the windows directory.
    sWindowsPath = Space$(64)
    nRet = GetWindowsDirectory(StrPtr(sWindowsPath), 64)

    ' This gives us the volume that Windows is on. Open it.
    sVolumeDevice = "\\.\" & Left$(sWindowsPath, 2)
    hLogicalBootDrive = CreateFile(sVolumeDevice, GENERIC_READ + GENERIC_WRITE, FILE_SHARE_READ + FILE_SHARE_WRITE, 0&, OPEN_EXISTING, 0&, 0&)

    ' Find out information about this volume.
    nRet = DeviceIoControlNoInput(hLogicalBootDrive, IOCTL_VOLUME_GET_VOLUME_DISK_EXTENTS, 0&, 0&, uVolumeDiskExtents, LenB(uVolumeDiskExtents), nBytesReturned, 0&)

    If nRet = 0 Then
    ' Something went wrong. Return error value.
        GetBootPhysicalDrive = -1
    Else
    ' This is the physical disk number.
        GetBootPhysicalDrive = uVolumeDiskExtents.Extents(1).DiskNumber
    End If

    ' Close volume.
    CloseHandle hLogicalBootDrive

End Function

Public Function GetDiskSerialNumber() As String
    Dim wmiObject As Object
    Dim obj As Object

    Set wmiObject = GetObject("WinMgmts:")
    For Each obj In wmiObject.InstancesOf("Win32_PhysicalMedia")
        If obj.Tag = "\\.\PHYSICALDRIVE" + CStr(GetBootPhysicalDrive) Then GetDiskSerialNumber = obj.Tag + " : " + obj.SerialNumber
    Next obj
End Function

Большое спасибо Mark Bertenshaw.

Источник
Другие вопросы по тегам