Обобщение набора фактов в CLIPS (попытка найти совпадающие значения слотов в многослотовых слотах)

Question

Я пытаюсь сделать что-то вроде "обобщения фактов" в CLIPS (не уверен, какой термин описывает это лучше всего), и я не уверен, как это сделать наилучшим образом.

Рассмотрим такую ​​ситуацию. У меня есть набор фактов, которые описаны ниже шаблонов:

(deftemplate MAIN::simplecause
   (slot coraxidcause (type INTEGER) (default 0))
   (slot changeidcause (type SYMBOL) (default PF1))
   (multislot coraxinfo (type SYMBOL) (default undefined))
   (multislot changeinfo (type SYMBOL) (default undefined)))  

(deftemplate MAIN::finalcause  
   (multislot coraxinfo (type SYMBOL) (default undefined))
   (multislot changeinfo (type SYMBOL) (default undefined))
   (slot casecount (type INTEGER) (default 0)))

Комбинация Coraxidcause и changeidcause является своего рода ключом - комбинация этих двух полей уникальна. changeinfo и coraxinfo имеют некоторые символические значения в слотах (у меня всегда есть не более 10 значений в каждом из этих слотов)

Итак, у меня есть несколько простых причин. Я хочу найти, какие значения одинаковы в changeinfo и coraxinfo, и подтвердить их. Например, если у меня есть эти простые факты:

(simplecause (coraxidcause id1) (changeidcause id1) (coraxinfo 1 2 3) (changeinfo a b c))

(simplecause (coraxidcause id2) (changeidcause id2) (coraxinfo 2 3 6 7) (changeinfo e a b d f))

(simplecause (coraxidcause id3) (changeidcause id3) (coraxinfo 9 11 2 3 0) (changeinfo g a b))

(simplecause (coraxidcause id4) (changeidcause id4) (coraxinfo 77) (changeinfo z))

Я хочу утверждать такой факт:

(finalcause (coraxinfo 2 3) (changeinfo a b))

На данный момент я написал это правило:

(defrule MAIN::cause_generalization_initial
   (simplecause (coraxidcause ?coraxid1) (changeidcause ?factid1) (coraxinfo $? $?coraxdetails $?) (changeinfo $? $?changedetails $?))
   (simplecause (coraxidcause ?coraxid2) (changeidcause ?factid2) (coraxinfo $? $?coraxdetails $?) (changeinfo $? $?changedetails $?))
   (or (test (<> ?coraxid1 ?coraxid2))
                                (neq ?factid1 ?factid2))
                (not (finalcause (coraxinfo $?coraxdetails) (changeinfo $?changeddetails)))
   =>
   (assert (finalcause (coraxinfo ?coraxdetails) (changeinfo ?changedetails) (casecount 0))))

Проблема в том, что, если мы вернемся к тем четырем фактам, которые упоминались ранее, это подтверждает следующее:

(finalcause (coraxinfo 2) (changeinfo a))
(finalcause (coraxinfo 3) (changeinfo a))
(finalcause (coraxinfo 2 3) (changeinfo b))

и т.п.

Мне не нужны все эти "частичные совпадения", мне просто нужна полностью совпадающая часть - (finalcause (coraxinfo 2 3) (changeinfo a b)), и я не уверен, как это сделать. Более того, действительно ужасные вещи случаются, когда у меня происходит что-то вроде этого:

(simplecause (coraxidcause id5) (changeidcause id5) (coraxinfo 0 1 2 3) (changeidcause a b c))

(simplecause (coraxidcause id6) (changeidcause id6) (coraxinfo 6 1 2 3) (changeidcause a b c))

В этот момент движок CLIPS переходит в нечто вроде бесконечного цикла, LHS перечисляет все возможные совпадения:

(finalcause (coraxinfo 1) (changeidcause a))
(finalcause (coraxinfo 1) (changeidcause a b))

и т.п.

Это занимает много времени (и все еще делает то, что мне не нужно, как я уже упоминал ранее). Я новичок в CLIPS, поэтому я предполагаю, что я упускаю что-то очевидное, должен быть какой-то способ сделать то, что мне нужно. Я буду признателен за любую помощь или предложения о том, как это сделать. Любые идеи будут действительно полезны.

Похоже, я не уточнил, что именно я хочу. Мне нужно найти все возможные "совпадения" по всем фактам, например, если у меня есть эти факты:

    (deffacts start
       (simplecause (coraxinfo 1 2 3) (changeinfo a b c))
       (simplecause (coraxinfo 7 8 2 3 9) (changeinfo d a b e))
       (simplecause (coraxinfo 2 3 10 13) (changeinfo f g a b z))
       (simplecause (coraxinfo 77 88 99 66) (changeinfo k m l s))
       (simplecause (coraxinfo 88 99 11 22) (changeinfo v k m w))
       (simplecause (coraxinfo 13 88 99) (changeinfo k m))
       (simplecause (coraxinfo 666 777) (changeinfo abc def)))

Мне нужно получить это в качестве вывода:

(finalcause (coraxinfo 2 3) (changeinfo a b))
(finalcause 88 99) (changeinfo k m)) 

