Лучше VB.NET String Scrambler?

Question

Мне нужна была функция, чтобы взять строковую фразу и зашифровать ее. Итак, я написал это, но мне интересно, есть ли более эффективный / более быстрый способ сделать это?

    Public Function Scramble(phrase As String) As String
    Dim rand As New Random()
    Dim newPhrase As String = ""
    Dim clist As New List(Of String)

    ' break phrase into characters and add to list
    For i As Integer = 1 To Len(phrase)
        clist.Add(Mid(phrase.ToLower(), i, 1))
    Next

    ' remove from list randomly and add to new string
    Do While clist.Count > 0
        Dim r As Integer = rand.Next(0, clist.Count)
        newPhrase &= clist(r)
        clist.RemoveAt(r)
    Loop

    Return newPhrase

End Function

Answer 1

Вот один вкладыш Плутоникса:

Public Function Scramble(ByVal phrase As String) As String
    Static rand As New Random()
    Return New String(phrase.ToLower.ToCharArray.OrderBy(Function(r) rand.Next).ToArray)
End Function

... и вот альтернативная версия вашей более длинной формы:

Public Function Scramble(ByVal phrase As String) As String
    Static rand As New Random()
    Dim sb As New System.Text.StringBuilder
    Dim chars As New List(Of Char)(phrase.ToLower.ToCharArray)
    While chars.Count > 0
        Dim r As Integer = rand.Next(0, chars.Count)
        sb.Append(chars(r))
        chars.RemoveAt(r)
    End While
    Return sb.ToString
End Function