Есть ли в libxslt возможность разбивать документ на несколько документов?

Похоже, libxslt не поддерживает XSLT 2.0, и xsl:result-document, Есть ли способ подражать xsl:result-document с помощью libxslt, или же xsltproc?

Источник

3 ответа

Решение

Да, есть, используя exsl: document. Простой пример:

==== foo.xsl ====
<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0"
                xmlns:exsl="http://exslt.org/common"
                extension-element-prefixes="exsl">
  <xsl:output method="html"/>
  <xsl:template match="/">
    <exsl:document href="toc.html" method="html">
      <html>
        <body>
          <xsl:apply-templates select=".//h1"/>
        </body>
      </html>
    </exsl:document>
    <xsl:apply-templates/>
  </xsl:template>
  <xsl:template match="node()|@*">
    <xsl:copy>
      <xsl:apply-templates select="node()|@*"/>
    </xsl:copy>
  </xsl:template>
</xsl:stylesheet>

принимая это в качестве входных данных:

==== foo.html ====
<html>
  <body>
    <h1>Hello, world!</h1>
    <p>Some longwinded text follows.</p>
  </body>
</html>

когда бегаешь так:

xsltproc foo.xsl foo.html

выдаст это на стандартный вывод:

<html>
  <body>
    <h1>Hello, world!</h1>
    <p>Some longwinded text follows.</p>
  </body>
</html>

в то же время пишу это toc.html:

<html><body><h1>Hello, world!</h1></body></html>
Источник

Если libxslt реализует EXSLT, то вы можете использовать <exsl:document> элемент расширения.

Если нет, то вы должны написать свои собственные функции расширения, потому что XSLT 1.0 не поддерживает создание нескольких документов результатов.

Обновление: Как подтверждено в этом комментарии, libxslt реализует EXSLT. Просто возьмите его и используйте <exsl:document>,

Источник

И вот пример, который показывает, как использовать расширение для создания неограниченного количества файлов при обходе набора узлов. Опять же, используя xsltproc (libxslt)

Пример XML-ввода:

<clients>
    <client id="ACME1" name="ACME Company 1"/>
    <client id="ACME2" name="ACME Company 2"/>
    <client id="ACME3" name="ACME Company 3"/>
</clients>

Образец XSLT:

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0" 
                xmlns:exsl="http://exslt.org/common"
                extension-element-prefixes="exsl">

<xsl:output method="html" indent="yes" encoding="UTF-8" />

<xsl:template match="/">
    <xsl:for-each select="/clients/client">
    <exsl:document href="{@id}.html" method="html">
      <html>
        <body>
          <h1>Company: <xsl:apply-templates select="@name"/></h1>
        </body>
      </html>
    </exsl:document>
    </xsl:for-each>
</xsl:template>

</xsl:stylesheet>

Будет выдавать 3 файла ACME1.html, ACME2.html и т. Д.

Источник
Другие вопросы по тегам