Отладка с использованием таймера

Question

Я делаю консольную игру, в которой движущийся персонаж должен двигаться влево и вправо, чтобы перехватить падающих "фруктовых" /ASCII-персонажей, только у меня проблемы. Я использую таймер с интервалом в 1 секунду, и каждый раз, когда он истекает, он должен проверять список фруктов, которые уже есть на доске, и перемещать каждый фрукт по одному, а затем случайным образом вставлять новый фрукт на доску. Фрукты все хранятся как объекты в классе.

Вот код таймера:

Sub FruitTick() Handles FruitTimer.Elapsed
    Dim RandomNumber As Integer
    Dim Fruit As Fruit

    For i = 0 To FruitList.Count - 1
        If FruitList(i).Position.Y < FruitBoard.Height - 1 Then
            FruitList(i).LowerFruitByOne()
        End If
    Next

    PeriodUntilFruitAppears -= 1
    If PeriodUntilFruitAppears <= 0 Then
        PeriodUntilFruitAppears = FruitFrequency
        RandomNumber = New Random().Next(1, 5)
        If RandomNumber = 1 Then
            Fruit = New Fruit()
            Fruit.AddToList()
            Fruit.PlaceOnBoard()
        End If
    End If
End Sub

А вот класс для фруктов:

Public Class Fruit
    Private FruitIcons() As Char = {"#", "ð", "ó", "ç", "%", "$"}
    Public Icon As Char
    Public Position As Location
    Public Colour As ConsoleColor
    Sub New()
        Me.Icon = FruitIcons(New Random().Next(FruitIcons.Length))
        Me.Position = New Location(New Random().Next(FruitBoard.Width), 0)
        Me.Colour = New Random().Next(1, 16)
    End Sub
    Sub New(_Icon As Char, _
            _Position As Location, _
            _Colour As ConsoleColor)

        Me.Icon = _Icon
        Me.Position = New Location(_Position.X, 0)
        Me.Colour = _Colour
    End Sub
    Sub PlaceOnBoard()
        Console.SetCursorPosition(FruitBoard.Position.X + Me.Position.X, FruitBoard.Position.Y + Me.Position.Y)
        Console.ForegroundColor = Me.Colour
        Console.BackgroundColor = FruitBoard.BackColour
        Console.Write(Me.Icon)
    End Sub
    Sub AddToList()
        FruitList.Add(Me)
    End Sub
    Sub LowerFruitByOne()
        Dim DrawInstruction As Instruction
        DrawInstruction = New Instruction(" ", _
                                          New Location(FruitBoard.Position.X + Me.Position.X, _
                                                       FruitBoard.Position.Y + Me.Position.Y), _
                                          FruitBoard.BackColour, _
                                          FruitBoard.BackColour)
        DrawInstruction.Execute()
        Me.Position.Y += 1
        DrawInstruction = New Instruction(Me.Icon, _
                                          New Location(FruitBoard.Position.X + Me.Position.X, _
                                                       FruitBoard.Position.Y + Me.Position.Y), _
                                          Me.Colour, _
                                          FruitBoard.BackColour)
        DrawInstruction.Execute()
    End Sub
End Class

Упомянутый класс Instruction просто используется для перерисовки символов в консоли.

У меня странные проблемы, такие как конечные символы, где они должны были быть перетянуты пробелом, фрукты падают двумя символами вместо одного, фрукты нерестятся слева от предыдущего фрукта, а затем останавливаются и т. Д... но У меня особенно проблемы с отладкой. Когда я ставлю точку останова и вхожу в код, кажется, что отладчик перемещается с места на место хаотично, как будто таймер все еще работает, пока он приостановлен, и я слишком медленный.

Есть ли способ отладить его должным образом, построчно, или мне придется делать умные предположения о том, что происходит?

Answer 1

Вы должны остановить таймер в то время как в истекшем методе. Попробуйте остановить таймер в начале и включить его в последней строке.

Sub FruitTick() Handles FruitTimer.Elapsed
    FruitTimer.Enabled = False

    ' Your actual code

    FruitTimer.Enabled = True
End Sub

Возможно, ваш код длится более секунды, и код запускается снова до завершения последнего выполнения. Что более очевидно при отладке. Это, вероятно, будет генерировать все ваши проблемы, и это приведет к проблемам с памятью в конце.