Как изменить серию нулей в вычисляемом столбце

Question

Я использую приведенный ниже T-SQL для создания таблицы с вычисляемым столбцом, который дает мне идентификаторы в 'BID(The Year)-0000', Проблема в том, что я хотел бы сбросить серию нулей в идентификаторе при изменении года. Например, последний идентификатор в таблице BID2017-0923 когда год меняется, я хочу, чтобы серия была сброшена, например 'BID2018-0001',

Вот T-SQL, который я сейчас использую.

CREATE TABLE Books
(
    ID INT IDENTITY(1,1) NOT NULL PRIMARY KEY,
    IDCreateDate DATETIME NOT NULL DEFAULT GETDATE(),
    BookID AS ('BID' + LTRIM(YEAR(IDCreateDate)) + '-' + RIGHT('0000' + LTRIM(ID), 4)),
    ISBN VARCHAR(32),
    BookName NVARCHAR(50),
    AuthorName NVARCHAR(50),
    BLanguage VARCHAR(50),
    StaId int,
    StuId int,
    CatNo int
);

ОБНОВЛЕНИЕ: Кроме того, я хотел бы, чтобы идентификатор col запоминал свой последний идентификатор в зависимости от года, в котором он находится. Например, последний идентификатор в столбце BID2017-0920 когда я изменяю год на 2010, он должен сбросить номер серии, например BID2010-0001 но когда я возвращаюсь на 2017 год, я не хочу, чтобы сериал сбрасывался, а хочу, чтобы он начинался с BID2017-0921,

Answer 1

Редактировать #1: я обновил свое решение в соответствии с последними комментариями ОП

/*
CREATE TABLE dbo.CustomSequence (
    Name VARCHAR(50) NOT NULL,
    Prefix      VARCHAR(10) NOT NULL,
    LastValue   VARCHAR(50) NULL, -- All generated values will have following pattern: PrefixYYYY-SeqvNumber
    LastYear    SMALLINT NOT NULL,
        CONSTRAINT PK_CustomSequence_Name_LastYear PRIMARY KEY (Name, LastYear),
    LastNumber  SMALLINT NULL
);
GO
-- Config OrderSequence 2014
INSERT  dbo.CustomSequence (Name, Prefix, LastValue, LastYear, LastNumber) 
VALUES  ('BookSequence', 'BID', NULL, 2014, 1)
GO
-- Config OrderSequence 2017
INSERT  dbo.CustomSequence (Name, Prefix, LastValue, LastYear, LastNumber) 
VALUES  ('BookSequence', 'BID', NULL, 2017, 1)
GO
*/

-- Generating new seq
    -- IN Parameters
    DECLARE @CustomSequenceName VARCHAR(50) = 'BookSequence'
    DECLARE @Year               SMALLINT = 2017 --YEAR(GETDATE())
    DECLARE @LenOfNumber        TINYINT = 4
    -- End of IN Parameters
    -- OUT Parameters
    DECLARE @GeneratedValue     VARCHAR(50)
    -- End of OUT Parameters

    UPDATE  s
    SET     LastNumber      = IIF(LastValue IS NULL, LastNumber, LastNumber + 1) + IIF(LastNumber = REPLICATE('9', @LenOfNumber), 1/0, 0),
            @GeneratedValue = LastValue = Prefix + LTRIM(@Year) + '-' + RIGHT(REPLICATE('0', @LenOfNumber)  + LTRIM(IIF(LastValue IS NULL, LastNumber, LastNumber + 1)), @LenOfNumber)
    FROM    dbo.CustomSequence s
    WHERE   s.Name = @CustomSequenceName
    AND     s.LastYear = @Year
-- End of Generating new seq

SELECT @GeneratedValue
SELECT * FROM dbo.CustomSequence
--> BID2017-0001, BID2017-0002, BID2017-0003, ...

Примечание № 1: Это решение работает с пессимистическим контролем параллелизма (поведение SQL Server Database Engine по умолчанию)

Примечание № 2: если мы достигаем 10000 следующего куска кода

... IIF(LastNumber = 9999, 1/0, 0) ...

поднимет исключение

Msg 8134, Level 16, State 1, Line 30
Divide by zero error encountered.
The statement has been terminated.

Примечание № 3: оператор UPDATE может быть инкапсулирован в хранимую процедуру с @CustomSequenceName VARCHAR(50) в качестве входного параметра и @GeneratedValue VARCHAR(50) OUTPUT как параметр OUT[PUT].

Примечание #4: @LenOfNumber позволяет настроить длину последовательного номера (по умолчанию 4)

Изменить #2:

Оператор UPDATE может быть заменен следующей комбинацией операторов INSERT + UPDATE:

SET XACT_ABORT ON
BEGIN TRAN
    IF NOT EXISTS(SELECT * FROM dbo.CustomSequence s WITH(HOLDLOCK) WHERE s.Name = @CustomSequenceName AND s.LastYear = @Year)
    BEGIN
        INSERT  dbo.CustomSequence (Name, Prefix, LastValue, LastYear, LastNumber) 
        VALUES  (@CustomSequenceName, @Prefix, NULL, @Year, 1)
    END
    UPDATE  s
    SET     LastNumber      = IIF(LastValue IS NULL, LastNumber, LastNumber + 1) + IIF(LastNumber = REPLICATE('9', @LenOfNumber), 1/0, 0),
            @GeneratedValue = LastValue = Prefix + LTRIM(@Year) + '-' + RIGHT(REPLICATE('0', @LenOfNumber)  + LTRIM(IIF(LastValue IS NULL, LastNumber, LastNumber + 1)), @LenOfNumber)
    FROM    dbo.CustomSequence s WITH(HOLDLOCK)
    WHERE   s.Name = @CustomSequenceName
    AND     s.LastYear = @Year
COMMIT