Perl - создание массива хэшей на основе хеш-фильтра

Question

У меня есть этот хэш, который содержит некоторую информацию:

my %hash = (
    key_1 => {
        year => 2000,
        month => 02,
    }, 
    key_2 => {
        year => 2000,
        month => 02,
    }, 
    key_3 => {
        year => 2000,
        month => 03,
    }, 
    key_4 => {
        year => 2000,
        month => 05,
    }, 
    key_5 => {
        year => 2000,
        month => 01,
    }
);

Я не хочу создавать массив хешей, в котором каждый из элементов массива перечисляет каждую пару пар ключ / значение хеша, которые имеют одинаковые год и месяц.

В общем, я хочу создать что-то вроде этого:

$VAR1 = [
    'key_1' => {
        'month' => 2,
        'year' => 2000
    },
    'key_2' => {
        'month' => 2,
        'year' => 2000
    }
], [
    'key_3' => {
        'month' => 3,
        'year' => 2000
    }
], [
    'key_4' => {
        'month' => 3,
        'year' => 2000
    }
], [
    'key_5' => {
        'year' => 2000,
        'month' => 1
    }
];

Реальный вопрос здесь: как я могу сравнить значения ключа хеш-ключа с другими значениями ключа ключа и сделать из него карту.

Спасибо за ваше время! знак равно

Answer 1

Я получаю немного разные результаты - key_3 и key_4 должны принадлежать к одной группе.

my %by_year_and_month;
undef $by_year_and_month{ $hash{$_}{year} }{ $hash{$_}{month} }{$_}
    for keys %hash;

my $result;
for my $year (keys %by_year_and_month) {
    for my $month (keys %{ $by_year_and_month{$year} }) {
        push @$result, [ map { $_ => { month => $month, year => $year } }
                         keys %{ $by_year_and_month{$year}{$month} } ];
    }
}

Answer 2

my %hash = (
    key_1 => {year => 2000, month => 02},
    key_2 => {year => 2000, month => 02},
    key_3 => {year => 2000, month => 03},
    key_4 => {year => 2000, month => 03},
    key_5 => {year => 2000, month => 01}
);
my @v=qw(year month);             # keys compared
my @k=sort keys %hash;
my(@a,%i);
push@{$a[sub{$i{join$;,map$_[0]{$_},@v}//=@a}->($hash{$_})]},($_=>$hash{$_}) for@k;
use Data::Dumper; print Dumper(\@a);

Answer 3

Вы говорите, что хотите следующее, но это не имеет смысла.

 $VAR1 = [$k,$v,$k,$v...], [...], [...], ...;

---

В принятом ответе предполагается, что вы хотите получить следующее:

$VAR1 = [ [$k,$v,$k,$v,...], [...], [...], ... ];

Это может быть получено следующим образом:

sub group_id { sprintf "%04d-%02d", @{ $_[0] }{qw( year month )} }

my %grouped;
for my $k (keys(%hash)) {
   my $v = $hash{$k};
   push @{ $grouped{ group_id($v) } }, $k, $v;
}

my $VAR1 = [ map { $grouped{$_} } sort keys %grouped ];

---

Но это очень странный формат. Следующее будет иметь гораздо больше смысла:

$VAR1 = [ { $k=>$v,$k=>$v,...}, {...}, {...}, ... ];

Это может быть получено следующим образом:

sub group_id { sprintf "%04d-%02d", @{ $_[0] }{qw( year month )} }

my %grouped;
for my $k (keys(%hash)) {
   my $v = $hash{$k};
   $grouped{ group_id($v) }{$k} = $v;
}

my $VAR1 = [ map { $grouped{$_} } sort keys %grouped ];

---

В обоих случаях ключ состоит в том, чтобы использовать хеш для группировки похожих вещей.

В обоих случаях полученные группы упорядочены в хронологическом порядке.