Visual Fox Pro доступ к файлам

Question

У меня есть функция, которая создает XML-файлы с некоторыми данными внутри. Каждый раз, во-первых, он удаляет старый файл. Все работает нормально, за исключением того, что иногда он зависает, а сам файл блокируется. Его размер составляет 0 кб, и программа не может даже удалить его. И я должен убить процесс, удалить файл самостоятельно, а затем снова запустить программу. Можно ли убить все процессы одной и той же программы перед началом новой? Или, по крайней мере, установить таймер, чтобы он автоматически выключался через некоторое время?

Нужны идеи, спасибо.

fHandle = f_cFile("D:\Data\new_eur\Saskaitos.xml")
if fHandle < 0
**=messagebox("Can't create file!",16,"!!!")
=STRTOFILE("Can't create XML file" + CHR(13) + CHR(10), "d:\Log.txt", 1)
quit
ENDIF

** Header
if fputs(fHandle, '<?xml version="1.0" encoding="windows-1257"?>') < 0
=fclose(fHandle)
=STRTOFILE("Can't write to XML file" + CHR(13) + CHR(10), "d:\Log.txt", 1)
quit
endif

=STRTOFILE(TTOC(dateTIME()) + ": " + "XML ok"+CHR(13)+CHR(10), "d:\LogData.txt", 1)
=fputs(fHandle, "<Accounts>")

enteris = CHR(13)
DO WHILE NOT EOF()
=fputs(fHandle, "<Detali>")
=fputs(fHandle, "<Snr><![CDATA[" + ALLTRIM(Data.dok_nr) + "]]></Snr>" + enteris)
=fputs(fHandle, "<Code_ks><![CDATA[" + ALLTRIM(Data.Code_ks) + "]]></Code_ks>" + enteris)
=fputs(fHandle, "<Sdata>" + ALLTRIM(Data.dok_data) + "</Sdata>" + enteris)
=fputs(fHandle, "<Term>" + ALLTRIM(Duomenys.Terminas) + "</Term>" + enteris)
=fputs(fHandle, "<Manager><![CDATA[" + ALLTRIM(Data.Code_ms) + "]]></Manager>" + enteris)
IF Data.val_poz = 0
    =fputs(fHandle, "<MokSuma>" + ALLTRIM(STR(Duomenys.SumaMok, 12, 2)) + "</MokSuma>" + enteris)
    =fputs(fHandle, "<ApSuma>" + ALLTRIM(STR(Duomenys.ApSuma, 12, 2)) + "</ApSuma>" + enteris)
 ELSE
    =fputs(fHandle, "<MokSuma>" + ALLTRIM(STR(Duomenys.SumaVal, 12, 2)) + "</MokSuma>" + enteris)
    =fputs(fHandle, "<ApSuma>" + ALLTRIM(STR(Duomenys.ApVal, 12, 2)) + "</ApSuma>" + enteris)
ENDIF 
=fputs(fHandle, "</Detali>")    
skip
ENDDO
fputs(fHandle, "</Accounts>")
=fclose(fHandle)

Теперь это код, который помещает данные XML в файл. В какой-то момент он зависает, и при следующем запуске программа все еще использует тот же файл.

Функция f_cFile:

FUNCTION f_cFile
PARAMETERS fName
fHandle = fcreate(fName)
IF fHandle < 0
    IF FILE(fName,1)
        DELETE FILE fName
        IF FILE(fName,1)
            =STRTOFILE("Can't delete old file: " + fName + CHR(13) + CHR(10), " d:\Log.txt", 1)
        ELSE    
            fHandle = fcreate(fName)        
        ENDIF   
    ENDIF
ENDIF
RETURN fHandle
ENDFUNC

Answer 1

Ух ты... много других вариантов, чтобы упростить проблему блокировки. Во-первых, не слишком сильно меняя свои вещи, это строить через строки... Создайте переменную и продолжайте добавлять к ней, пока вы не закончите, затем запишите ее с помощью одной команды записи, например

enteris = CHR(13)
myXML = '<?xml version="1.0" encoding="windows-1257"?>' + enteris;
        + "<Accounts>"

SCAN 
    myXML   = myXML + "<Detali>";
            + "<Snr><![CDATA[" + ALLTRIM(Data.dok_nr) + "]]></Snr>" + enteris;
            + "<Code_ks><![CDATA[" + ALLTRIM(Data.Code_ks) + "]]></Code_ks>" + enteris;
            + "<Sdata>" + ALLTRIM(Data.dok_data) + "</Sdata>" + enteris;
            + "<Term>" + ALLTRIM(Duomenys.Terminas) + "</Term>" + enteris;
            + "<Manager><![CDATA[" + ALLTRIM(Data.Code_ms) + "]]></Manager>" + enteris

    IF Data.val_poz = 0
        myXML = myXML + "<MokSuma>" + ALLTRIM(STR(Duomenys.SumaMok, 12, 2)) + "</MokSuma>" + enteris;
                + "<ApSuma>" + ALLTRIM(STR(Duomenys.ApSuma, 12, 2)) + "</ApSuma>" + enteris
    ELSE
        myXML = myXML + "<MokSuma>" + ALLTRIM(STR(Duomenys.SumaVal, 12, 2)) + "</MokSuma>" + enteris;
                + "<ApSuma>" + ALLTRIM(STR(Duomenys.ApVal, 12, 2)) + "</ApSuma>" + enteris
    ENDIF 
    myXML = myXML + "</Detali>";
ENDSCAN 

myXML = myXML + "</Accounts>"

if StrToFile( myXML, "D:\Data\new_eur\Saskaitos.xml" ) = 0
    =STRTOFILE("Can't create XML file" + CHR(13) + CHR(10), "d:\Log.txt", 1)
endif 

Готово... Пусть VFP обрабатывает открытие и закрытие низкого уровня записи.