gradle - как мне создать банку с директорией lib с другими банками в ней?

Question

gradle - как мне создать банку с директорией lib с другими банками в ней?

В Gradle - как я могу встроить JAR в мой выходной файл сборки в каталоге lib (в частности, lib/enttoolkit.jar и lib/mail.jar)?

73

gradle jar uberjar

Источник

user75877 10 авг '10 в 03:28

8 ответов

Другие вопросы по тегам gradle jar uberjar

user260280 20 фев '12 в 10:26 2012-02-20 10:26 · Answer 1 · 2012-02-20 10:26

Если у вас есть все банки внутри каталога (давайте назовем его libs) в вашем проекте вам нужно только это:

jar {
    into('lib') {
        from 'libs'
    }
}

Я предполагаю, что более вероятно, что эти фляги - зависимости некоторого вида. Тогда вы можете сделать это так:

configurations {
    // configuration that holds jars to copy into lib
    extraLibs
}
dependencies {
    extraLibs 'org.something:something-dep1:version'
    extraLibs 'org.something:something-dep2:version'
}

jar {
    into('lib') {
        from configurations.extraLibs
    }
}

user31172 10 авг '10 в 15:07 2010-08-10 15:07 · Answer 2 · 2010-08-10 15:07

Отменено дословно с: http://docs.codehaus.org/display/GRADLE/Cookbook

Gradle 0,9:

jar {
    from configurations.compile.collect { it.isDirectory() ? it : zipTree(it) }
}

Gradle 0.8:

jar.doFirst {
    for(file in configurations.compile) {
        jar.merge(file)
    }
}

Приведенные выше фрагменты будут включать только зависимости компиляции для этого проекта, а не какие-либо переходные зависимости времени выполнения. Если вы также хотите объединить их, замените файл configurations.compile на файл configurations.runtime.

РЕДАКТИРОВАТЬ: только выбирая банки, которые вам нужны

Сделайте новую конфигурацию, возможно, releaseJars

configurations {
    releaseJars
}

Добавьте банки, которые вы хотите, к этой конфигурации

dependencies {
    releaseJars group: 'javax.mail', name: 'mail', version: '1.4'
    //etc
}

затем используйте эту конфигурацию в задаче jar, описанной выше.

user211277 19 мар '12 в 15:18 2012-03-19 15:18 · Answer 3 · 2012-03-19 15:18

Просто:

task copyToLib( type: Copy ) {
    into "$buildDir/libs/lib"
    from configurations.runtime
}

jar { dependsOn copyToLib }

запустить его:

$ gradle jar
...
$ tree build/libs

build/libs
├── your-project-0.0.1.BUILD-SNAPSHOT.jar
└── lib
    ├── akka-actor-2.0.jar
    ├── akka-camel-2.0.jar
    ├── ... ... ...
    ├── spring-expression-3.1.0.RELEASE.jar
    └── zmq-2.1.9.jar

1 directory, 46 files

23

Источник

user211277 19 мар '12 в 15:18

user8912 12 мар '12 в 16:42 2012-03-12 16:42 · Answer 4 · 2012-03-12 16:42