Answer 1

Вы можете сделать это с помощью одного правила, но это немного грубовато:

CLIPS> 
(deftemplate simplecause
   (multislot coraxinfo)
   (multislot changeinfo))
CLIPS>    
(deftemplate finalcause   
   (multislot coraxinfo)
   (multislot changeinfo))
CLIPS> 
(deffacts start
   (simplecause (coraxinfo 1 2 3) (changeinfo a b c))
   (simplecause (coraxinfo 7 8 2 3 9) (changeinfo d a b e))
   (simplecause (coraxinfo 2 3 10 13) (changeinfo f g a b z)))
CLIPS> 
(defrule cause_generalization_initial
   ;; There's a simplecause with two subsequences
   (simplecause (coraxinfo $? $?coraxdetails $?) (changeinfo $? $?changedetails $?))
   ;; And every simplecause contains that same subsequence
   (forall (simplecause (coraxinfo $?all1) (changeinfo $?all2))
           (test (and (subsetp $?coraxdetails $?all1) (subsetp $?changedetails $?all2))))
   ;; And there's not a longer subsequence where every simplecause contains that subsequence
   (not (and (simplecause (coraxinfo $? $?coraxdetails2 $?) (changeinfo $? $?changedetails2 $?)) 
             (test (or (and (>= (length $?coraxdetails2) (length $?coraxdetails))
                            (> (length $?changedetails2) (length $?changedetails)))
                       (and (> (length $?coraxdetails2) (length $?coraxdetails))
                            (>= (length $?changedetails2) (length $?changedetails)))))
             (forall (simplecause (coraxinfo $?all1) (changeinfo $?all2))
                     (test (and (subsetp $?coraxdetails2 $?all1) (subsetp $?changedetails2 $?all2))))))
   ;; And a fact for the subsequences has not been generated (since 
   ;; the rule will have an activation for each simple cause)
   (not (finalcause (coraxinfo $?coraxdetails) (changeinfo $?changedetails)))
   =>
   (assert (finalcause (coraxinfo $?coraxdetails) (changeinfo $?changedetails))))
CLIPS> (reset)
CLIPS> (agenda)
0      cause_generalization_initial: f-3,*,*,*
0      cause_generalization_initial: f-2,*,*,*
0      cause_generalization_initial: f-1,*,*,*
For a total of 3 activations.
CLIPS> (watch rules)
CLIPS> (run)
FIRE    1 cause_generalization_initial: f-3,*,*,*
CLIPS> (facts)
f-0     (initial-fact)
f-1     (simplecause (coraxinfo 1 2 3) (changeinfo a b c))
f-2     (simplecause (coraxinfo 7 8 2 3 9) (changeinfo d a b e))
f-3     (simplecause (coraxinfo 2 3 10 13) (changeinfo f g a b z))
f-4     (finalcause (coraxinfo 2 3) (changeinfo a b))
For a total of 5 facts.
CLIPS>

Немного легче понять, если работа распределена по нескольким правилам:

CLIPS> (unwatch all)
CLIPS> 
(deftemplate simplecause
   (multislot coraxinfo)
   (multislot changeinfo))
CLIPS>    
(deftemplate finalcause   
   (multislot coraxinfo)
   (multislot changeinfo))
CLIPS> 
(deffacts start
   (simplecause (coraxinfo 1 2 3) (changeinfo a b c))
   (simplecause (coraxinfo 7 8 2 3 9) (changeinfo d a b e))
   (simplecause (coraxinfo 2 3 10 13) (changeinfo f g a b z)))
CLIPS> 
(defrule cause_generalization_initial
   (simplecause (coraxinfo $? $?coraxdetails $?) (changeinfo $? $?changedetails $?))
   (forall (simplecause (coraxinfo $?all1) (changeinfo $?all2))
           (test (and (subsetp $?coraxdetails $?all1) (subsetp $?changedetails $?all2))))
   =>
   (assert (finalcause (coraxinfo $?coraxdetails) (changeinfo $?changedetails))))
CLIPS> 
(defrule cause_generalization_better
   ?f <- (finalcause (coraxinfo $?coraxdetails1) (changeinfo $?changedetails1))
   (finalcause (coraxinfo $?coraxdetails2) (changeinfo $?changedetails2))
   (test (or (< (length $?coraxdetails1) (length $?coraxdetails2))
             (< (length $?changedetails1) (length $?changedetails2))))
   =>
   (retract ?f))
CLIPS> (reset)
CLIPS> (run)
CLIPS> (facts)
f-0     (initial-fact)
f-1     (simplecause (coraxinfo 1 2 3) (changeinfo a b c))
f-2     (simplecause (coraxinfo 7 8 2 3 9) (changeinfo d a b e))
f-3     (simplecause (coraxinfo 2 3 10 13) (changeinfo f g a b z))
f-24    (finalcause (coraxinfo 2 3) (changeinfo a b))
For a total of 5 facts.
CLIPS> 

Ключевой частью обоих методов является общий условный элемент, который проверяет, что каждая простая причина содержит рассматриваемую подпоследовательность.

