Кодирование URL в Erlang

Question

Я использую erlang http:request для отправки некоторых данных на удаленный сервис. У меня работает сообщение, но данные в теле () сообщения поступают как есть, без какой-либо кодировки URL, что приводит к сбою сообщения при анализе удаленной службой.

Есть ли в Erlang функция, аналогичная CGI.escape в Ruby для этой цели?

Answer 1

Вы можете найти здесь подпрограммы YAWS url_encode и url_decode

Они довольно просты, хотя комментарии показывают, что кодирование не завершено на 100% для всех знаков пунктуации.

Answer 2

Я также столкнулся с отсутствием этой функции в модулях HTTP.

Оказывается, что эта функциональность на самом деле доступна в дистрибутиве Erlang, вы просто должны выглядеть достаточно усердно.

> edoc_lib:escape_uri("[e-mail]").
"luca%2bmore%40here.com"

Это ведет себя как CGI.escape в Ruby, также есть URI.escape, который ведет себя немного по-другому:

> CGI.escape("[e-mail]")
 => "luca%2Bmore%40here.com" 
> URI.escape("[e-mail]")
 => "[e-mail]" 

edoc_lib

Answer 3

По крайней мере, в R15 есть http_uri:encode/1, который выполняет эту работу. Я также не рекомендовал бы использовать edoc_lib:escape_uri для перевода '=' в%3d вместо%3D, что вызвало у меня некоторые проблемы.

Answer 4

Вот простая функция, которая делает эту работу. Он предназначен для работы напрямую с http-инетами.

%% @doc A function to URL encode form data.
%% @spec url_encode(formdata()).

-spec(url_encode(formdata()) -> string()).
url_encode(Data) ->
    url_encode(Data,"").

url_encode([],Acc) ->
    Acc;

url_encode([{Key,Value}|R],"") ->
    url_encode(R, edoc_lib:escape_uri(Key) ++ "=" ++ edoc_lib:escape_uri(Value));
url_encode([{Key,Value}|R],Acc) ->
    url_encode(R, Acc ++ "&" ++ edoc_lib:escape_uri(Key) ++ "=" ++ edoc_lib:escape_uri(Value)).

Пример использования:

httpc:request(post, {"http://localhost:3000/foo", [], 
                    "application/x-www-form-urlencoded",
                    url_encode([{"username", "bob"}, {"password", "123456"}])}
             ,[],[]).

Answer 5

Если кому-то нужно кодировать URI, который работает с UTF-8 в Erlang:

https://gist.github.com/3796470

Ex.

Eshell V5.9.1  (abort with ^G)

1> c(encode_uri_rfc3986).
{ok,encode_uri_rfc3986}

2> encode_uri_rfc3986:encode("テスト").
"%e3%83%86%e3%82%b9%e3%83%88"

3> edoc_lib:escape_uri("テスト").
"%c3%86%c2%b9%c3%88" # output wrong: ƹÈ

Answer 6

Чтобы ответить на мой собственный вопрос... Я нашел эту библиотеку в ibrowse!

http://www.erlware.org/lib/5.6.3/ibrowse-1.4/ibrowse_lib.html

url_encode/1

url_encode(Str) -> UrlEncodedStr

Str = string()
UrlEncodedStr = string()

URL-кодирует строку на основе RFC 1738. Возвращает плоский список.

Я думаю, я могу использовать это, чтобы сделать кодировку и все еще использовать http:

Answer 7

Вот "развилка" функции edoc_lib:escape_uri, которая улучшает поддержку UTF-8, а также поддерживает двоичные файлы.

escape_uri(S) when is_list(S) ->
    escape_uri(unicode:characters_to_binary(S));
escape_uri(<<C:8, Cs/binary>>) when C >= $a, C =< $z ->
    [C] ++ escape_uri(Cs);
escape_uri(<<C:8, Cs/binary>>) when C >= $A, C =< $Z ->
    [C] ++ escape_uri(Cs);
escape_uri(<<C:8, Cs/binary>>) when C >= $0, C =< $9 ->
    [C] ++ escape_uri(Cs);
escape_uri(<<C:8, Cs/binary>>) when C == $. ->
    [C] ++ escape_uri(Cs);
escape_uri(<<C:8, Cs/binary>>) when C == $- ->
    [C] ++ escape_uri(Cs);
escape_uri(<<C:8, Cs/binary>>) when C == $_ ->
    [C] ++ escape_uri(Cs);
escape_uri(<<C:8, Cs/binary>>) ->
    escape_byte(C) ++ escape_uri(Cs);
escape_uri(<<>>) ->
    "".

escape_byte(C) ->
    "%" ++ hex_octet(C).

hex_octet(N) when N =< 9 ->
    [$0 + N];
hex_octet(N) when N > 15 ->
    hex_octet(N bsr 4) ++ hex_octet(N band 15);
hex_octet(N) ->
    [N - 10 + $a].

Обратите внимание, что из-за использования unicode:characters_to_binary он будет работать только в версии R13 или новее.

Answer 8

AFAIK, в стандартных библиотеках нет кодировщика URL. Думаю, я "позаимствовал" следующий код у YAWS или, возможно, у одного из других веб-серверов Erlang:

% Utility function to convert a 'form' of name-value pairs into a URL encoded
% content string.

urlencode(Form) ->
    RevPairs = lists:foldl(fun({K,V},Acc) -> [[quote_plus(K),$=,quote_plus(V)] | Acc] end, [],Form),
    lists:flatten(revjoin(RevPairs,$&,[])).

quote_plus(Atom) when is_atom(Atom) ->
    quote_plus(atom_to_list(Atom));

quote_plus(Int) when is_integer(Int) ->
    quote_plus(integer_to_list(Int));

quote_plus(String) ->
    quote_plus(String, []).

quote_plus([], Acc) ->
    lists:reverse(Acc);

quote_plus([C | Rest], Acc) when ?QS_SAFE(C) ->
    quote_plus(Rest, [C | Acc]);

quote_plus([$\s | Rest], Acc) ->
    quote_plus(Rest, [$+ | Acc]);

quote_plus([C | Rest], Acc) ->
    <<Hi:4, Lo:4>> = <<C>>,
    quote_plus(Rest, [hexdigit(Lo), hexdigit(Hi), ?PERCENT | Acc]).

revjoin([], _Separator, Acc) ->
    Acc;

revjoin([S | Rest],Separator,[]) ->
    revjoin(Rest,Separator,[S]);

revjoin([S | Rest],Separator,Acc) ->
    revjoin(Rest,Separator,[S,Separator | Acc]).

hexdigit(C) when C < 10 -> $0 + C;
hexdigit(C) when C < 16 -> $A + (C - 10).