Отсутствует запись FROM-предложения для таблицы?

Question

Когда я выбираю определенное поле из таблицы в отношении "есть много", я получаю исключение, подобное этому: org.postgresql.util.PSQLException: ERROR: missing FROM-clause entry for table \"bar\"

Вот отношения, которые я определил:

(declare foo bar)

(korma/defentity foo
                 (korma/pk :token)
                 (korma/database db)
                 (korma/table :foo)
                 (korma/has-many bar {:fk :token}))

(korma/defentity bar
                 (korma/pk :token)
                 (korma/database db)
                 (korma/table :bar)
                 (korma/belongs-to foo {:fk :token}))

Вот запрос, который я генерирую в sqlkorma:

(defn fetch []
  (->
    (korma/select* foo)
    (korma/with bar)
    (korma/fields :foo.token :bar.col)
    (korma/exec)))

Если я выберу все поля, используя с * тогда запрос выполняется без проблем. Тем не менее, я хотел бы указать, какие поля я хочу выбрать, что я делаю не так?

Answer 1

Думаю, я передавал bar.col поле в неправильном месте. Я думаю, потому что это отношение имеет много, sql korma должен уйти и выполнить n+1 запросов здесь. Это объясняет, почему я вижу missing FROM-clause исключение, потому что я говорил sql korma, чтобы получить поле в неправильном запросе.

(defn fetch []
  (->
    (korma/select* foo)
    (korma/fields :token)
    (korma/with bar (korma/fields :col))
    (korma/exec)))

Answer 2

Я бросил пытаться сделать это с Кормой. Я думаю, что вам может быть лучше с базовым взаимодействием SQL:

(ns tst.demo.jdbc
  (:use demo.core tupelo.core tupelo.test)
  (:require
    [clojure.java.jdbc :as jdbc]
    [clojure.string :as str]
    [clojure.java.io :as io] ))

(def db {:classname   "org.h2.Driver"
         :subprotocol "h2:mem"
        ;:subname     "./korma.db"
         :subname     "demo;DB_CLOSE_DELAY=-1" ; -1 very important!!!
                          ; http://www.h2database.com/html/features.html#in_memory_databases
                          ; http://makble.com/using-h2-in-memory-database-in-clojure
         :user "sa"
         :password ""
         })

(dotest
  (spyx (jdbc/db-do-commands db ["drop table if exists langs"]))
  (spyx (jdbc/db-do-commands db ["drop table if exists releases"]))
  (spy :create
       (jdbc/db-do-commands
         db
         (jdbc/create-table-ddl :langs
                                [[:id :serial]
                                 [:lang "varchar not null"]])))
  (spy :create
       (jdbc/db-do-commands
         db
         (jdbc/create-table-ddl :releases
                                [[:id :serial]
                                 [:desc "varchar not null"]
                                 [:langId "numeric"]])))
  (spy :insert
       (jdbc/insert-multi! db :langs
                           [{:lang "Clojure"}
                            {:lang "Java"}]))
  ;; -> ({:lang "Clojure", :id 1} {:lang "Java", :id 2})
  (spyx-pretty (jdbc/query db ["select * from langs"]))

  (let [clj-id (grab :id (only (jdbc/query db ["select id from langs where lang='Clojure'"])))]
    (spyx clj-id)
    (spy :insert-rel
         (jdbc/insert-multi! db :releases
                             [{:desc "ancients" :langId clj-id}
                              {:desc "1.8" :langId clj-id}
                              {:desc "1.9" :langId clj-id}])) )
  (let [java-id (grab :id (only (jdbc/query db ["select id from langs where lang='Java'"])))]
    (spyx java-id)
    (spy :insert-rel
         (jdbc/insert-multi! db :releases
                             [{:desc "dusty" :langId java-id}
                              {:desc "8" :langId java-id}
                              {:desc "9" :langId java-id}
                              {:desc "10" :langId java-id}])) )
  (spyx-pretty
   (jdbc/query db [
   "select langs.lang, releases.desc
       from langs inner join releases
       on (langs.id = releases.langId)
       where lang = 'Clojure' "]) )
  )

с результатом:

(jdbc/db-do-commands db ["drop table if exists langs"]) => (0)
(jdbc/db-do-commands db ["drop table if exists releases"]) => (0)
:create => (0)
:create => (0)
:insert => ({:id 1} {:id 2})
(jdbc/query db ["select * from langs"]) =>
({:id 1, :lang "Clojure"} {:id 2, :lang "Java"})
clj-id => 1
:insert-rel => ({:id 1} {:id 2} {:id 3})
java-id => 2
:insert-rel => ({:id 4} {:id 5} {:id 6} {:id 7})
(jdbc/query db ["select langs.lang, releases.desc\n       from langs inner join releases\n       on (langs.id = releases.langId)\n       where lang = 'Clojure' "]) =>
({:lang "Clojure", :desc "ancients"}
 {:lang "Clojure", :desc "1.8"}
 {:lang "Clojure", :desc "1.9"})