Клен магический квадрат

Question

Хорошо, я действительно нуждаюсь в вашей помощи, ребята, я действительно потерял это выглядит так просто, но я не могу понять это. Примечание: это для магического квадрата 3х3

Итак, вот условие для магического квадрата: 1. сумма элементов строки = k 2. сумма элементов столбца = k 3. сумма элементов диагонали = k

Вопрос в том, что я должен перевести 3 условия там в линейную систему Bx=0, где x=(a,b,c,d,e,f,g,h,i), которая представляет неизвестное из матрицы 3x3 и B является матрицей 7x9.

так вот что я сделал:

Итак, цель состоит в том, чтобы написать однородную систему в форме Bx=0, чтобы затем определить ее решение. Но сейчас я немного растерялся, чувствую себя глупо, потому что, кажется, легко, ха-ха, может кто-то поможет, будет очень признателен, спасибо!

Answer 1

Я предлагаю решить систему в терминах меньшего числа свободных переменных, а затем использовать перестановки [1,...,9] для проверки решений. Пожалуйста, попробуйте следующее, которое использует k=15 и возвращает единственное решение (после удаления поворотов и отражений):

restart;

# Number of variables.
m := 9;

# Variables.
X := [ seq( x[i], i=1..m ) ];

# Indices.
N := [ seq( i, i=1..m ) ];

# Equations.
EQ := [ x[1] + x[2] + x[3] = 15,
        x[4] + x[5] + x[6] = 15,
        x[7] + x[8] + x[9] = 15,
        x[1] + x[4] + x[7] = 15,
        x[2] + x[5] + x[8] = 15,
        x[3] + x[6] + x[9] = 15,
        x[1] + x[5] + x[9] = 15,
        x[3] + x[5] + x[7] = 15
];

# Constraints to remove equivalent solutions.
INEQ := [ x[1] < x[3], x[1] < x[7], x[1] < x[9], x[3] < x[7] ];

# Solve in terms of free parameters.
A, B := LinearAlgebra:-GenerateMatrix( EQ, X );
S := convert( LinearAlgebra:-LinearSolve( A, B, ':-free'=x ), 'list' );

# Free parameters.
Q := convert( indets( S, 'name' ), 'list' );
n := numelems( Q );

# Table to store solutions.
H := table();

# Cycle through all possible values for Q, first by combination, and then by permutation,
# and record any solutions found.
for i from 1 to combinat:-numbcomb( m, n ) do

    if i = 1 then
        C := convert( combinat:-firstcomb( m, n ), 'list' ):
    else
        C := convert( combinat:-nextcomb( C, m ), 'list' ):
    end if:

    for j from 1 to n! do

        if j = 1 then
            P := C:
        else
            P := combinat:-nextperm( P ):
        end if:

        T := eval( S, Q =~ P ):

        # Check if it is a solution satisfying all the constraints.
        if andmap( is, [ sort( T ) = N, op( eval( EQ, X =~ T ) ), op( eval( INEQ, X =~ T ) ) ] ) then
                H[T] := NULL:
        end if:

    end do:

end do:

# Solutions.
map( op, [ indices( H ) ] );