Delphi WPD Event Callback - Получить имя файла

Question

Я пытаюсь отследить, когда файл создается на WPD-совместимом устройстве, например на цифровой камере или телефоне Android. Я регистрируюсь, чтобы получать события с Advice и мой обратный вызов вызван правильно, но я не могу правильно получить имя файла (возможно, OBJECT_NAME). Вот что у меня есть:

TPortableDeviceEventsCallback = class(TInterfacedObject, IPortableDeviceEventCallback)
 public
  function OnEvent(const pEventParameters: IPortableDeviceValues): HResult; dynamic; stdcall;
 end;
.
.
.
function TPortableDeviceEventsCallback.OnEvent(const pEventParameters: IPortableDeviceValues): HResult;
var
ObjName: PWideChar;
begin
  pEventParameters.GetStringValue(WPD_EVENT_PARAMETER_OBJECT_NAME, ObjName);
  Log(string(ObjName));
end;

Я получаю только мусор вместо добавленного / удаленного имени объекта. Что мне здесь не хватает?

Answer 1

Первый, OnEvent() не должен быть объявлен как dynamic, Уже virtual в IPortableDeviceEventCallback,

Во-вторых, вы не обрабатываете ошибки на IPortableDeviceValues.GetStringValue()или освобождая память, которую он возвращает. Это должно выглядеть больше так:

function TPortableDeviceEventsCallback.OnEvent(const pEventParameters: IPortableDeviceValues): HResult;
var
  Hr: HResult;
  ObjName: PWideChar;
begin
  Hr := pEventParameters.GetStringValue(WPD_EVENT_PARAMETER_OBJECT_NAME, ObjName);
  case Hr of
    S_OK: begin
      try
        Log('Object Name: ' + String(ObjName));
      finally
        CoTaskMemFree(ObjName);
      end;
    end;
    DISP_E_TYPEMISMATCH: begin
      Log('Object Name is not a string!');
    end;
    $80070490: // HRESULT_FROM_WIN32(ERROR_NOT_FOUND)
    begin
      Log('Object Name is not found!');
    end;
  else
    // some other error
    Log('Error getting Object Name: $' + IntToHex(Hr, 8));
  end;
  Result := S_OK;
end;

В-третьих, вы не смотрите на стоимость WPD_EVENT_PARAMETER_EVENT_ID параметр (который является единственным обязательным параметром), чтобы знать, какое событие вы получаете, чтобы узнать, какие параметры доступны с ним. Разные события имеют разные значения параметров.

Попробуйте перечислить доступные значения, чтобы увидеть, что вы на самом деле получаете в каждом событии:

function TPortableDeviceEventsCallback.OnEvent(const pEventParameters: IPortableDeviceValues): HResult;
var
  Hr: HResult;
  Count, I: DWORD;
  Key: PROPERTYKEY;
  Value: PROPVARIANT;
begin
  Log('Event received');

  Hr := pEventParameters.GetCount(Count);
  if FAILED(Hr) or (Count = 0) then Exit;

  Log('Param count: ' + IntToStr(Count));

  for I := 0 to Count-1 do
  begin
    Hr := pEventParameters.GetAt(I, Key, Value);
    if FAILED(Hr) then
    begin
      Log('Cant get parameter at index ' + IntToStr(I));
      Continue;
    end;
    try
      Log('Param Key: ' + GuidToString(Key.fmtid) + ', Value type: $' + IntToHex(Value.vt, 4));
      // log content of Value based on its particular data type as needed...
    finally
      PropVariantClear(Value);
    end;
  end;
  Result := S_OK;
end;