Модифицированный подход, основанный на вашем комментарии:

CLIPS> (clear)
CLIPS>     
(deftemplate simplecause
   (multislot coraxinfo)
   (multislot changeinfo))
CLIPS>     
(deftemplate finalcause   
   (multislot coraxinfo)
   (multislot changeinfo))
CLIPS>  
(deffacts start
   (simplecause (coraxinfo 1 2 3) (changeinfo a b c))
   (simplecause (coraxinfo 7 8 2 3 9) (changeinfo d a b e))
   (simplecause (coraxinfo 2 3 10 13) (changeinfo f g a b z))
   (simplecause (coraxinfo 77 88 99 66) (changeinfo k m l s))
   (simplecause (coraxinfo 88 99 11 22) (changeinfo v k m w))
   (simplecause (coraxinfo 13 88 99) (changeinfo k m))
   (simplecause (coraxinfo 666 777) (changeinfo abc def)))
CLIPS>    
(defrule cause_generalization_initial
   ?f1 <- (simplecause (coraxinfo $? ?v11 ?v12 $?) (changeinfo $? ?v21 ?v22 $?))
   ?f2 <- (simplecause (coraxinfo $? ?v11 ?v12 $?) (changeinfo $? ?v21 ?v22 $?))
   (test (neq ?f1 ?f2))
   (not (finalcause (coraxinfo ?v11 ?v12) (changeinfo ?v21 ?v22)))
   =>
   (assert (finalcause (coraxinfo ?v11 ?v12) (changeinfo ?v21 ?v22))))
CLIPS> (reset)
CLIPS> (watch rules)
CLIPS> (run)
FIRE    1 cause_generalization_initial: f-6,f-5,*
FIRE    2 cause_generalization_initial: f-3,f-2,*
CLIPS> (facts)
f-0     (initial-fact)
f-1     (simplecause (coraxinfo 1 2 3) (changeinfo a b c))
f-2     (simplecause (coraxinfo 7 8 2 3 9) (changeinfo d a b e))
f-3     (simplecause (coraxinfo 2 3 10 13) (changeinfo f g a b z))
f-4     (simplecause (coraxinfo 77 88 99 66) (changeinfo k m l s))
f-5     (simplecause (coraxinfo 88 99 11 22) (changeinfo v k m w))
f-6     (simplecause (coraxinfo 13 88 99) (changeinfo k m))
f-7     (simplecause (coraxinfo 666 777) (changeinfo abc def))
f-8     (finalcause (coraxinfo 88 99) (changeinfo k m))
f-9     (finalcause (coraxinfo 2 3) (changeinfo a b))
For a total of 10 facts.
CLIPS> 

Answer 2

Хорошо, с помощью Гари вот окончательный результат:

(deftemplate simplecause
   (multislot coraxinfo)
   (multislot changeinfo))

(deftemplate finalcause   
   (multislot coraxinfo)
   (multislot changeinfo))

(deffacts start
   (simplecause (coraxinfo 1 2 3) (changeinfo a b c))
   (simplecause (coraxinfo 7 8 2 3 9) (changeinfo d a b e))
   (simplecause (coraxinfo 2 3 10 13) (changeinfo f g a b z))
   (simplecause (coraxinfo 77 88 99 66) (changeinfo k m l s))
   (simplecause (coraxinfo 88 99 11 22) (changeinfo v k m w))
   (simplecause (coraxinfo 13 88 99) (changeinfo k m))
   (simplecause (coraxinfo 666 777) (changeinfo abc def)))

(defrule cause_generalization_initial
   ?f1 <- (simplecause (coraxinfo $? $?match1 $?) (changeinfo $? $?match2 $?))
   ?f2 <- (simplecause (coraxinfo $? $?match1 $?) (changeinfo $? $?match2 $?))
   (test (neq ?f1 ?f2))
   (not (finalcause (coraxinfo $?match1) (changeinfo $?match2)))
   =>
   (assert (finalcause (coraxinfo $?match1) (changeinfo $?match2))))

(reset)

(run)

;retract simplecause facts and prevent them from adding 'partial matched final causes'
(do-for-all-facts ((?f simplecause)) TRUE (retract ?f)) 

;retracts partially matched facts so that we have only best matches
(defrule cause_generalization_better
   ?f1 <- (finalcause (coraxinfo $?match1) (changeinfo $?match2))
   ?f2 <- (finalcause (coraxinfo $?matchbig1) (changeinfo $?matchbig2))
   (test (and (subsetp $?match1 $?matchbig1) (subsetp $?match2 $?matchbig2) (neq ?f1 ?f2)))
   =>
   (retract ?f1))


;in some cases we can see facts like (finalcause (coraxinfo 13) (changeinfo))
;this happens when there is match by coraxinfo but no match by changeinfo or vice versa
;we retract such facts too

(defrule cause_generalization_remove_empty_coraxinfo
   ?f1 <- (finalcause (coraxinfo))
   =>
   (retract ?f1))

(defrule cause_generalization_remove_empty_changeinfo
   ?f1 <- (finalcause (changeinfo))
   =>
   (retract ?f1))

(run)