Невозможно понять, как выполняется задание APEX_MAIL

Question

В настоящее время я пытаюсь реализовать аналогичную версию пакета APEX_MAIL оракула. У меня все работает, но я не могу заставить работу работать, пока не изменю ее.

Задание, которое использует APEX_MAIL, называется ORACLE_APEX_MAIL_QUEUE.

BEGIN
DBMS_SCHEDULER.set_attribute( name => '"APEX_040000"."ORACLE_APEX_MAIL_QUEUE"', attribute => 'job_action', value => 'APEX_040000.WWV_FLOW_MAIL.PUSH_QUEUE');

DBMS_SCHEDULER.set_attribute( name => '"APEX_040000"."ORACLE_APEX_MAIL_QUEUE"', attribute => 'number_of_arguments', value => '2');
DBMS_SCHEDULER.SET_JOB_ARGUMENT_VALUE( 
         job_name => '"APEX_040000"."ORACLE_APEX_MAIL_QUEUE"', 
         argument_position => 1, 
         argument_value => '');
DBMS_SCHEDULER.SET_JOB_ARGUMENT_VALUE( 
         job_name => '"APEX_040000"."ORACLE_APEX_MAIL_QUEUE"', 
         argument_position => 2, 
         argument_value => '');

END; 
/

Поэтому я иду в пакет, чтобы посмотреть, что делает код. Я предполагал, что push-очередь будет отправлять электронные письма в очереди. Вместо этого он снова вызывает ту же работу!

PROCEDURE PUSH_QUEUE( P_SMTP_HOSTNAME IN VARCHAR2 DEFAULT NULL,
                      P_SMTP_PORTNO   IN VARCHAR2 DEFAULT NULL )
IS
BEGIN
    PUSH_QUEUE_BACKGROUND;
END PUSH_QUEUE;


PROCEDURE PUSH_QUEUE_BACKGROUND
IS
BEGIN
    SYS.DBMS_SCHEDULER.RUN_JOB( JOB_NAME => 'ORACLE_APEX_MAIL_QUEUE', USE_CURRENT_SESSION => FALSE );
EXCEPTION
    WHEN OTHERS THEN
        IF SQLCODE <> -27478 THEN
            RAISE;
        END IF;
END PUSH_QUEUE_BACKGROUND;

Так что в основном эта работа ничего не делает, но я переключаю ее на вызов PUSH_QUEUE_IMMEDIATE, который делает то, что, я думаю, должен делать.

PROCEDURE PUSH_QUEUE_IMMEDIATE( P_FORCE_YN IN VARCHAR2 DEFAULT 'N')
IS
    L_STATUS            NUMBER;
    L_LOCK_HDL          VARCHAR2(128);
    E_DB_SHUTDOWN       EXCEPTION;
    PRAGMA EXCEPTION_INIT(E_DB_SHUTDOWN, -1089);
BEGIN



    WWV_FLOW_DEBUG.ENABLE_DBMS_OUTPUT;



    SYS.DBMS_LOCK.ALLOCATE_UNIQUE( LOCKNAME => 'APEX_MAIL_QUEUE_LOCK', LOCKHANDLE => L_LOCK_HDL);
    L_STATUS := SYS.DBMS_LOCK.REQUEST( LOCKHANDLE        => L_LOCK_HDL,
                                   LOCKMODE          => SYS.DBMS_LOCK.X_MODE,
                                   TIMEOUT           => 0,
                                   RELEASE_ON_COMMIT => FALSE );
    WWV_FLOW_DEBUG.INFO('APEX Mail Lock status: ' || L_STATUS );




    IF L_STATUS = 0 THEN

        FOR C1 IN ( SELECT   ID, MAIL_SEND_COUNT, LAST_UPDATED_ON
                      FROM WWV_FLOW_MAIL_QUEUE
                     ORDER BY MAIL_SEND_COUNT, LAST_UPDATED_ON) LOOP
            BEGIN
                WWV_FLOW_DEBUG.INFO( 'Pushing email: ' || C1.ID );







                IF  (C1.MAIL_SEND_COUNT = 0) OR (NVL(P_FORCE_YN,'N') = 'Y') OR
                   (C1.MAIL_SEND_COUNT > 0 AND (POWER(2,C1.MAIL_SEND_COUNT)/(60*24) + C1.LAST_UPDATED_ON) < SYSDATE) THEN
                    BACKGROUND( P_ID => C1.ID );
                END IF;
                WWV_FLOW_DEBUG.INFO( 'Pushed email: ' || C1.ID );
            EXCEPTION
                WHEN OTHERS THEN
                    WWV_FLOW_DEBUG.LOG_EXCEPTION;

                    IF L_LOCK_HDL IS NOT NULL THEN
                        L_STATUS := SYS.DBMS_LOCK.RELEASE( L_LOCK_HDL );
                        WWV_FLOW_DEBUG.INFO('APEX Mail released lock' );
                    END IF;
            END;
        END LOOP;
    END IF;



    IF L_LOCK_HDL IS NOT NULL THEN
        L_STATUS := SYS.DBMS_LOCK.RELEASE( L_LOCK_HDL );
        WWV_FLOW_DEBUG.INFO('APEX Mail released lock' );
    END IF;
EXCEPTION WHEN E_DB_SHUTDOWN THEN 
    NULL;
END PUSH_QUEUE_IMMEDIATE;

Я пытаюсь скопировать APEX_MAIL в точку, но если я это сделаю, у меня не будет рабочей работы. Кто-нибудь может указать, если APEX_MAIL меняет то, что делает работа после изменения настроек приложения или каких-либо других изменений?

Заранее спасибо!

Answer 1

APEX_MAIL.PUSH_QUEUE используется в вашем собственном коде для немедленной отправки вашей почты (в очереди). Работа обычно вызывает PUSH_QUEUE_IMMEDIATE. Я не знаю, была ли ваша настройка когда-либо ошибкой в ​​установке или чем-то неправильным на вашем сайте. Таким образом, он вызывает PUSH_QUEUE_IMMEDIATE в отдельном сеансе как задание APEX_040000.

Поскольку каждый может запросить немедленную отправку всех заданий в очереди, с помощью SYS.DBMS_LOCK.REQUEST он гарантирует, что только один сеанс будет выполнять передачу.