Добавить опорные линии в SAS Heatmap

Question

Я делаю тепловые карты через SAS. Я хотел бы добавить контрольные линии (горизонтальные и вертикальные) к тепловой карте, которая разделяет его на квадранты. Мой код сейчас выглядит так:

proc template;
  define statgraph heatmapparm;
    begingraph;
      layout overlay;
         heatmapparm x=X_Value y=Y_Value colorresponse=percent / colormodel=(blue yellow red)
          name="heatmapparm" xbinaxis=false ybinaxis=false datatransparency=0;
        continuouslegend "heatmapparm" / location=outside valign=bottom;
      endlayout;
    endgraph;
  end;
run;

proc sgrender data=Data template=heatmapparm;
run;

Это график тепловой карты переменных X и Y, но я бы хотел добавить поперечные линии, чтобы отметить середину моего графика. Спасибо!!

Answer 1

Попробуйте drawline заявление.

http://support.sas.com/documentation/cdl/en/grstatgraph/65377/HTML/default/viewer.htm

Это добавляет строки к примеру тепловой карты из документа:

proc template;
  define statgraph heatmapparm;
    begingraph;
      layout overlay;
        heatmapparm x=height y=weight colorresponse=count /
          name="heatmapparm" xbinaxis=false ybinaxis=false;
        drawline x1=50 y1=0 x2=50 y2=100 /
          x1space=wallpercent y1space=wallpercent
          x2space=wallpercent y2space=wallpercent
          lineattrs=GraphReference  ;
        drawline x1=0 y1=50 x2=100 y2=50 /
          x1space=wallpercent y1space=wallpercent
          x2space=wallpercent y2space=wallpercent
          lineattrs=GraphReference  ;
        continuouslegend "heatmapparm" / location=outside valign=bottom;
      endlayout;
    endgraph;
  end;
run;

proc sgrender data=sashelp.gridded template=heatmapparm;
run;