XML - XSL - FO XML Dot Leader Mutliple Происшествия
У меня есть сотни строк текста, отформатированных в XML-документе, которые мне нужно вывести в PDF и отобразить в виде:
LEFT TEXT.......................................................................RIGHT TEXT
Я обнаружил, как это сделать в XSL, но в настоящее время он работает как инструкция обработки во время вывода FO. XSL:
<xsl:template match="processing-instruction('leftrighttext')">
<fo:block text-align-last="justify">
<xsl:text>LEFT TEXT</xsl:text>
<fo:leader leader-pattern="dots"/>
<xsl:text>RIGHT TEXT</xsl:text>
</fo:block>
Как выглядит XML (используется в таблице):
<row>
<entry> <?leftrighttext?> </entry>
</row
Желаемый результат:
LEFT TEXT........................................................................RIGHT TEXT
NEXT TEXT WITHIN TABLE...........................................................OTHER TEXT
Мой вопрос заключается в том, как получить "ЛЕВЫЙ ТЕКСТ" и "ПРАВОЙ ТЕКСТ" для вызова из документа XML вместо ввода значений непосредственно в таблицу стилей, например:
<row>
<entry>LEFT TEXT <sometag> RIGHT TEXT</entry>
</row>
<row>
<entry>NEXT TEXT WITHIN TABLE <sometag> OTHER TEXT
Есть ли тег, который я могу создать, или строка для идентификации текста перед тегом, и текст после, вводите лидеры точек между ними?
Любая помощь будет оценена.
Запрашиваемая дополнительная информация: я использовал XSLT, опубликованный в ответе ниже, вот документ XML, который я пытаюсь преобразовать. Я также следовал плану XML, который был размещен ниже. Пожалуйста, дайте мне знать, что мне не хватает...
XML:
<?xml-model href="http://docbook.org/xml/5.0/rng/docbook.rng" schematypens="http://relaxng.org/ns/structure/1.0"?>
<?xml-model href="http://docbook.org/xml/5.0/rng/docbook.rng" type="application/xml" schematypens="http://purl.oclc.org/dsdl/schematron"?>
<section xmlns="http://docbook.org/ns/docbook" xmlns:xlink="http://www.w3.org/1999/xlink"
version="5.0">
<table>
<tgroup cols="2">
<colspec colnum="1" colname="col1" colwidth="235"/>
<colspec colnum="2" colname="col2" colwidth="235"/>
<thead>
<row>
<entry align="center">LSP</entry>
<entry align="center">RSP</entry>
</row>
</thead>
<tbody>
<row>
<entry align="center" namest="col1" nameend="col2">(PF) Takeoff Briefing<?leftrighttext?>PERFORM</entry>
</row>
</tbody>
</tgroup>
</table>
</section>
Вот что я имею для начала таблицы стилей:
XSLT:
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:date="http://exslt.org/dates-and-times"
xmlns:xs="http://www.w3.org/2001/XMLSchema"
xmlns:fo="http://www.w3.org/1999/XSL/Format"
xmlns:d="http://docbook.org/ns/docbook"
exclude-result-prefixes="xs date"
extension-element-prefixes="date"
version="1.0">
<xsl:import href="http://docbook.sourceforge.net/release/xsl-ns/current/fo/docbook.xsl"/>
1 ответ
Я бы придерживался вашего оригинального подхода использования инструкции обработки. Вам просто нужно использовать xsl:apply-templates создать fo:table-cell,
Пример:
Ввод XML
<doc>
<row>
<entry>LEFT TEXT <?leftrighttext?> RIGHT TEXT</entry>
</row>
<row>
<entry>NEXT TEXT WITHIN TABLE <?leftrighttext?> OTHER TEXT</entry>
</row>
</doc>
XSLT 1.0
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:fo="http://www.w3.org/1999/XSL/Format">
<xsl:output indent="yes"/>
<xsl:strip-space elements="*"/>
<xsl:template match="/*">
<fo:root>
<fo:layout-master-set>
<fo:simple-page-master master-name="my-page" page-width="8.5in" page-height="11in">
<fo:region-body margin="1in" margin-top="1.5in" margin-bottom="1.5in"/>
</fo:simple-page-master>
</fo:layout-master-set>
<fo:page-sequence master-reference="my-page">
<fo:flow flow-name="xsl-region-body">
<fo:table>
<fo:table-body>
<xsl:apply-templates select="row"/>
</fo:table-body>
</fo:table>
</fo:flow>
</fo:page-sequence>
</fo:root>
</xsl:template>
<xsl:template match="row">
<fo:table-row>
<xsl:apply-templates select="entry"/>
</fo:table-row>
</xsl:template>
<xsl:template match="entry">
<fo:table-cell>
<fo:block text-align-last="justify">
<xsl:apply-templates/>
</fo:block>
</fo:table-cell>
</xsl:template>
<xsl:template match="entry/text()">
<xsl:value-of select="normalize-space()"/>
</xsl:template>
<xsl:template match="processing-instruction('leftrighttext')">
<fo:leader leader-pattern="dots"/>
</xsl:template>
</xsl:stylesheet>
Выход XSL-FO
<fo:root xmlns:fo="http://www.w3.org/1999/XSL/Format">
<fo:layout-master-set>
<fo:simple-page-master master-name="my-page" page-width="8.5in" page-height="11in">
<fo:region-body margin="1in" margin-top="1.5in" margin-bottom="1.5in"/>
</fo:simple-page-master>
</fo:layout-master-set>
<fo:page-sequence master-reference="my-page">
<fo:flow flow-name="xsl-region-body">
<fo:table>
<fo:table-body>
<fo:table-row>
<fo:table-cell>
<fo:block text-align-last="justify">LEFT TEXT<fo:leader leader-pattern="dots"/>RIGHT TEXT</fo:block>
</fo:table-cell>
</fo:table-row>
<fo:table-row>
<fo:table-cell>
<fo:block text-align-last="justify">NEXT TEXT WITHIN TABLE<fo:leader leader-pattern="dots"/>OTHER TEXT</fo:block>
</fo:table-cell>
</fo:table-row>
</fo:table-body>
</fo:table>
</fo:flow>
</fo:page-sequence>
</fo:root>
Отрендеренный PDF
ОБНОВЛЕННЫЙ ПРИМЕР
Глядя на ваш пример обновления XML, я вижу, что у вас есть пространство имен по умолчанию (xmlns="http://docbook.org/ns/docbook"). Что вы должны сделать, это объявить это пространство имен с префиксом в вашем XSLT, а затем использовать этот префикс в ваших XPath.
Если вы используете XSLT 2.0, вы можете вместо этого добавить xpath-default-namespace="http://docbook.org/ns/docbook" на ваш xsl:stylesheet и не меняйте ни одного из ваших XPath-ов.
Трудно рекомендовать что-то конкретное, потому что вы не показали полный XSLT (или даже шаблон, который показывает нам контекст, в котором создается тело), так что это полное предположение.
Вот пример использования вашего обновленного XML и объявления http://docbook.org/ns/docbook пространство имен с префиксом doc,
(Я не пытался обрабатывать заголовки таблиц или что-то в этом роде, просто для простоты.)
Ввод XML
<section xmlns="http://docbook.org/ns/docbook" xmlns:xlink="http://www.w3.org/1999/xlink"
version="5.0">
<table>
<tgroup cols="2">
<colspec colnum="1" colname="col1" colwidth="235"/>
<colspec colnum="2" colname="col2" colwidth="235"/>
<thead>
<row>
<entry align="center">LSP</entry>
<entry align="center">RSP</entry>
</row>
</thead>
<tbody>
<row>
<entry align="center" namest="col1" nameend="col2">(PF) Takeoff Briefing<?leftrighttext?>PERFORM</entry>
</row>
</tbody>
</tgroup>
</table>
</section>
XSLT 1.0
<xsl:stylesheet version="1.0" xmlns:doc="http://docbook.org/ns/docbook" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:fo="http://www.w3.org/1999/XSL/Format">
<xsl:output indent="yes"/>
<xsl:strip-space elements="*"/>
<xsl:template match="/*">
<fo:root>
<fo:layout-master-set>
<fo:simple-page-master master-name="my-page" page-width="8.5in" page-height="11in">
<fo:region-body margin="1in" margin-top="1.5in" margin-bottom="1.5in"/>
</fo:simple-page-master>
</fo:layout-master-set>
<fo:page-sequence master-reference="my-page">
<fo:flow flow-name="xsl-region-body">
<xsl:apply-templates/>
</fo:flow>
</fo:page-sequence>
</fo:root>
</xsl:template>
<xsl:template match="doc:table">
<fo:table>
<fo:table-body>
<xsl:apply-templates select="doc:tgroup/doc:tbody/doc:row"/>
</fo:table-body>
</fo:table>
</xsl:template>
<xsl:template match="doc:row">
<fo:table-row>
<xsl:apply-templates select="doc:entry"/>
</fo:table-row>
</xsl:template>
<xsl:template match="doc:entry">
<fo:table-cell>
<fo:block text-align-last="justify">
<xsl:apply-templates/>
</fo:block>
</fo:table-cell>
</xsl:template>
<xsl:template match="doc:entry/text()">
<xsl:value-of select="normalize-space()"/>
</xsl:template>
<xsl:template match="processing-instruction('leftrighttext')">
<fo:leader leader-pattern="dots"/>
</xsl:template>
</xsl:stylesheet>
Выход XSL-FO
<fo:root xmlns:doc="http://docbook.org/ns/docbook"
xmlns:fo="http://www.w3.org/1999/XSL/Format">
<fo:layout-master-set>
<fo:simple-page-master master-name="my-page" page-width="8.5in" page-height="11in">
<fo:region-body margin="1in" margin-top="1.5in" margin-bottom="1.5in"/>
</fo:simple-page-master>
</fo:layout-master-set>
<fo:page-sequence master-reference="my-page">
<fo:flow flow-name="xsl-region-body">
<fo:table>
<fo:table-body>
<fo:table-row>
<fo:table-cell>
<fo:block text-align-last="justify">(PF) Takeoff Briefing<fo:leader leader-pattern="dots"/>PERFORM</fo:block>
</fo:table-cell>
</fo:table-row>
</fo:table-body>
</fo:table>
</fo:flow>
</fo:page-sequence>
</fo:root>
Отрендеренный PDF
