Пакетный скрипт для поиска и замены строки в текстовом файле в течение минуты для файлов до 12 МБ

Question

Я написал пакетный скрипт для замены строки в текстовом файле.

Ниже приводится сценарий.

@echo off &setlocal
set "search=%1"
set "replace=%2"
set "textfile=Input.txt"
set "newfile=Output.txt"
(for /f "delims=" %%i in (%textfile%) do (
    set "line=%%i"
    setlocal enabledelayedexpansion
    set "line=!line:%search%=%replace%!"
    echo(!line!
    endlocal
))>"%newfile%"
del %textfile%
rename %newfile%  %textfile%

Но для файла размером 12 МБ требуется около 7 минут. Я хочу, чтобы это было меньше минуты. Можем ли мы использовать команду find или findstr, чтобы сократить время, которое требуется?

Answer 1

Дайте этому шанс:

@echo off
setlocal

call :FindReplace "findstr" "replacestr" input.txt

exit /b 

:FindReplace <findstr> <replstr> <file>
set tmp="%temp%\tmp.txt"
If not exist %temp%\_.vbs call :MakeReplace
for /f "tokens=*" %%a in ('dir "%3" /s /b /a-d /on') do (
  for /f "usebackq" %%b in (`Findstr /mic:"%~1" "%%a"`) do (
    echo(&Echo Replacing "%~1" with "%~2" in file %%~nxa
    <%%a cscript //nologo %temp%\_.vbs "%~1" "%~2">%tmp%
    if exist %tmp% move /Y %tmp% "%%~dpnxa">nul
  )
)
del %temp%\_.vbs
exit /b

:MakeReplace
>%temp%\_.vbs echo with Wscript
>>%temp%\_.vbs echo set args=.arguments
>>%temp%\_.vbs echo .StdOut.Write _
>>%temp%\_.vbs echo Replace(.StdIn.ReadAll,args(0),args(1),1,-1,1)
>>%temp%\_.vbs echo end with

Answer 2

Просто скачайте пердеть (найти и заменить текст) отсюда

использовать его в CMD (для простоты использования я добавляю папку fart в переменную path)

вот пример:

fart -r "C:\myfolder\*.*" findSTR replaceSTR

эта команда будет искать в C:\myfolder и всех подпапках и заменять findSTR на replaceSTR

-r означает рекурсивную обработку подпапок.

пердеть действительно быстро и легко

Answer 3

Вариант с использованием Bat/Powershell (нужен.net framework):

replace.bat:

@echo off

call:DoReplace "Findstr" "replacestr" test.txt test1.txt
exit /b

:DoReplace
echo ^(Get-Content "%3"^) ^| ForEach-Object { $_ -replace %1, %2 } ^| Set-Content %4>Rep.ps1
Powershell.exe -executionpolicy ByPass -File Rep.ps1
if exist Rep.ps1 del Rep.ps1
echo Done
pause

Answer 4

Это использует вспомогательный командный файл с именем repl.bat - загрузить с: https://www.dropbox.com/s/qidqwztmetbvklt/repl.bat

Место repl.bat в той же папке, что и пакетный файл, или в папке, которая находится в пути.

Repl.bat - это гибридный пакетный файл, использующий собственные сценарии Windows, и он намного быстрее, чем обычный пакетный сценарий.

L Параметр switch выполняет текстовый поиск и заменяет буквенную строку, и я ожидаю, что файл размером 12 МБ завершится за несколько секунд на современном ПК.

@echo off &setlocal
set "search=%~1"
set "replace=%~2"
set "textfile=Input.txt"
set "newfile=Output.txt"
call repl.bat "%search%" "%replace%" L < "%textfile%" >"%newfile%"
del "%textfile%"
rename "%newfile%" "%textfile%"

Answer 5

Как насчет этого, ребята?

set search=%1
set replace=%2
set textfile=Input.txt    

set line1=with open('%textfile%', 'rw') as f:
set line2=f.write(f.read().replace('%search%', '%replace%'))
python -c "%line1%%line2%"

Muhahaha

---

Редактировать:

В сумасшедшем лайнере

python -c "with open('%textfile%', 'rw') as f: f.write(f.read().replace('%search%', '%replace%'))"

Answer 6

Попробуй это:

@echo off &setlocal
setlocal enabledelayedexpansion

set "search=%1"
set "replace=%2"
set "textfile=Input.txt"
set "newfile=Output.txt"
(for /f "delims=" %%i in (%textfile%) do (
    set "line=%%i"
    set "line=!line:%search%=%replace%!"
    echo(!line!
))>"%newfile%"
del %textfile%
rename %newfile%  %textfile%
endlocal