x86_64 неправильное соглашение о вызовах при вызове функции

Question

Я относительно новичок в LLVM, и я пытаюсь создать LLVM IR, который вызывает функцию C ( growDictionary). Это на x86_64 Linux, используя llvm 12:

      $ llc-12 --version
Ubuntu LLVM version 12.0.1

  Optimized build.
  Default target: x86_64-pc-linux-gnu
  Host CPU: broadwell

Функция (определенная в C ++ как extern "C", скомпилировано с clang 12):

      struct StringDictionary {
    uint32_t* base;
    uint32_t elementSize;
    uint32_t rowCount;
    uint32_t wordsCapacity;
};

extern "C" {
StringDictionary growStringDictionary(StringDictionary dict,
                                      uint32_t neededWordsCapacity);
}

Функция принимает объект StringDictionary по значению, но, согласно x86_64 ABI (https://github.com/hjl-tools/x86-psABI/wiki/x86-64-psABI-1.0.pdf , раздел 3.2.3, «Parameter Passing») должен быть передан в стек. (Размер объекта превышает два восьми байта, и ни один из восьми байтов не принадлежит классу SSE или SSEUP, поэтому он превращается в класс MEMORY в соответствии с разделом «Очистка после слияния».) Беглый взгляд на разборку подтверждает, что это действительно та самая операция. кейс:

      Dump of assembler code for function growStringDictionary(rockset::jit::StringDictionary, uint32_t):
   0x00007ffff7f98f70 <+0>: push   %rbp
   0x00007ffff7f98f71 <+1>: mov    %rsp,%rbp
   0x00007ffff7f98f74 <+4>: push   %rbx
   0x00007ffff7f98f75 <+5>: and    $0xffffffffffffffe0,%rsp
   0x00007ffff7f98f79 <+9>: sub    $0x1c0,%rsp
   0x00007ffff7f98f80 <+16>:    mov    %rsp,%rbx
   0x00007ffff7f98f83 <+19>:    mov    %esi,0x15c(%rbx)
   0x00007ffff7f98f89 <+25>:    mov    %rdi,0x160(%rbx)
[...]

%rdi это адрес, по которому будет записано возвращаемое значение, %esi является аргументом uint32_t requiredWordsCapacity, никакие другие регистры передачи аргументов не используются.

Пока все в порядке, но теперь я пытаюсь вызвать эту функцию из своего сгенерированного IR, и она пытается передать все аргументы в регистры. Вот соответствующие разделы кода:

        %83 = call { i32*, i32, i32, i32 } @growStringDictionary({ i32*, i32, i32, i32 } %70, i32 %73)
[...]
declare { i32*, i32, i32, i32 } @growStringDictionary({ i32*, i32, i32, i32 }, i32)

Обратите внимание, что соглашение о вызовах используется по умолчанию (не изменено на что-то вроде fastcc).

Сгенерированный код (как JIT, который я пытаюсь использовать, так и llc дают один и тот же результат) пытается передать аргумент в регистрах, вот вывод из llc -O0; -O3 похож:

              movl    148(%rsp), %r9d                 # 4-byte Reload
        movl    140(%rsp), %r8d                 # 4-byte Reload
        movl    136(%rsp), %ecx                 # 4-byte Reload
        movl    132(%rsp), %edx                 # 4-byte Reload
        movq    120(%rsp), %rsi                 # 8-byte Reload
        leaq    376(%rsp), %rdi
        callq   growStringDictionary@PLT

Неудивительно, что мой код не работает.

Я удивлен, что сгенерированный llc код не соответствует ABI. Есть ли какие-либо атрибуты, которые мне нужно добавить в объявление функции или определение типа, или есть что-то еще, чего мне не хватает?

Answer 1

Оказывается, эта часть соглашения о вызовах обрабатывается внешним интерфейсом (вместе, я полагаю, с такими вещами, как «это нетривиальный объект C++»).

Возьмите этот пример файла:

      #include <stdint.h>

struct A {
  uint32_t* p;
  uint32_t a;
  uint32_t b;
};

struct B {
  uint32_t* p;
  uint32_t a;
  uint32_t b;
  uint32_t c;
};

uint32_t addA(struct A x) {
  return x.a + x.b;
}

uint32_t addB(struct B x) {
  return x.a + x.b + x.c;
}

clang -S -emit-llvmговорит:

      %struct.A = type { i32*, i32, i32 }
%struct.B = type { i32*, i32, i32, i32 }

; Function Attrs: noinline nounwind optnone uwtable
define dso_local i32 @addA(i32* %0, i64 %1) #0 {
  %3 = alloca %struct.A, align 8
  %4 = bitcast %struct.A* %3 to { i32*, i64 }*
  %5 = getelementptr inbounds { i32*, i64 }, { i32*, i64 }* %4, i32 0, i32 0
  store i32* %0, i32** %5, align 8
  %6 = getelementptr inbounds { i32*, i64 }, { i32*, i64 }* %4, i32 0, i32 1
  store i64 %1, i64* %6, align 8
  %7 = getelementptr inbounds %struct.A, %struct.A* %3, i32 0, i32 1
  %8 = load i32, i32* %7, align 8
  %9 = getelementptr inbounds %struct.A, %struct.A* %3, i32 0, i32 2
  %10 = load i32, i32* %9, align 4
  %11 = add i32 %8, %10
  ret i32 %11
}

; Function Attrs: noinline nounwind optnone uwtable
define dso_local i32 @addB(%struct.B* byval(%struct.B) align 8 %0) #0 {
  %2 = getelementptr inbounds %struct.B, %struct.B* %0, i32 0, i32 1
  %3 = load i32, i32* %2, align 8
  %4 = getelementptr inbounds %struct.B, %struct.B* %0, i32 0, i32 2
  %5 = load i32, i32* %4, align 4
  %6 = add i32 %3, %5
  %7 = getelementptr inbounds %struct.B, %struct.B* %0, i32 0, i32 3
  %8 = load i32, i32* %7, align 8
  %9 = add i32 %6, %8
  ret i32 %9
}

Обратите внимание, что аргумент для addBстал %struct.B* byval(%struct.B)указывает, что это передается в стек.