Oracle Apex - Сохранить список чисел в поле таблицы varray

Question

У меня есть таблица с varray числового поля type aptitude_list as varray(60) of number и хотите сохранить / обновить разделенный запятыми список из текстового поля апекса в нем.

Мой оператор SQL выглядит так:

INSERT INTO tbl_aptitude (ID, APTITUDE)
VALUES ('12345678', aptitude_list(1,2,3,4));

и прекрасно работает в SQL Developer.

Теперь я хочу заменить цифры своим текстовым полем aptitude_list(:P7_APTITUDE) с P7_APTITUDE='1,2,3,4', Это не может быть сохранено, потому что '1,2,3,4' недействительный номер

Как я могу сказать системе, что я хочу хранить четыре разных числа, а не одно?

Спасибо за вашу помощь!

Answer 1

Существует много способов разделения строки с разделителями в Oracle.

Одним из способов является использование функции:

Установка Oracle:

CREATE type aptitude_list as varray(60) of number
/

CREATE OR REPLACE FUNCTION split_String(
  i_str    IN  VARCHAR2,
  i_delim  IN  VARCHAR2 DEFAULT ','
) RETURN aptitude_list DETERMINISTIC
AS
  p_result       aptitude_list := aptitude_list();
  p_start        NUMBER(5) := 1;
  p_end          NUMBER(5);
  p_count        NUMBER(3) := 0;
  c_len CONSTANT NUMBER(5) := LENGTH( i_str );
  c_ld  CONSTANT NUMBER(5) := LENGTH( i_delim );
BEGIN
  IF c_len > 0 THEN
    p_end := INSTR( i_str, i_delim, p_start );
    WHILE p_end > 0 LOOP
      p_result.EXTEND;
      p_result( p_result.COUNT ) := SUBSTR( i_str, p_start, p_end - p_start );
      p_start := p_end + c_ld;
      p_end := INSTR( i_str, i_delim, p_start );
    END LOOP;
    IF p_start <= c_len + 1 THEN
      p_result.EXTEND;
      p_result( p_result.COUNT ) := SUBSTR( i_str, p_start, c_len - p_start + 1 );
    END IF;
  END IF;
  RETURN p_result;
END;
/

CREATE TABLE tbl_aptitude (
  ID       VARCHAR2(20),
  APTITUDE aptitude_list
); 

Тогда вы можете использовать:

INSERT INTO tbl_aptitude (ID, APTITUDE)
VALUES ('12345678', split_String(:P7_APTITUDE));

Запрос:

SELECT *
FROM   tbl_aptitude;

Выход:

| ID       | APTITUDE               |
|----------|------------------------|
| 12345678 | APTITUDE_LIST(1,2,3,4) |