Невозможно обновить пиксели из 1D координат в обработке

Я написал программу в Processing, которая записывает 1D координаты черных пикселей на изображении в текстовый файл.

Я написал вторую программу, которая должна прочитать текстовый файл и воссоздать черные пиксели на белом изображении, чтобы проверить работоспособность сценария № 1.

Проблема в том, что вторая программа, которая должна воссоздавать черные пиксели на белом изображении, этого не делает.

Для первого сценария пользователь открывает графический интерфейс, нажимает 2, чтобы открыть браузер файлов, а затем загружает файл. Код изменяет размер файла и меняет его на черно-белый. Затем код сканирует черные пиксели и записывает координаты черного пикселя в текстовый файл с одной координатой на строку.

Второй сценарий должен просто воссоздать исходное изображение, добавив черные пиксели в этих координатах к белому изображению. Это необходимо для проверки работоспособности скрипта № 1.

Вот код для скрипта № 1:

boolean stopt = false;
boolean writin = false;
PrintWriter output;
PImage input;
int limiter = 0;
void setup() {
  size(350, 500);
// Create a new file in the sketch directory
 output = createWriter("DIRECTIONS.TXT");
}
void draw(){
  background(0, 25, 51);
  //show processed image here.
  text("Click and type '1' to stop", 10, 440);
   text("Click and type '2' to convert image to command file", 10, 460);
    text("Copy DIRECTIONS.TXT to the printer's memory card after", 10, 480);
    if (stopt) {
      writin = false;
       text("finished or stopped.", 10, 420);
    }
    if (!stopt) {
      text("                          ", 10, 420);
    }
    if (writin) {
      stopt = false;
      text("translating image to printer commands", 10, 420);
    }
    if (!writin) {
      text("                          ", 10, 420);
    }
  if(input!= null){
    input.resize(300, 300);
    input.filter(THRESHOLD, 0.5);
    image(input, 10, 10, 330, 330);

     input.loadPixels();
  //Loop through each pixel (use image size instead of pixels.length!)
  if (limiter <= 90000) {
for (int x = 0; x < width; x++ ) {
  for (int y = 0; y < height; y++ ) { 
    color black = color(0, 0, 0);
    color c = get(x, y);
    if (c == black) {
    int loc = x + y * width;
     output.println(loc);
     writin = true;
  }
}
limiter = limiter + 1;
}

  }
  else if (limiter > 90000) {
    stopt = true;
  }
}
}

void imageSelected(File selection) {
  if (selection == null) {
    println("Window was closed or the user hit cancel.");
  } else {
    input = loadImage (selection.getAbsolutePath());
  }
}
void keyPressed() {
  if (key == '1') {
  output.flush(); // Writes the remaining data to the file
  output.close(); // Finishes the file
  stopt = true;
  //exit(); // Stops the program
}
if (key == '2') {
  selectInput("Select an image to process", "imageSelected");
  }
}

Вот код для сценария № 2 (должен воссоздать изображение, загруженное в сценарий № 1, из текстового файла, созданного сценарием № 1, но это не так)

PImage input;
int tex = 0;
void setup() {
  input = loadImage("white.png"); //mostly blank image in sketch folder 300 x 300 px.
  size (300, 300);
}
void draw() {
  loadPixels();
  input.loadPixels();
  String[] lines = loadStrings("direct.TXT"); //text file with each line being a 1D pixel coordinate in linear order.
  for (int i = 0; i < lines.length; i++) {
    tex = Integer.parseInt(lines[i]);
    for (int x = 0; x < width; x++ ) {
      for (int y = 0; y < height; y++ ) { 
        color black = color(0, 0, 0);
        //color c = get(x, y);
        int loc = x + y * width; 
        if (loc == tex) {
          pixels[loc] = black;
        }
      }
    }
  }
  updatePixels();
}
Источник

2 ответа

Решение

Это исправлено. Вот решение:

Скрипт для преобразования координат в текстовом файле обратно в изображение для проверки оригинального конвертера:

String[] input;// input file

void setup(){
  size(300, 300);
  input = loadStrings("DIRECTIONS.TXT");// load DIRECTIONS.TXT

  background(255);// clear image

  loadPixels();
  for(int i = 0; i < input.length; i ++){
    pixels[int(input[i])] = color(0);// for each line in the input file, set that pixel to black
  }
  updatePixels();
  println("done");
}

Скрипт для обработки и изображения в текстовый файл с координатами черного пикселя:

PImage input;// The selected image
String[] output;// The output file

void setup(){
  size(300, 300);
  output = new String[1];
  output[0] = "";// Avoid "null" at beginning
  selectInput("Select an image to process", "select");
}

void select(File selection){
  if(selection == null){
    exit();// exit if the input is null
  }else{
    input = loadImage(selection.getAbsolutePath());// load selected image
    input.resize(width, height);// reszie
    input.filter(THRESHOLD, 0.5);// make everything black and white

    input.loadPixels();
    for(int i = 0; i < input.pixels.length; i ++){// loop through all pixels
      if(input.pixels[i] == color(0)){
        output[0] += i + "\n";// if the pixel is black, write the position to the file
      }
    }
    saveStrings("DIRECTIONS.TXT", output);// save everything
    println("done");
  }
}
Источник

Имейте в виду, что draw() функция вызывается 60 раз в секунду.

Тогда в вашем draw() функция, у вас есть это вложенное for цикл:

for (int x = 0; x < width; x++ ) {
  for (int y = 0; y < height; y++ ) {

Это означает, что 60 раз в секунду вы зацикливаетесь на всех пикселях и выводите материал в файл.

Поэтому, чтобы решить вашу проблему, вам нужно изменить код, чтобы вы больше не делали этого.

Сделав шаг назад, вы должны привыкнуть к отладке кода, чтобы точно понять, что он делает. Это поможет вам в подобных случаях и поможет понять, как должен работать ваш код. Удачи!

Источник
Другие вопросы по тегам