Как переместить папки в новое место с помощью скрипта Apple

Question

Я не знаю, как приступить к настройке сценария Apple, который перемещает папки с их содержимым в новую локацию, где эти папки уже существуют. Если это так, Finder должен перезаписать эти папки. Но в том же процессе у меня также есть определенные файлы, которые должны быть перемещены в новое место. Я не понимаю, как заставить это работать.

Это файлы и папки, которые я хочу переместить и перезаписать: OLDFOLDER > source, который должен быть перезаписан с назначением> NEWFOLDER

папки

• /Volumes/Netshare/Maxon/OLDFOLDER/ библиотека / скрипты
• /Volumes/Netshare/Maxon/OLDFOLDER/Off_Plugins

папки

• /Users/ имя /Library/Preferences/MAXON/OLDFOLDER/ библиотека / браузер
• /Users/ имя /Library/Preferences/MAXON/OLDFOLDER/ Prefs

документы (без окончания)

• /Users/ имя /Library/Preferences/MAXON/OLDFOLDER/ префы / xxx_net_80
• /Users/ имя /Library/Preferences/MAXON/OLDFOLDER/ префы /xxx_net_80_version4

документы (с окончанием)

• /Users/name/Library/Preferences/MAXON/OLDFOLDER/prefs/c4d_M_GLOBAL_POPUP.res

Я был бы признателен за любую помощь, которая дает понять, как это реализовать. Я пробовал некоторые исследования раньше, но не опередил...

Лучший

Answer 1

Это работает для меня, используя последнюю версию Sierra

-- Set The Variables To Your Folder Locations
set folderToBeMoved to (path to desktop as text) & "Folder_To_Move"
set destinationFolder to (path to desktop as text) & "New_Location"

-- Select Files You Want To Move To A Different Location
set filesToMove to choose file with prompt ¬
    "Choose Files To Be Moved" invisibles false ¬
    multiple selections allowed true ¬
    without showing package contents

-- Move Files To Different Folder 
tell application "Finder"
    repeat with i from 1 to number of items in filesToMove
        set this_item to item i of filesToMove
        set moveFiles to move file this_item ¬
            to destinationFolder ¬
            with replacing
    end repeat
end tell

-- Move Folder To Different Folder 
tell application "Finder"
    set moveFolder to move folder folderToBeMoved ¬
        to destinationFolder ¬
        with replacing
end tell

Answer 2

Спасибо @wch1zpink

Я получил необходимый скрипт для работы с некоторыми улучшениями для моего случая. Вот как это работает сейчас:

-- Set The Variables To Program Netshare Folder Locations
set NetsharePath to "Macintosh HD:Volumes:Netshare:Maxon:"
set NetshareFolderOrigin to NetsharePath & "19.044_RB221380"
set NetshareFolderDestination to NetsharePath & "Testfolder"
-- (path to desktop as text) & "New_Location"

set NetshareFoldersToMove to {":library:scripts", ":Off_Plugins", ":plugins"}
set NetshareSubfolderDestination to {":library", "", ""}

-- Move Netshare Folders To New Folders 
tell application "Finder"
    repeat with i from 1 to number of items in NetshareFoldersToMove
        set folderToBeMoved to NetshareFolderOrigin & item i of NetshareFoldersToMove
        set NetshareFolderDestinationCombination to NetshareFolderDestination & item i of NetshareSubfolderDestination
        set netMoveFolder to move folder folderToBeMoved ¬
            to NetshareDestinationFolderCombination ¬
            with replacing
        -- duplicate folderToBeMoved to NetshareFolderDestinationCombination
    end repeat
end tell

-- Set The Variables To Preferences Folder Locations
set Username to "USER"
set PreferencesPath to "Macintosh HD:Users:" & Username & ":Library:Preferences:Maxon:"
set PreferencesFolderOriginName to "19.044_RB221380_FDCD4BE0"
set PreferencesFolderDestinationName to "Test"
set PreferencesPathOrigin to PreferencesPath & PreferencesFolderOriginName
set PreferencesPathDestination to PreferencesPath & PreferencesFolderDestinationName

set PreferencesFoldersToMove to {":_bugreports", ":bug.html", ":library:browser", ":library:layout", ":prefs:cache", ":prefs:directorycache",":prefs:c4d_M_GLOBAL_POPUP.res", ":prefs:CINEMA 4D.prf", ":prefs:shortcuttable.res", ":prefs:template.l4d", ":prefs:template.prf"}
set PreferencesSubfolderDestination to {"", "", ":library", ":library", ":prefs", ":prefs", ":prefs", ":prefs", ":prefs", ":prefs", ":prefs"}

-- Move Preferences Folders To new Folders 
tell application "Finder"
    repeat with i from 1 to number of items in PreferencesFoldersToMove
        set prefFolderToBeMoved to PreferencesPathOrigin & item i of PreferencesFoldersToMove
        set PreferencesDestinationFolderCombination to PreferencesPathDestination & item i of PreferencesSubfolderDestination
        set prefMoveFolder to move folder prefFolderToBeMoved ¬
            to PreferencesDestinationFolderCombination ¬
            with replacing
        -- duplicate prefFolderToBeMoved to PreferencesDestinationFolderCombination
    end repeat
end tell