Comonad непустого списка

Question

Я медитировал над комонадами, и у меня есть интуиция, что непустой список ("полный список")- это комонада. Я построил правдоподобную реализацию в Идрисе и работал над доказательством законов комонада, но не смог доказать рекурсивную ветвь одного из законов. Как мне доказать это ?i_do_not_know_how_to_prove_this_if_its_provable дыра)- или я ошибаюсь из-за того, что моя реализация действительна (я посмотрел на Haskell NonEmpty Реализация comonad и она, кажется, такая же, как у меня)?

module FullList

%default total

data FullList : Type -> Type where
  Single : a -> FullList a
  Cons : a -> FullList a -> FullList a

extract : FullList a -> a
extract (Single x) = x
extract (Cons x _) = x

duplicate : FullList a -> FullList (FullList a)
duplicate = Single 

extend : (FullList a -> b) -> FullList a -> FullList b
extend f (Single x) = Single (f (Single x))
extend f (Cons x y) = Cons (f (Cons x y)) (extend f y)

extend_and_extract_are_inverse : (l : FullList a) -> extend FullList.extract l = l
extend_and_extract_are_inverse (Single x) = Refl
extend_and_extract_are_inverse (Cons x y) = rewrite extend_and_extract_are_inverse y in Refl

comonad_law_1 : (l : FullList a) -> extract (FullList.extend f l) = f l
comonad_law_1 (Single x) = Refl
comonad_law_1 (Cons x y) = Refl

nesting_extend : (l : FullList a) -> extend f (extend g l) = extend (\x => f (extend g x)) l
nesting_extend (Single x) = Refl
nesting_extend (Cons x y) = ?i_do_not_know_how_to_prove_this_if_its_provable

Answer 1

Обратите внимание, что ваша цель имеет следующую форму:

Cons (f (Cons (g (Cons x y)) (extend g y))) (extend f (extend g y)) =
Cons (f (Cons (g (Cons x y)) (extend g y))) (extend (\x1 => f (extend g x1)) y)

Вам нужно доказать, что части хвоста равны:

extend f (extend g y) = extend (\x1 => f (extend g x1)) y

Но это именно то, что гипотеза индукции (nesting_extend y) говорит! Следовательно, доказательство довольно тривиально:

nesting_extend : (l : FullList a) -> extend f (extend g l) = extend (f . extend g) l
nesting_extend (Single x) = Refl
nesting_extend (Cons x y) = cong $ nesting_extend y

Я использовал конгруэнтную лемму cong:

cong : (a = b) -> f a = f b

который говорит, что любая функция f сопоставляет равные условия в равные условия.

Здесь Идрис делает вывод, что f является Cons (f (Cons (g (Cons x y)) (extend g y))), где f внутри Cons относится к nesting_extendпараметр f,