Скриншот Delphi Active Window

Question

Я пытаюсь добавить снимок экрана активного окна с помощью этого кода

procedure ScreenShot(activeWindow: bool; destBitmap : TBitmap) ;
 var
    w,h : integer;
    DC : HDC;
    hWin : Cardinal;
    r : TRect;
 begin
    if activeWindow then
    begin
      hWin :=  GetForegroundWindow;
      dc := GetWindowDC(hWin) ;
      GetWindowRect(hWin,r) ;
      w := r.Right - r.Left;
      h := r.Bottom - r.Top;
    end
    else
    begin
      hWin := GetForegroundWindow;
      dc := GetDC(hWin) ;
      w := GetDeviceCaps (DC, HORZRES) ;
      h := GetDeviceCaps (DC, VERTRES) ;
    end;

    try
     destBitmap.Width := w;
     destBitmap.Height := h;
     BitBlt(destBitmap.Canvas.Handle,
            0,
            0,
            destBitmap.Width,
            destBitmap.Height,
            DC,
            0,
            0,
            SRCCOPY) ;
    finally
     ReleaseDC(hWin, DC) ;
    end;
 end;

И в Button1 я использую:

var
  path:string;
  b:TBitmap;
begin
   path:= ExtractFilePath(Application.ExeName) + '/Screenshot/';
   b := TBitmap.Create;
   try
     ScreenShot(TRUE, b) ;
     b.SaveToFile(path + 'Screenshot_1.png');
   finally
     b.FreeImage;
     FreeAndNil(b) ;
   end;
end;

это работает хорошо, только проблема не захватить строку заголовка:(

Вот полный вид активного окна:

И вот что я получаю из этого кода

Где я делаю неправильно?

Answer 1

Я проверил и получил тот же результат.

оригинал с рамкой

Но если вы установите

sSkinProvider1.AllowExtBorders:=False;

Вы получаете скриншот без прозрачной границы.

затем установить обратно

sSkinProvider1.AllowExtBorders:=True;

Не нужно делать после этого ни секунды

Form1.Repaint;

Вы увидите только короткий переключатель.

procedure TForm1.BitBtn1Click(Sender: TObject);
var
  path:string;
  b:TBitmap;
begin
   sSkinProvider1.AllowExtBorders:=False;
   Form1.Repaint;
   path:= ExtractFilePath(Application.ExeName) + 'Screenshot\';
   b := TBitmap.Create;
   try
     ScreenShot(TRUE, b) ;
     b.SaveToFile(path + 'Screenshot_1.png');
   finally
     b.FreeImage;
     FreeAndNil(b) ;
     sSkinProvider1.AllowExtBorders:=True;
[...]

Кстати. не устанавливайте путь как

path:= ExtractFilePath(Application.ExeName) + '/Screenshot/';

использовать обратную косую черту в стиле Windows и только одну

path:= ExtractFilePath(Application.ExeName) + 'Screenshot\'; 

Протестировано с Delphi5

Answer 2

Я не знаю, какие компоненты визуального стиля вы используете (хотя значок формы показывает, что это Delphi 7).

Этот код прекрасно работает для меня:

function CaptureWindow(const WindowHandle: HWnd): TBitmap;
var
  DC: HDC;
  wRect: TRect;
  Width, Height: Integer;
begin
  DC := GetWindowDC(WindowHandle);
  Result := TBitmap.Create;
  try
    GetWindowRect(WindowHandle, wRect);
    Width := wRect.Right - wRect.Left;
    Height := wRect.Bottom - wRect.Top;
    Result.Width := Width;
    Result.Height := Height;
    Result.Modified := True;
    BitBlt(Result.Canvas.Handle, 0, 0, Width, Height, DC, 0, 0, SRCCOPY);
  finally
    ReleaseDC(WindowHandle, DC);
  end;
end;

procedure TForm1.Button1Click(Sender: TObject);
var
  Capture: TBitmap;
begin
  //  For active window, change Handle to GetForegroundWindow()
  Capture := CaptureWindow(Handle);  
  try
    Capture.SaveToFile('E:\TempFiles\ScreenCapture2014.bmp');
  finally
    Capture.Free;
  end;
end;

Вот изображение, которое я сделал: