Фортран: пытается создать минимальную структуру данных стека

Question

Вопрос о стеках на SO, наконец-то! Вся моя жизнь привела меня к этому моменту.

Поэтому мне нужно было включить в стек довольно большую пользовательскую структуру данных. Я решил написать минимальную структуру стека, состоящую только из одного целочисленного значения. Вот -

MODULE STACK_MODULE
 IMPLICIT NONE

 TYPE ELEMENT_TYPE
  INTEGER(4) :: VAL
  TYPE(ELEMENT_TYPE), POINTER :: PREV
 END TYPE ELEMENT_TYPE

 TYPE STACK_TYPE
  INTEGER(4) :: SIZE=0
  TYPE(ELEMENT_TYPE), POINTER :: LASTIN
 END TYPE STACK_TYPE

 CONTAINS
  SUBROUTINE PUSH(VAL_,STACK)
   IMPLICIT NONE
   INTEGER(4), INTENT(IN) :: VAL_
   TYPE(STACK_TYPE), INTENT(INOUT) :: STACK
   TYPE(ELEMENT_TYPE),TARGET       :: CURRENT
   ! INIT CURRENT
   CURRENT%VAL = VAL_
   CURRENT%PREV => STACK%LASTIN
   ! ADD CURRENT TO STACK
   STACK%LASTIN => CURRENT
   STACK%SIZE = STACK%SIZE+1
   RETURN
  END SUBROUTINE PUSH

  SUBROUTINE POP(STACK,VAL_)
   IMPLICIT NONE
   TYPE(STACK_TYPE), INTENT(INOUT) :: STACK
   INTEGER(4)      , INTENT(OUT)   :: VAL_
   TYPE(ELEMENT_TYPE), POINTER     :: B4LASTIN
   !WRITE TO VAL_
   IF (ASSOCIATED(STACK%LASTIN)) THEN
    VAL_ = STACK%LASTIN%VAL
    !TAKE OUT THE LAST-IN ELEMENT
    B4LASTIN => STACK%LASTIN%PREV
    STACK%LASTIN => B4LASTIN
    STACK%SIZE = STACK%SIZE-1 
   ELSE
    IF (STACK%SIZE.NE.0) THEN
     PRINT*, STACK%SIZE
     STOP 'MISMATCH BETWEEN STACKSIZE AND POINTER: BAD BOOK KEEPING!'
    END IF
   END IF
   RETURN
  END SUBROUTINE POP 
END MODULE STACK_MODULE

PROGRAM MAIN
 USE STACK_MODULE
 IMPLICIT NONE
 INTEGER(4) :: I,J
 TYPE(STACK_TYPE) :: STACK1
 DO I = 1,10
  CALL PUSH(I,STACK1)
 END DO
 DO WHILE (ASSOCIATED(STACK1%LASTIN))
  CALL POP(STACK1,J)
  PRINT*, J
 END DO
END PROGRAM

Результат меня сильно удивил! У меня были сомнения по поводу того, SIZE Счетчик будет не отставать.. но не это.

          10
 -1076898780
     1752444
 -1219604480
  1651076143
 stderr
Program received signal SIGSEGV: Segmentation fault - invalid memory reference.

Backtrace for this error:
#0  0xB777FD63
#1  0xB77803F0
#2  0xB78713FF
#3  0x8048666 in __stack_module_MOD_pop
#4  0x80487A3 in MAIN__ at prog.f95:?

Есть какие-нибудь указатели (паузы, когда он безудержно хихикает) о том, где я ошибся? Вот ссылка на код на IDEONE.
РЕДАКТИРОВАТЬ: ссылка IDEONE теперь содержит обновленную версию кода с включенным в него решением! Надеюсь, он может быть использован в качестве универсального шаблона для стеков!

Answer 1

Несколько мелких проблем

1) Когда PUSH выходит, CURRENT исчезает вместе с ним. Вам нужно что-то вроде

TYPE(ELEMENT_TYPE),POINTER       :: CURRENT
! INIT CURRENT
ALLOCATE(CURRENT)

2) Аналогично, когда заканчивается POP, необходимо удалить данные так,

B4LASTIN => STACK%LASTIN%PREV
DEALLOCATE(STACK%LASTIN)
STACK%LASTIN => B4LASTIN

3) ASSOCIATED работает, но только если указатели правильно инициализированы.

TYPE(STACK_TYPE) :: STACK1
STACK1%LASTIN => NULL()

И ты должен быть готов к бегу.