Proc означает - Расчет доли / веса

Question

Я использую средства proc для расчета доли платежей, произведенных бизнес-линией, данные выглядят так:

data Test;
input ID Business_Line Payment2017;
Datalines;
1 1 1000
2 1 2000
3 1 3000
4 1 4000
5 2 500
6 2 1500
7 2 3000
;
run;

Я рассчитываю рассчитать дополнительный столбец, который по группам (business_line) вычисляет процентную долю (вес) платежа как таковую:

   data Test;
input ID Business_Line Payment2017 share;
Datalines;
1 1 1000 0.1
2 1 2000 0.2
3 1 3000 0.3
4 1 4000 0.4
5 2 500 0.1
6 2 1500 0.3
7 2 3000 0.6
;
run;

код, который я использовал до сих пор:

proc means data = test noprint;
class ID;
by business_line;
var Payment2017;
output out=test2 
sum = share;
weight = payment2017/share;
run;

Я также пытался

proc means data = test noprint;
class ID;
by business_line;
var Payment2017 /weight = payment2017;
output out=test3 ;
run;

ценим помощь.

Answer 1

Proc FREQ будет рассчитывать проценты. Вы можете разделить PERCENT столбец вывода, чтобы получить дробь, или работать с процентами вниз по течению.

В этом примере id кресты payment2017 чтобы гарантировать, что все исходные строки являются частью вывода. Если id не было, и были какие-либо повторяющиеся суммы платежа, FREQ будет агрегировать суммы платежей.

proc freq data=have noprint;
 by business_line;
 table id*payment2017 / out=want all;
 weight payment2017 ;
run;

Answer 2

Это удобно делать с proc sql:

proc sql;
   select *, payment2017/sum(payment2017) as share from test group by business_line;
quit;

шаг данных:

data have;
    do until (last.business_line);
    set test;
    by business_line notsorted;
    total+payment2017;
    end;
    do until (last.business_line);
    set test;
    by business_line notsorted;
    share=payment2017/total;
    output;
    end;
    call missing(total);
    drop total;
run;