Пролог GNU - оператор Univ? Объяснение этого

Question

Итак, унив оператор. Я не совсем понимаю это.

Например это:

foo(PredList,[H|_]) :- bar(PredList,H).
foo(PredList,[_|T]) :- foo(PredList,T),!.

bar([H|_],Item) :- G =.. [H,Item],G.
bar([_|T],Item) :- bar(T,Item).

Что это делает? Это выглядит, чтобы увидеть, если другой предикат верен. Я не понимаю, что делает ".."

Как бы вы переписали это без оператора Univ?

Answer 1

Univ (=..) разбивает термин на список составляющих или строит термин из такого списка. Пытаться:

?- f(x,y) =.. L.
L = [f, x, y].

?- f(x,y,z) =.. [f|Args].
Args = [x, y, z].

?- Term =.. [g,x,y].
Term = g(x, y).

bar кажется, вызывает каждый предикат в PredList на Item, с foo отступая над Items. (Использование переменной в качестве предиката не переносимо; call предикат должен быть предпочтительным.)

Изменить: Каарел прав, Univ может быть заменен на functor/3 а также arg/3, следующее:

bar([H|_],Item) :-
    functor(Goal,H,1),   % unifies Goal with H(_)
    arg(1,Goal,Item),    % unifies first argument of Goal with Item
    call(Goal).          % use this for portability

Answer 2

Наиболее подходящим, по моему мнению, будет переписать:

 bar( [H|_], Item ) :- call(H, Item).

call/n еще не являются частью основного стандарта ISO, но они могут стать в ближайшем будущем (*). Многие системы Prolog уже поддерживают их.

Есть одна причина, почему call/n должно быть предпочтительнее простого (=..)/2 а также functor/3 + arg/3 решения. call/n Решение способно обрабатывать замыкания (**).

С простым (=..)/2 а также functor/3 + arg/3 решение можно вызвать bar/2 только с атомами в первом аргументе списка. Например:

 p1(1).
 p2(2).
 ?- bar( [p1, p2], 1 ).
 Yes
 ?- bar( [p1, p2], 2 ).
 Yes
 ?- bar( [p1, p2], 3 ).
 No

С замыканиями мы не ограничены атомами, и мы могли бы сэкономить некоторые усилия по кодированию. Например, мы можем сделать следующее напрямую:

 ?- bar( [=(1), =(2)], 1 ).
 Yes
 ?- bar( [=(1), =(2)], 2 ).
 Yes
 ?- bar( [=(1), =(2)], 3 ).
 No

С уважением

(*)
Проект технического исправления 2
http://www.complang.tuwien.ac.at/ulrich/iso-prolog/dtc2

(**)
Кто это придумал? call/n Предикаты
http://www.complang.tuwien.ac.at/ulrich/Prolog-inedit/naish.html