Мне также нужно было сделать что-то похожее, и я не смог понять, что Гус и Стигкдж предложили работать, но с их помощью подобрались достаточно близко, чтобы заставить его работать (пример Гуса взорвался dependencies { compile { extendsFrom myLibs }} закрытие для меня.

apply plugin: 'groovy'

repositories {
    mavenCentral()
}

configurations {
    // custom config of files we want to include in our fat jar that we send to hadoop
    includeInJar
}

dependencies {
    includeInJar 'org.codehaus.groovy:groovy:1.8.6'

    configurations.compile.extendsFrom(configurations.includeInJar)
}

jar {
    into('lib') {
        println "includeInJar: " + configurations.includeInJar.collect { File file -> file }
        from configurations.includeInJar
    }

}

Потом работает gradle jar и проверка созданного фляги дает мне этот вывод, показывая, что я получаю файл фляги, чтобы иметь groovy так же как все фляги, от которых это зависит в "толстом фляге":

%  gradle jar                                                                                                                         
includeInJar: [/Users/tnaleid/.gradle/caches/artifacts-8/filestore/org.codehaus.groovy/groovy/1.8.6/jar/553ca93e0407c94c89b058c482a404427ac7fc72/groovy-1.8.6.jar, /Users/tnaleid/.gradle/caches/artifacts-8/filestore/antlr/antlr/2.7.7/jar/83cd2cd674a217ade95a4bb83a8a14f351f48bd0/antlr-2.7.7.jar, /Users/tnaleid/.gradle/caches/artifacts-8/filestore/asm/asm/3.2/jar/9bc1511dec6adf302991ced13303e4140fdf9ab7/asm-3.2.jar, /Users/tnaleid/.gradle/caches/artifacts-8/filestore/asm/asm-tree/3.2/jar/cd792e29c79d170c5d0bdd05adf5807cf6875c90/asm-tree-3.2.jar, /Users/tnaleid/.gradle/caches/artifacts-8/filestore/asm/asm-commons/3.2/jar/e7a19b8c60589499e35f5d2068d09013030b8891/asm-commons-3.2.jar, /Users/tnaleid/.gradle/caches/artifacts-8/filestore/asm/asm-util/3.2/jar/37ebfdad34d5f1f45109981465f311bbfbe82dcf/asm-util-3.2.jar, /Users/tnaleid/.gradle/caches/artifacts-8/filestore/asm/asm-analysis/3.2/jar/c624956db93975b7197699dcd7de6145ca7cf2c8/asm-analysis-3.2.jar]
:compileJava UP-TO-DATE
:compileGroovy UP-TO-DATE
:processResources UP-TO-DATE
:classes UP-TO-DATE
:jar

BUILD SUCCESSFUL

Total time: 3.387 secs

%  jar tvf build/libs/gradletest.jar                                                                                                  
     0 Mon Mar 12 11:40:00 CDT 2012 META-INF/
    25 Mon Mar 12 11:40:00 CDT 2012 META-INF/MANIFEST.MF
     0 Mon Mar 12 11:40:00 CDT 2012 lib/
5546084 Mon Mar 05 13:13:32 CST 2012 lib/groovy-1.8.6.jar
445288 Mon Mar 05 13:13:38 CST 2012 lib/antlr-2.7.7.jar
 43398 Mon Mar 05 13:13:40 CST 2012 lib/asm-3.2.jar
 21878 Mon Mar 05 13:13:40 CST 2012 lib/asm-tree-3.2.jar
 33094 Mon Mar 05 13:13:40 CST 2012 lib/asm-commons-3.2.jar
 36551 Mon Mar 05 13:13:40 CST 2012 lib/asm-util-3.2.jar
 17985 Mon Mar 05 13:13:40 CST 2012 lib/asm-analysis-3.2.jar

user2509415 18 дек '14 в 16:20 2014-12-18 16:20 · Answer 5 · 2014-12-18 16:20

Ниже код можно попробовать. Это зависит от задачи jar и имеет тип Jar

task createJobJar(dependsOn:jar,type:Jar) {
    manifest {
        attributes(
                "Implementation-Title": 'Job '
                ,"Implementation-Version": version
        )
    }
    classifier 'job'
    destinationDir new File("$buildDir")
    into('libs'){
         from configurations.compile
    }
    into('classes'){
        from "$buildDir/classes"
    }
    into('resources'){
        from "$projectDir/src/main/resources"
    }
    into('scripts'){
        from "$projectDir/src/main/scripts"
    }
}

Приведенный выше код будет упаковывать разное содержимое в разные каталоги. Проверено на Gradle 2.2

user666481 24 май '11 в 02:18 2011-05-24 02:18 · Answer 6 · 2011-05-24 02:18

Мне нужно было то же, что вы просили, и использовал этот метод. Вам может не потребоваться объявление пользовательской конфигурации, но мне нужно было отделить локально используемые файлы JAR от тех, которые объявлены в файле супер-сборки.

configurations{
    //declare custom config if necessary, otherwise just use compile
    myLibs
}
dependencies {
    //add lib/*.jar files to myLibs
    myLibs fileTree(dir: 'lib', include: '*.jar')
    compile {
        //set compile configuration to extend from myLibs
        extendsFrom myLibs
    }
}
// task to copy libs to output/lib dir
task copyToLib(type: Copy) {
    into "$buildDir/output/lib"
    from configurations.myLibs
}

jar {
    //include contents of output dir
    from "$buildDir/output"
    manifest {
        //...
    }
}

//set build task to depend on copyToLib
build.dependsOn(copyToLib)

user11151187 05 мар '19 в 00:50 2019-03-05 00:50 · Answer 7 · 2019-03-05 00:50

У меня такая же проблема. Я решил это так:

Скопируйте файлы в папку lib с помощью copyToLib и создайте ссылку на зависимость с помощью Class-Path.

ext.mainClass = 'test.main'

dependencies {
    compile fileTree(include: ['*.jar'], dir: 'libs')
    compile 'com.google.code.gson:gson:2.8.2'
    //....
}

jar {
    from "$buildDir/libs/lib"
    manifest {
        attributes 'Main-Class': 'test.main',
        'Class-Path': configurations.compile.collect { 'lib/'+it.getName() }.join(' ')
    }
}

task copyToLib(type: Copy) {
    into "$buildDir/libs/lib"
    from configurations.compile
}

build.dependsOn(copyToLib)

user2114557 01 июл '20 в 13:29 2020-07-01 13:29 · Answer 8 · 2020-07-01 13:29

Вот как мне удалось добиться этой настройки сборки с помощью Gradle. Это создаст ваше приложение в Jar, скопирует сгенерированные библиотеки jar-файлов в каталог libs в build/libs, а также настроит путь к классам для включения jar-файлов в созданный каталог build/libs/libs.

 plugins {
    id 'application'
 }

 group 'org.pkg'
 version '1.0-SNAPSHOT'

 ext.mainClass = 'org.pkg.MainClass'

 repositories {
    mavenCentral()
    mavenLocal()
 }

 dependencies {
    compile fileTree(include: ['*.jar'], dir: 'libs')
    testCompile group: 'junit', name: 'junit', version: '4.12'

    implementation group: 'com.mchange', name: 'c3p0', version: '0.9.5.5'
 }
 
 task copyToLib(type: Copy) {
    into "$buildDir/libs/libs"
    // configurations.runtimeClasspath includes maven jars
    from configurations.runtimeClasspath 
 }

 def archiveVersion = "1.0.0"

 task uberJar(type: Jar) {
    archiveClassifier = 'uber'

    from sourceSets.main.output
    // include the copy task
    dependsOn(copyToLib)

    // use onfigurations.runtimeClasspath to collect all the jars
    manifest {
      attributes(
            'Class-Path': configurations.runtimeClasspath.collect { 'libs/' + it.getName() }.join(' '),
            'Main-Class': 'org.pkg.MainClass',
            "Implementation-Title": "Gradle",
            "Implementation-Version": archiveVersion
      )
    }
 }

user2723001 12 апр '17 в 16:10 2017-04-12 16:10 · Answer 9 · 2017-04-12 16:10

В моем случае мне нужно было включить содержимое корневого проекта Jar в подпроект Jar. Итак, чтобы он работал, можно использовать этот шаблон:

jar{
  manifest{
    attributes 'Main-Class':'<main class>'
  }
  def conf= configurations.find {it.name.equals('compile') }
  File jar= conf.files.find {it.name.contains('<name or part of the name of produced Jar>')}

  FileTree fileTree=zipTree(jar)
  from fileTree
}

Мой пример:

jar{
   manifest{
       attributes 'Main-Class':'alexiy.jace.Jace'
   }
   description='Make a runnable API Jar'
   def conf= configurations.find {it.name.equals('compile') }
   File tools= conf.files.find {it.name.contains('Tools')}

   FileTree fileTree=zipTree(tools)
   from fileTree
}

user8219693 27 июн '17 в 09:27 2017-06-27 09:27 · Answer 10 · 2017-06-27 09:27

task <taskname>(type: Jar) {
    archiveName 'nameofjar.jar'
    doFirst {
    manifest {
            attributes 'Class-Path': configurations.compile.files.collect{ project.uri(it) }.join(' ')
        }
    }
}

-1

Источник

user8219693 27 июн '17 в 09:27